realspace_grid_cube_unittest.F

Go to the documentation of this file.

!--------------------------------------------------------------------------------------------------!
!   CP2K: A general program to perform molecular dynamics simulations                              !
!   Copyright 2000-2026 CP2K developers group <https://cp2k.org>                                   !
!                                                                                                  !
!   SPDX-License-Identifier: GPL-2.0-or-later                                                      !
!--------------------------------------------------------------------------------------------------!
PROGRAM realspace_grid_cube_unittest
   USE kinds,                           ONLY: dp
   USE realspace_grid_cube,             ONLY: cube_read_values,&
                                              cube_value_format,&
                                              cube_values_format
 
   IMPLICIT NONE
 
   CHARACTER(LEN=13)                                  :: value
   CHARACTER(LEN=92)                                  :: slice_values
   CHARACTER(LEN=79)                                  :: values
   REAL(kind=dp), DIMENSION(6)                        :: buffer, reference
   REAL(kind=dp), DIMENSION(7)                        :: slice_buffer, slice_reference
 
   WRITE (value, cube_value_format) 3.33004e-101_dp
   IF (index(value, "E-101") <= 0) THEN
      error stop "Cube value format must preserve three-digit negative exponents."
   END IF
 
   reference = [0.0_dp, -0.91458e-35_dp, 3.33004e-101_dp, &
                -1.32487e-103_dp, 1.0_dp, -1.0_dp]
   WRITE (values(1:78), cube_values_format) reference
   values(79:79) = new_line("C")
   IF (index(values, "E-101") <= 0) THEN
      error stop "Cube line format must preserve E-101."
   END IF
   IF (index(values, "E-103") <= 0) THEN
      error stop "Cube line format must preserve E-103."
   END IF
   CALL cube_read_values(values, buffer)
   IF (maxval(abs(buffer - reference)) > 1.0e-12_dp) THEN
      error stop "Cube reader must parse adjacent explicit-exponent values."
   END IF
 
   slice_reference(1:6) = reference
   slice_reference(7) = 0.27183e-123_dp
   WRITE (slice_values(1:78), cube_values_format) slice_reference(1:6)
   slice_values(79:79) = new_line("C")
   WRITE (slice_values(80:92), cube_value_format) slice_reference(7)
   CALL cube_read_values(slice_values, slice_buffer)
   IF (maxval(abs(slice_buffer - slice_reference)) > 1.0e-12_dp) THEN
      error stop "Cube reader must parse multi-line z-slices."
   END IF
 
END PROGRAM realspace_grid_cube_unittest