atprop_types.F

Go to the documentation of this file.

!--------------------------------------------------------------------------------------------------!
!   CP2K: A general program to perform molecular dynamics simulations                              !
!   Copyright 2000-2024 CP2K developers group <https://cp2k.org>                                   !
!                                                                                                  !
!   SPDX-License-Identifier: GPL-2.0-or-later                                                      !
!--------------------------------------------------------------------------------------------------!
 
! **************************************************************************************************
!> \brief Holds information on atomic properties
!> \par History
!>      07.2011 created
!> \author JHU
! **************************************************************************************************
MODULE atprop_types
 
   USE kinds,                           ONLY: dp
#include "../base/base_uses.f90"
 
   IMPLICIT NONE
   PRIVATE
 
   CHARACTER(len=*), PARAMETER, PRIVATE :: moduleN = 'atprop_types'
 
   PUBLIC :: atprop_type, atprop_create, atprop_release, atprop_init
   PUBLIC :: atprop_array_init, atprop_array_add
 
! **************************************************************************************************
!> \brief type for the atomic properties
!> \author fawzi
! **************************************************************************************************
   TYPE atprop_type
      LOGICAL                                   :: energy = .false.
      LOGICAL                                   :: stress = .false.
      REAL(KIND=dp), DIMENSION(:), POINTER      :: atener => null()
      REAL(KIND=dp), DIMENSION(:), POINTER      :: ateb => null()
      REAL(KIND=dp), DIMENSION(:), POINTER      :: atexc => null()
      REAL(KIND=dp), DIMENSION(:), POINTER      :: ateself => null()
      REAL(KIND=dp), DIMENSION(:), POINTER      :: atevdw => null()
      REAL(KIND=dp), DIMENSION(:), POINTER      :: ategcp => null()
      REAL(KIND=dp), DIMENSION(:), POINTER      :: atecc => null()
      REAL(KIND=dp), DIMENSION(:), POINTER      :: ate1c => null()
      REAL(KIND=dp), DIMENSION(:), POINTER      :: atecoul => null()
      REAL(KIND=dp), DIMENSION(:, :, :), POINTER  :: atstress => null()
   END TYPE atprop_type
 
CONTAINS
 
! **************************************************************************************************
!> \brief ...
!> \param atprop_env ...
! **************************************************************************************************
   SUBROUTINE atprop_create(atprop_env)
      TYPE(atprop_type), POINTER                         :: atprop_env
 
      CALL atprop_release(atprop_env)
      ALLOCATE (atprop_env)
 
   END SUBROUTINE atprop_create
 
! **************************************************************************************************
!> \brief ...
!> \param atprop_env ...
!> \param natom ...
! **************************************************************************************************
   SUBROUTINE atprop_init(atprop_env, natom)
      TYPE(atprop_type), INTENT(INOUT)                   :: atprop_env
      INTEGER, INTENT(IN)                                :: natom
 
      IF (atprop_env%energy) THEN
         CALL atprop_array_init(atprop_env%atener, natom)
         CALL atprop_array_release(atprop_env%ateb)
         CALL atprop_array_release(atprop_env%atevdw)
         CALL atprop_array_release(atprop_env%ategcp)
         CALL atprop_array_release(atprop_env%atecc)
         CALL atprop_array_release(atprop_env%atecoul)
         CALL atprop_array_release(atprop_env%ateself)
         CALL atprop_array_release(atprop_env%atexc)
         CALL atprop_array_release(atprop_env%ate1c)
      END IF
 
      IF (atprop_env%stress) THEN
         IF (ASSOCIATED(atprop_env%atstress)) THEN
            cpassert(SIZE(atprop_env%atstress, 3) == natom)
         ELSE
            ALLOCATE (atprop_env%atstress(3, 3, natom))
         END IF
         atprop_env%atstress = 0._dp
      END IF
 
   END SUBROUTINE atprop_init
 
! **************************************************************************************************
!> \brief ...
!> \param atarray ...
!> \param natom ...
! **************************************************************************************************
   SUBROUTINE atprop_array_init(atarray, natom)
      REAL(kind=dp), DIMENSION(:), POINTER               :: atarray
      INTEGER, INTENT(IN)                                :: natom
 
      IF (ASSOCIATED(atarray)) THEN
         cpassert(SIZE(atarray) == natom)
      ELSE
         ALLOCATE (atarray(natom))
      END IF
      atarray = 0._dp
 
   END SUBROUTINE atprop_array_init
 
! **************************************************************************************************
!> \brief ...
!> \param atarray ...
! **************************************************************************************************
   SUBROUTINE atprop_array_release(atarray)
      REAL(kind=dp), DIMENSION(:), POINTER               :: atarray
 
      IF (ASSOCIATED(atarray)) THEN
         DEALLOCATE (atarray)
      END IF
 
   END SUBROUTINE atprop_array_release
 
! **************************************************************************************************
!> \brief ...
!> \param array_a ...
!> \param array_b ...
! **************************************************************************************************
   SUBROUTINE atprop_array_add(array_a, array_b)
      REAL(kind=dp), DIMENSION(:), INTENT(INOUT)         :: array_a
      REAL(kind=dp), DIMENSION(:), INTENT(IN), POINTER   :: array_b
 
      IF (ASSOCIATED(array_b)) THEN
         array_a = array_a + array_b
      END IF
 
   END SUBROUTINE atprop_array_add
 
! **************************************************************************************************
!> \brief releases the atprop
!> \param atprop_env the object to release
!> \author fawzi
! **************************************************************************************************
   SUBROUTINE atprop_release(atprop_env)
      TYPE(atprop_type), POINTER                         :: atprop_env
 
      IF (ASSOCIATED(atprop_env)) THEN
         ! energy
         CALL atprop_array_release(atprop_env%atener)
         CALL atprop_array_release(atprop_env%ateb)
         CALL atprop_array_release(atprop_env%ateself)
         CALL atprop_array_release(atprop_env%atexc)
         CALL atprop_array_release(atprop_env%atevdw)
         CALL atprop_array_release(atprop_env%ategcp)
         CALL atprop_array_release(atprop_env%atecc)
         CALL atprop_array_release(atprop_env%ate1c)
         CALL atprop_array_release(atprop_env%atecoul)
         ! stress
         IF (ASSOCIATED(atprop_env%atstress)) THEN
            DEALLOCATE (atprop_env%atstress)
         END IF
         ! atprop type
         DEALLOCATE (atprop_env)
      END IF
      NULLIFY (atprop_env)
   END SUBROUTINE atprop_release
 
END MODULE atprop_types