(git:2d33723)
Loading...
Searching...
No Matches
qs_core_energies.F
Go to the documentation of this file.
1!--------------------------------------------------------------------------------------------------!
2! CP2K: A general program to perform molecular dynamics simulations !
3! Copyright 2000-2026 CP2K developers group <https://cp2k.org> !
4! !
5! SPDX-License-Identifier: GPL-2.0-or-later !
6!--------------------------------------------------------------------------------------------------!
7
8! **************************************************************************************************
9!> \brief Calculation of the energies concerning the core charge distribution
10!> \par History
11!> - Full refactoring of calculate_ecore and calculate_ecore_overlap (jhu)
12!> \author Matthias Krack (27.04.2001)
13! **************************************************************************************************
14MODULE qs_core_energies
15 USE atomic_kind_types, ONLY: atomic_kind_type,&
16 get_atomic_kind,&
17 get_atomic_kind_set
18 USE atprop_types, ONLY: atprop_array_init,&
19 atprop_type
20 USE cell_types, ONLY: cell_type,&
21 pbc
22 USE cp_dbcsr_api, ONLY: dbcsr_p_type,&
23 dbcsr_type
24 USE cp_dbcsr_contrib, ONLY: dbcsr_dot
25 USE distribution_1d_types, ONLY: distribution_1d_type
26 USE kinds, ONLY: dp
27 USE mathconstants, ONLY: oorootpi,&
28 twopi
29 USE message_passing, ONLY: mp_comm_type,&
30 mp_para_env_type
31 USE particle_types, ONLY: particle_type
32 USE qs_cneo_types, ONLY: cneo_potential_type
33 USE qs_energy_types, ONLY: qs_energy_type
34 USE qs_environment_types, ONLY: get_qs_env,&
35 qs_environment_type
36 USE qs_force_types, ONLY: qs_force_type
37 USE qs_kind_types, ONLY: get_qs_kind,&
38 qs_kind_type
39 USE qs_neighbor_list_types, ONLY: get_iterator_info,&
40 neighbor_list_iterate,&
41 neighbor_list_iterator_create,&
42 neighbor_list_iterator_p_type,&
43 neighbor_list_iterator_release,&
44 neighbor_list_set_p_type
45 USE virial_methods, ONLY: virial_pair_force
46 USE virial_types, ONLY: virial_type
47#include "./base/base_uses.f90"
48
49 IMPLICIT NONE
50
51 PRIVATE
52
53! *** Global parameters ***
54
55 CHARACTER(len=*), PARAMETER, PRIVATE :: moduleN = 'qs_core_energies'
56
57 PUBLIC :: calculate_ptrace, &
58 calculate_ecore_overlap, &
59 calculate_ecore_self, calculate_ecore_alpha
60
61 INTERFACE calculate_ptrace
62 MODULE PROCEDURE calculate_ptrace_1, calculate_ptrace_gamma, calculate_ptrace_kp
63 END INTERFACE
64
65! **************************************************************************************************
66
67CONTAINS
68
69! **************************************************************************************************
70!> \brief Calculate the trace of a operator matrix with the density matrix.
71!> Sum over all spin components (in P, no spin in H)
72!> \param hmat ...
73!> \param pmat ...
74!> \param ecore ...
75!> \param nspin ...
76!> \param spinmat Flag for spin dependency of operator matrix
77!> \date 29.07.2014
78!> \par History
79!> - none
80!> \author JGH
81!> \version 1.0
82! **************************************************************************************************
83 SUBROUTINE calculate_ptrace_gamma(hmat, pmat, ecore, nspin, spinmat)
84
85 TYPE(dbcsr_p_type), DIMENSION(:), POINTER :: hmat, pmat
86 REAL(KIND=dp), INTENT(OUT) :: ecore
87 INTEGER, INTENT(IN) :: nspin
88 LOGICAL, INTENT(IN), OPTIONAL :: spinmat
89
90 CHARACTER(len=*), PARAMETER :: routineN = 'calculate_ptrace_gamma'
91
92 INTEGER :: handle, ispin
93 LOGICAL :: lspin
94 REAL(KIND=dp) :: etr
95
96 CALL timeset(routinen, handle)
97
98 lspin = .false.
99 IF (PRESENT(spinmat)) lspin = spinmat
100
101 ecore = 0.0_dp
102 DO ispin = 1, nspin
103 etr = 0.0_dp
104 IF (lspin) THEN
105 CALL dbcsr_dot(hmat(ispin)%matrix, pmat(ispin)%matrix, etr)
106 ELSE
107 CALL dbcsr_dot(hmat(1)%matrix, pmat(ispin)%matrix, etr)
108 END IF
109 ecore = ecore + etr
110 END DO
111
112 CALL timestop(handle)
113
114 END SUBROUTINE calculate_ptrace_gamma
115
116! **************************************************************************************************
117!> \brief Calculate the trace of a operator matrix with the density matrix.
118!> Sum over all spin components (in P, no spin in H) and the real space
119!> coordinates
120!> \param hmat H matrix
121!> \param pmat P matrices
122!> \param ecore Tr(HP) output
123!> \param nspin Number of P matrices
124!> \param spinmat Flag for spin dependency of operator matrix
125!> \date 29.07.2014
126!> \author JGH
127!> \version 1.0
128! **************************************************************************************************
129 SUBROUTINE calculate_ptrace_kp(hmat, pmat, ecore, nspin, spinmat)
130
131 TYPE(dbcsr_p_type), DIMENSION(:, :), POINTER :: hmat, pmat
132 REAL(kind=dp), INTENT(OUT) :: ecore
133 INTEGER, INTENT(IN) :: nspin
134 LOGICAL, INTENT(IN), OPTIONAL :: spinmat
135
136 CHARACTER(len=*), PARAMETER :: routinen = 'calculate_ptrace_kp'
137
138 INTEGER :: handle, ic, ispin, nc
139 LOGICAL :: lspin
140 REAL(kind=dp) :: etr
141
142 CALL timeset(routinen, handle)
143
144 lspin = .false.
145 IF (PRESENT(spinmat)) lspin = spinmat
146
147 nc = SIZE(pmat, 2)
148
149 ecore = 0.0_dp
150 DO ispin = 1, nspin
151 DO ic = 1, nc
152 etr = 0.0_dp
153 IF (lspin) THEN
154 CALL dbcsr_dot(hmat(ispin, ic)%matrix, pmat(ispin, ic)%matrix, etr)
155 ELSE
156 CALL dbcsr_dot(hmat(1, ic)%matrix, pmat(ispin, ic)%matrix, etr)
157 END IF
158 ecore = ecore + etr
159 END DO
160 END DO
161
162 CALL timestop(handle)
163
164 END SUBROUTINE calculate_ptrace_kp
165
166! **************************************************************************************************
167!> \brief Calculate the core Hamiltonian energy which includes the kinetic
168!> and the potential energy of the electrons. It is assumed, that
169!> the core Hamiltonian matrix h and the density matrix p have the
170!> same sparse matrix structure (same atomic blocks and block
171!> ordering)
172!> \param h ...
173!> \param p ...
174!> \param ecore ...
175!> \date 03.05.2001
176!> \par History
177!> - simplified taking advantage of new non-redundant matrix
178!> structure (27.06.2003,MK)
179!> - simplified using DBCSR trace function (21.07.2010, jhu)
180!> \author MK
181!> \version 1.0
182! **************************************************************************************************
183 SUBROUTINE calculate_ptrace_1(h, p, ecore)
184
185 TYPE(dbcsr_type), POINTER :: h, p
186 REAL(kind=dp), INTENT(OUT) :: ecore
187
188 CHARACTER(len=*), PARAMETER :: routinen = 'calculate_ptrace_1'
189
190 INTEGER :: handle
191
192 CALL timeset(routinen, handle)
193
194 ecore = 0.0_dp
195 CALL dbcsr_dot(h, p, ecore)
196
197 CALL timestop(handle)
198
199 END SUBROUTINE calculate_ptrace_1
200
201! **************************************************************************************************
202!> \brief Calculate the overlap energy of the core charge distribution.
203!> \param qs_env ...
204!> \param para_env ...
205!> \param calculate_forces ...
206!> \param molecular ...
207!> \param E_overlap_core ...
208!> \param atecc ...
209!> \date 30.04.2001
210!> \par History
211!> - Force calculation added (03.06.2002,MK)
212!> - Parallelized using a list of local atoms for rows and
213!> columns (19.07.2003,MK)
214!> - Use precomputed neighborlists (sab_core) and nl iterator (28.07.2010,jhu)
215!> \author MK
216!> \version 1.0
217! **************************************************************************************************
218 SUBROUTINE calculate_ecore_overlap(qs_env, para_env, calculate_forces, molecular, &
219 E_overlap_core, atecc)
220 TYPE(qs_environment_type), POINTER :: qs_env
221 TYPE(mp_para_env_type), POINTER :: para_env
222 LOGICAL, INTENT(IN) :: calculate_forces
223 LOGICAL, INTENT(IN), OPTIONAL :: molecular
224 REAL(kind=dp), INTENT(OUT), OPTIONAL :: e_overlap_core
225 REAL(kind=dp), DIMENSION(:), OPTIONAL :: atecc
226
227 CHARACTER(len=*), PARAMETER :: routinen = 'calculate_ecore_overlap'
228
229 INTEGER :: atom_a, atom_b, handle, iatom, ikind, &
230 jatom, jkind, natom, nkind
231 INTEGER, ALLOCATABLE, DIMENSION(:) :: atom_of_kind
232 LOGICAL :: atenergy, only_molecule, use_virial
233 REAL(kind=dp) :: aab, dab, eab, ecore_overlap, f, fab, &
234 rab2, rootaab, zab
235 REAL(kind=dp), ALLOCATABLE, DIMENSION(:) :: alpha, radius, zeff
236 REAL(kind=dp), DIMENSION(3) :: deab, rab
237 REAL(kind=dp), DIMENSION(3, 3) :: pv_loc
238 TYPE(atomic_kind_type), DIMENSION(:), POINTER :: atomic_kind_set
239 TYPE(atprop_type), POINTER :: atprop
240 TYPE(cneo_potential_type), POINTER :: cneo_potential
241 TYPE(mp_comm_type) :: group
242 TYPE(neighbor_list_iterator_p_type), &
243 DIMENSION(:), POINTER :: nl_iterator
244 TYPE(neighbor_list_set_p_type), DIMENSION(:), &
245 POINTER :: sab_core
246 TYPE(particle_type), DIMENSION(:), POINTER :: particle_set
247 TYPE(qs_energy_type), POINTER :: energy
248 TYPE(qs_force_type), DIMENSION(:), POINTER :: force
249 TYPE(qs_kind_type), DIMENSION(:), POINTER :: qs_kind_set
250 TYPE(virial_type), POINTER :: virial
251
252 CALL timeset(routinen, handle)
253
254 NULLIFY (atomic_kind_set)
255 NULLIFY (qs_kind_set)
256 NULLIFY (energy)
257 NULLIFY (atprop)
258 NULLIFY (force)
259 NULLIFY (particle_set)
260
261 group = para_env
262
263 only_molecule = .false.
264 IF (PRESENT(molecular)) only_molecule = molecular
265
266 CALL get_qs_env(qs_env=qs_env, &
267 atomic_kind_set=atomic_kind_set, &
268 qs_kind_set=qs_kind_set, &
269 particle_set=particle_set, &
270 energy=energy, &
271 force=force, &
272 sab_core=sab_core, &
273 atprop=atprop, &
274 virial=virial)
275
276 ! Allocate work storage
277 nkind = SIZE(atomic_kind_set)
278 natom = SIZE(particle_set)
279
280 use_virial = virial%pv_availability .AND. (.NOT. virial%pv_numer)
281
282 ALLOCATE (alpha(nkind), radius(nkind), zeff(nkind))
283 alpha(:) = 0.0_dp
284 radius(:) = 0.0_dp
285 zeff(:) = 0.0_dp
286
287 IF (calculate_forces) THEN
288 CALL get_atomic_kind_set(atomic_kind_set, atom_of_kind=atom_of_kind)
289 END IF
290
291 atenergy = .false.
292 IF (ASSOCIATED(atprop)) THEN
293 IF (atprop%energy) THEN
294 atenergy = .true.
295 CALL atprop_array_init(atprop%atecc, natom)
296 END IF
297 END IF
298
299 DO ikind = 1, nkind
300 ! cneo quantum nuclei have their core energies calculated elsewhere
301 NULLIFY (cneo_potential)
302 CALL get_qs_kind(qs_kind_set(ikind), cneo_potential=cneo_potential)
303 IF (ASSOCIATED(cneo_potential)) THEN
304 alpha(ikind) = 1.0_dp
305 radius(ikind) = 1.0_dp
306 zeff(ikind) = 0.0_dp
307 ELSE
308 CALL get_qs_kind(qs_kind_set(ikind), &
309 alpha_core_charge=alpha(ikind), &
310 core_charge_radius=radius(ikind), &
311 zeff=zeff(ikind))
312 END IF
313 END DO
314
315 ecore_overlap = 0.0_dp
316 pv_loc = 0.0_dp
317
318 CALL neighbor_list_iterator_create(nl_iterator, sab_core)
319 DO WHILE (neighbor_list_iterate(nl_iterator) == 0)
320 CALL get_iterator_info(nl_iterator, ikind=ikind, jkind=jkind, iatom=iatom, jatom=jatom, r=rab)
321 zab = zeff(ikind)*zeff(jkind)
322 aab = alpha(ikind)*alpha(jkind)/(alpha(ikind) + alpha(jkind))
323 rootaab = sqrt(aab)
324 fab = 2.0_dp*oorootpi*zab*rootaab
325 rab2 = rab(1)*rab(1) + rab(2)*rab(2) + rab(3)*rab(3)
326 IF (rab2 > 1.e-8_dp) THEN
327 IF (ikind == jkind .AND. iatom == jatom) THEN
328 f = 0.5_dp
329 ELSE
330 f = 1.0_dp
331 END IF
332 dab = sqrt(rab2)
333 eab = zab*erfc(rootaab*dab)/dab
334 ecore_overlap = ecore_overlap + f*eab
335 IF (atenergy) THEN
336 atprop%atecc(iatom) = atprop%atecc(iatom) + 0.5_dp*f*eab
337 atprop%atecc(jatom) = atprop%atecc(jatom) + 0.5_dp*f*eab
338 END IF
339 IF (PRESENT(atecc)) THEN
340 atecc(iatom) = atecc(iatom) + 0.5_dp*f*eab
341 atecc(jatom) = atecc(jatom) + 0.5_dp*f*eab
342 END IF
343 IF (calculate_forces) THEN
344 deab(:) = rab(:)*f*(eab + fab*exp(-aab*rab2))/rab2
345 atom_a = atom_of_kind(iatom)
346 atom_b = atom_of_kind(jatom)
347 force(ikind)%core_overlap(:, atom_a) = force(ikind)%core_overlap(:, atom_a) + deab(:)
348 force(jkind)%core_overlap(:, atom_b) = force(jkind)%core_overlap(:, atom_b) - deab(:)
349 IF (use_virial) THEN
350 CALL virial_pair_force(pv_loc, 1._dp, deab, rab)
351 END IF
352 END IF
353 END IF
354 END DO
355 CALL neighbor_list_iterator_release(nl_iterator)
356
357 DEALLOCATE (alpha, radius, zeff)
358 IF (calculate_forces) THEN
359 DEALLOCATE (atom_of_kind)
360 END IF
361 IF (calculate_forces .AND. use_virial) THEN
362 virial%pv_ecore_overlap = virial%pv_ecore_overlap + pv_loc
363 virial%pv_virial = virial%pv_virial + pv_loc
364 END IF
365
366 CALL group%sum(ecore_overlap)
367
368 energy%core_overlap = ecore_overlap
369
370 IF (PRESENT(e_overlap_core)) THEN
371 e_overlap_core = energy%core_overlap
372 END IF
373
374 CALL timestop(handle)
375
376 END SUBROUTINE calculate_ecore_overlap
377
378! **************************************************************************************************
379!> \brief Calculate the self energy of the core charge distribution.
380!> \param qs_env ...
381!> \param E_self_core ...
382!> \param atecc ...
383!> \date 27.04.2001
384!> \author MK
385!> \version 1.0
386! **************************************************************************************************
387 SUBROUTINE calculate_ecore_self(qs_env, E_self_core, atecc)
388 TYPE(qs_environment_type), POINTER :: qs_env
389 REAL(kind=dp), INTENT(OUT), OPTIONAL :: e_self_core
390 REAL(kind=dp), DIMENSION(:), OPTIONAL :: atecc
391
392 CHARACTER(len=*), PARAMETER :: routinen = 'calculate_ecore_self'
393
394 INTEGER :: handle, iatom, ikind, iparticle_local, &
395 natom, nparticle_local
396 REAL(kind=dp) :: alpha_core_charge, ecore_self, es, zeff
397 TYPE(atomic_kind_type), DIMENSION(:), POINTER :: atomic_kind_set
398 TYPE(atprop_type), POINTER :: atprop
399 TYPE(cneo_potential_type), POINTER :: cneo_potential
400 TYPE(distribution_1d_type), POINTER :: local_particles
401 TYPE(particle_type), DIMENSION(:), POINTER :: particle_set
402 TYPE(qs_energy_type), POINTER :: energy
403 TYPE(qs_kind_type), DIMENSION(:), POINTER :: qs_kind_set
404
405! -------------------------------------------------------------------------
406
407 NULLIFY (atprop)
408 CALL timeset(routinen, handle)
409
410 CALL get_qs_env(qs_env=qs_env, atomic_kind_set=atomic_kind_set, &
411 qs_kind_set=qs_kind_set, energy=energy, atprop=atprop)
412
413 ecore_self = 0.0_dp
414
415 DO ikind = 1, SIZE(atomic_kind_set)
416 ! nuclear density self-interaction is already removed in CNEO
417 NULLIFY (cneo_potential)
418 CALL get_qs_kind(qs_kind_set(ikind), cneo_potential=cneo_potential)
419 IF (ASSOCIATED(cneo_potential)) cycle
420 CALL get_atomic_kind(atomic_kind_set(ikind), natom=natom)
421 CALL get_qs_kind(qs_kind_set(ikind), zeff=zeff, alpha_core_charge=alpha_core_charge)
422 ecore_self = ecore_self - real(natom, dp)*zeff**2*sqrt(alpha_core_charge)
423 END DO
424
425 energy%core_self = ecore_self/sqrt(twopi)
426 IF (PRESENT(e_self_core)) THEN
427 e_self_core = energy%core_self
428 END IF
429
430 IF (ASSOCIATED(atprop)) THEN
431 IF (atprop%energy) THEN
432 ! atomic energy
433 CALL get_qs_env(qs_env=qs_env, particle_set=particle_set, &
434 local_particles=local_particles)
435 natom = SIZE(particle_set)
436 CALL atprop_array_init(atprop%ateself, natom)
437
438 DO ikind = 1, SIZE(atomic_kind_set)
439 ! nuclear density self-interaction is already removed in CNEO
440 NULLIFY (cneo_potential)
441 CALL get_qs_kind(qs_kind_set(ikind), cneo_potential=cneo_potential)
442 IF (ASSOCIATED(cneo_potential)) cycle
443 nparticle_local = local_particles%n_el(ikind)
444 CALL get_qs_kind(qs_kind_set(ikind), zeff=zeff, alpha_core_charge=alpha_core_charge)
445 es = zeff**2*sqrt(alpha_core_charge)/sqrt(twopi)
446 DO iparticle_local = 1, nparticle_local
447 iatom = local_particles%list(ikind)%array(iparticle_local)
448 atprop%ateself(iatom) = atprop%ateself(iatom) - es
449 END DO
450 END DO
451 END IF
452 END IF
453 IF (PRESENT(atecc)) THEN
454 ! atomic energy
455 CALL get_qs_env(qs_env=qs_env, particle_set=particle_set, &
456 local_particles=local_particles)
457 natom = SIZE(particle_set)
458 DO ikind = 1, SIZE(atomic_kind_set)
459 nparticle_local = local_particles%n_el(ikind)
460 CALL get_qs_kind(qs_kind_set(ikind), zeff=zeff, alpha_core_charge=alpha_core_charge)
461 es = zeff**2*sqrt(alpha_core_charge)/sqrt(twopi)
462 DO iparticle_local = 1, nparticle_local
463 iatom = local_particles%list(ikind)%array(iparticle_local)
464 atecc(iatom) = atecc(iatom) - es
465 END DO
466 END DO
467 END IF
468
469 CALL timestop(handle)
470
471 END SUBROUTINE calculate_ecore_self
472
473! **************************************************************************************************
474!> \brief Calculate the overlap and self energy of the core charge distribution for a given alpha
475!> Use a minimum image convention and double loop over all atoms
476!> \param qs_env ...
477!> \param alpha ...
478!> \param atecc ...
479!> \author JGH
480!> \version 1.0
481! **************************************************************************************************
482 SUBROUTINE calculate_ecore_alpha(qs_env, alpha, atecc)
483 TYPE(qs_environment_type), POINTER :: qs_env
484 REAL(kind=dp), INTENT(IN) :: alpha
485 REAL(kind=dp), DIMENSION(:) :: atecc
486
487 CHARACTER(len=*), PARAMETER :: routinen = 'calculate_ecore_alpha'
488
489 INTEGER :: handle, iatom, ikind, jatom, jkind, &
490 natom, nkind
491 INTEGER, ALLOCATABLE, DIMENSION(:) :: kind_of
492 REAL(kind=dp) :: dab, eab, fab, rootaab, zab
493 REAL(kind=dp), ALLOCATABLE, DIMENSION(:) :: zeff
494 REAL(kind=dp), DIMENSION(3) :: rab
495 TYPE(atomic_kind_type), DIMENSION(:), POINTER :: atomic_kind_set
496 TYPE(cell_type), POINTER :: cell
497 TYPE(particle_type), DIMENSION(:), POINTER :: particle_set
498 TYPE(qs_kind_type), DIMENSION(:), POINTER :: qs_kind_set
499
500 CALL timeset(routinen, handle)
501
502 CALL get_qs_env(qs_env=qs_env, &
503 cell=cell, &
504 atomic_kind_set=atomic_kind_set, &
505 qs_kind_set=qs_kind_set, &
506 particle_set=particle_set)
507 CALL get_atomic_kind_set(atomic_kind_set=atomic_kind_set, kind_of=kind_of)
508 !
509 nkind = SIZE(atomic_kind_set)
510 natom = SIZE(particle_set)
511 ALLOCATE (zeff(nkind))
512 zeff(:) = 0.0_dp
513 DO ikind = 1, nkind
514 CALL get_qs_kind(qs_kind_set(ikind), zeff=zeff(ikind))
515 END DO
516
517 rootaab = sqrt(0.5_dp*alpha)
518 DO iatom = 1, natom
519 ikind = kind_of(iatom)
520 atecc(iatom) = atecc(iatom) - zeff(ikind)**2*sqrt(alpha/twopi)
521 DO jatom = iatom + 1, natom
522 jkind = kind_of(jatom)
523 zab = zeff(ikind)*zeff(jkind)
524 fab = 2.0_dp*oorootpi*zab*rootaab
525 rab = particle_set(iatom)%r - particle_set(jatom)%r
526 rab = pbc(rab, cell)
527 dab = sqrt(sum(rab(:)**2))
528 eab = zab*erfc(rootaab*dab)/dab
529 atecc(iatom) = atecc(iatom) + 0.5_dp*eab
530 atecc(jatom) = atecc(jatom) + 0.5_dp*eab
531 END DO
532 END DO
533
534 DEALLOCATE (zeff)
535
536 CALL timestop(handle)
537
538 END SUBROUTINE calculate_ecore_alpha
539
540END MODULE qs_core_energies
cell_types::pbc
Definition cell_types.F:97
qs_core_energies::calculate_ptrace
Definition qs_core_energies.F:61
atomic_kind_types
Define the atomic kind types and their sub types.
Definition atomic_kind_types.F:23
atomic_kind_types::get_atomic_kind_set
subroutine, public get_atomic_kind_set(atomic_kind_set, atom_of_kind, kind_of, natom_of_kind, maxatom, natom, nshell, fist_potential_present, shell_present, shell_adiabatic, shell_check_distance, damping_present)
Get attributes of an atomic kind set.
Definition atomic_kind_types.F:223
atomic_kind_types::get_atomic_kind
subroutine, public get_atomic_kind(atomic_kind, fist_potential, element_symbol, name, mass, kind_number, natom, atom_list, rcov, rvdw, z, qeff, apol, cpol, mm_radius, shell, shell_active, damping)
Get attributes of an atomic kind.
Definition atomic_kind_types.F:138
atprop_types
Holds information on atomic properties.
Definition atprop_types.F:14
atprop_types::atprop_array_init
subroutine, public atprop_array_init(atarray, natom)
...
Definition atprop_types.F:87
cell_types
Handles all functions related to the CELL.
Definition cell_types.F:15
cp_dbcsr_api
Definition cp_dbcsr_api.F:8
cp_dbcsr_contrib
Definition cp_dbcsr_contrib.F:8
cp_dbcsr_contrib::dbcsr_dot
subroutine, public dbcsr_dot(matrix_a, matrix_b, trace)
Computes the dot product of two matrices, also known as the trace of their matrix product.
Definition cp_dbcsr_contrib.F:367
distribution_1d_types
stores a lists of integer that are local to a processor. The idea is that these integers represent ob...
Definition distribution_1d_types.F:24
kinds
Defines the basic variable types.
Definition kinds.F:23
kinds::dp
integer, parameter, public dp
Definition kinds.F:34
mathconstants
Definition of mathematical constants and functions.
Definition mathconstants.F:16
mathconstants::oorootpi
real(kind=dp), parameter, public oorootpi
Definition mathconstants.F:115
mathconstants::twopi
real(kind=dp), parameter, public twopi
Definition mathconstants.F:112
message_passing
Interface to the message passing library MPI.
Definition message_passing.F:23
particle_types
Define the data structure for the particle information.
Definition particle_types.F:19
qs_cneo_types
Types used by CNEO-DFT (see J. Chem. Theory Comput. 2025, 21, 16, 7865–7877)
Definition qs_cneo_types.F:15
qs_core_energies
Calculation of the energies concerning the core charge distribution.
Definition qs_core_energies.F:14
qs_core_energies::calculate_ecore_overlap
subroutine, public calculate_ecore_overlap(qs_env, para_env, calculate_forces, molecular, e_overlap_core, atecc)
Calculate the overlap energy of the core charge distribution.
Definition qs_core_energies.F:220
qs_core_energies::calculate_ecore_self
subroutine, public calculate_ecore_self(qs_env, e_self_core, atecc)
Calculate the self energy of the core charge distribution.
Definition qs_core_energies.F:388
qs_core_energies::calculate_ecore_alpha
subroutine, public calculate_ecore_alpha(qs_env, alpha, atecc)
Calculate the overlap and self energy of the core charge distribution for a given alpha Use a minimum...
Definition qs_core_energies.F:483
qs_energy_types
Definition qs_energy_types.F:14
qs_environment_types
Definition qs_environment_types.F:14
qs_environment_types::get_qs_env
subroutine, public get_qs_env(qs_env, atomic_kind_set, qs_kind_set, cell, super_cell, cell_ref, use_ref_cell, kpoints, dft_control, mos, sab_orb, sab_all, qmmm, qmmm_periodic, mimic, sac_ae, sac_ppl, sac_lri, sap_ppnl, sab_vdw, sab_scp, sap_oce, sab_lrc, sab_se, sab_xtbe, sab_tbe, sab_core, sab_xb, sab_xtb_pp, sab_xtb_nonbond, sab_almo, sab_kp, sab_kp_nosym, sab_cneo, particle_set, energy, force, matrix_h, matrix_h_im, matrix_ks, matrix_ks_im, matrix_vxc, run_rtp, rtp, matrix_h_kp, matrix_h_im_kp, matrix_ks_kp, matrix_ks_im_kp, matrix_vxc_kp, kinetic_kp, matrix_s_kp, matrix_w_kp, matrix_s_ri_aux_kp, matrix_s, matrix_s_ri_aux, matrix_w, matrix_p_mp2, matrix_p_mp2_admm, rho, rho_xc, pw_env, ewald_env, ewald_pw, active_space, mpools, input, para_env, blacs_env, scf_control, rel_control, kinetic, qs_charges, vppl, xcint_weights, rho_core, rho_nlcc, rho_nlcc_g, ks_env, ks_qmmm_env, wf_history, scf_env, local_particles, local_molecules, distribution_2d, dbcsr_dist, molecule_kind_set, molecule_set, subsys, cp_subsys, oce, local_rho_set, rho_atom_set, task_list, task_list_soft, rho0_atom_set, rho0_mpole, rhoz_set, rhoz_cneo_set, ecoul_1c, rho0_s_rs, rho0_s_gs, rhoz_cneo_s_rs, rhoz_cneo_s_gs, do_kpoints, has_unit_metric, requires_mo_derivs, mo_derivs, mo_loc_history, nkind, natom, nelectron_total, nelectron_spin, efield, neighbor_list_id, linres_control, xas_env, virial, cp_ddapc_env, cp_ddapc_ewald, outer_scf_history, outer_scf_ihistory, x_data, et_coupling, dftb_potential, results, se_taper, se_store_int_env, se_nddo_mpole, se_nonbond_env, admm_env, lri_env, lri_density, exstate_env, ec_env, harris_env, dispersion_env, gcp_env, vee, rho_external, external_vxc, mask, mp2_env, bs_env, kg_env, wanniercentres, atprop, ls_scf_env, do_transport, transport_env, v_hartree_rspace, s_mstruct_changed, rho_changed, potential_changed, forces_up_to_date, mscfg_env, almo_scf_env, gradient_history, variable_history, embed_pot, spin_embed_pot, polar_env, mos_last_converged, eeq, rhs, do_rixs, tb_tblite)
Get the QUICKSTEP environment.
Definition qs_environment_types.F:530
qs_force_types
Definition qs_force_types.F:13
qs_kind_types
Define the quickstep kind type and their sub types.
Definition qs_kind_types.F:23
qs_kind_types::get_qs_kind
subroutine, public get_qs_kind(qs_kind, basis_set, basis_type, ncgf, nsgf, all_potential, tnadd_potential, gth_potential, sgp_potential, upf_potential, cneo_potential, se_parameter, dftb_parameter, xtb_parameter, dftb3_param, zatom, zeff, elec_conf, mao, lmax_dftb, alpha_core_charge, ccore_charge, core_charge, core_charge_radius, paw_proj_set, paw_atom, hard_radius, hard0_radius, max_rad_local, covalent_radius, vdw_radius, gpw_type_forced, harmonics, max_iso_not0, max_s_harm, grid_atom, ngrid_ang, ngrid_rad, lmax_rho0, dft_plus_u_atom, l_of_dft_plus_u, n_of_dft_plus_u, u_minus_j, u_of_dft_plus_u, j_of_dft_plus_u, alpha_of_dft_plus_u, beta_of_dft_plus_u, j0_of_dft_plus_u, occupation_of_dft_plus_u, dispersion, bs_occupation, magnetization, no_optimize, addel, laddel, naddel, orbitals, max_scf, eps_scf, smear, u_ramping, u_minus_j_target, eps_u_ramping, init_u_ramping_each_scf, reltmat, ghost, monovalent, floating, name, element_symbol, pao_basis_size, pao_model_file, pao_potentials, pao_descriptors, nelec)
Get attributes of an atomic kind.
Definition qs_kind_types.F:468
qs_neighbor_list_types
Define the neighbor list data types and the corresponding functionality.
Definition qs_neighbor_list_types.F:17
qs_neighbor_list_types::neighbor_list_iterator_create
subroutine, public neighbor_list_iterator_create(iterator_set, nl, search, nthread)
Neighbor list iterator functions.
Definition qs_neighbor_list_types.F:165
qs_neighbor_list_types::neighbor_list_iterator_release
subroutine, public neighbor_list_iterator_release(iterator_set)
...
Definition qs_neighbor_list_types.F:251
qs_neighbor_list_types::neighbor_list_iterate
integer function, public neighbor_list_iterate(iterator_set, mepos)
...
Definition qs_neighbor_list_types.F:351
qs_neighbor_list_types::get_iterator_info
subroutine, public get_iterator_info(iterator_set, mepos, ikind, jkind, nkind, ilist, nlist, inode, nnode, iatom, jatom, r, cell)
...
Definition qs_neighbor_list_types.F:549
virial_methods
Definition virial_methods.F:12
virial_methods::virial_pair_force
pure subroutine, public virial_pair_force(pv_virial, f0, force, rab)
Computes the contribution to the stress tensor from two-body pair-wise forces.
Definition virial_methods.F:142
virial_types
Definition virial_types.F:13
atomic_kind_types::atomic_kind_type
Provides all information about an atomic kind.
Definition atomic_kind_types.F:45
atprop_types::atprop_type
type for the atomic properties
Definition atprop_types.F:31
cell_types::cell_type
Type defining parameters related to the simulation cell.
Definition cell_types.F:60
cp_dbcsr_api::dbcsr_p_type
Definition cp_dbcsr_api.F:172
cp_dbcsr_api::dbcsr_type
Definition cp_dbcsr_api.F:176
distribution_1d_types::distribution_1d_type
structure to store local (to a processor) ordered lists of integers.
Definition distribution_1d_types.F:62
message_passing::mp_comm_type
Definition message_passing.F:155
message_passing::mp_para_env_type
stores all the informations relevant to an mpi environment
Definition message_passing.F:743
particle_types::particle_type
Definition particle_types.F:35
qs_cneo_types::cneo_potential_type
Definition qs_cneo_types.F:53
qs_energy_types::qs_energy_type
Definition qs_energy_types.F:25
qs_environment_types::qs_environment_type
Definition qs_environment_types.F:220
qs_force_types::qs_force_type
Definition qs_force_types.F:28
qs_kind_types::qs_kind_type
Provides all information about a quickstep kind.
Definition qs_kind_types.F:177
qs_neighbor_list_types::neighbor_list_iterator_p_type
Definition qs_neighbor_list_types.F:117
qs_neighbor_list_types::neighbor_list_set_p_type
Definition qs_neighbor_list_types.F:67
virial_types::virial_type
Definition virial_types.F:26