de/d1b/embed__main_8F_source.html

 !--------------------------------------------------------------------------------------------------!

 !   CP2K: A general program to perform molecular dynamics simulations                              !

 !   Copyright 2000-2024 CP2K developers group <https://cp2k.org>                                   !

 !                                                                                                  !

 !   SPDX-License-Identifier: GPL-2.0-or-later                                                      !

 !--------------------------------------------------------------------------------------------------!


 ! **************************************************************************************************

 !> \brief Main force create for embedding

 !> \author Vladimir Rybkin 02.2018

 ! **************************************************************************************************

 MODULE embed_main

    USE cp_files,                        ONLY: open_file

    USE cp_log_handling,                 ONLY: cp_get_default_logger,&

                                               cp_logger_create,&

                                               cp_logger_set,&

                                               cp_logger_type,&

                                               cp_to_string

    USE cp_output_handling,              ONLY: cp_print_key_unit_nr

    USE embed_environment,               ONLY: embed_init

    USE embed_types,                     ONLY: embed_env_create,&

                                               embed_env_type

    USE input_section_types,             ONLY: section_vals_type,&

                                               section_vals_val_get

    USE kinds,                           ONLY: default_path_length

    USE message_passing,                 ONLY: mp_para_env_type

 #include "./base/base_uses.f90"


    IMPLICIT NONE


    PRIVATE


 ! *** Global parameters ***

    CHARACTER(len=*), PARAMETER, PRIVATE :: moduleN = 'embed_main'


    PUBLIC :: embed_create_force_env


 CONTAINS

 ! **************************************************************************************************

 !> \brief Controls program flow for embedded calculations

 !> \param embed_env ...

 !> \param root_section ...

 !> \param para_env ...

 !> \param force_env_section ...

 !> \param n_subforce_eval ...

 !> \param use_motion_section ...

 !> \author Vladimir Rybkin

 ! **************************************************************************************************

    SUBROUTINE embed_create_force_env(embed_env, root_section, para_env, &

                                      force_env_section, n_subforce_eval, use_motion_section)


       TYPE(embed_env_type), INTENT(OUT)                  :: embed_env

       TYPE(section_vals_type), POINTER                   :: root_section

       TYPE(mp_para_env_type), POINTER                    :: para_env

       TYPE(section_vals_type), POINTER                   :: force_env_section

       INTEGER, INTENT(IN)                                :: n_subforce_eval

       LOGICAL, INTENT(IN)                                :: use_motion_section


       CHARACTER(LEN=*), PARAMETER :: routinen = 'embed_create_force_env'


       CHARACTER(len=default_path_length)                 :: c_val, input_file_path, output_file_path

       INTEGER                                            :: group_size_wish, handle, i, lp, &

                                                             n_rep_val, ngroup_wish, output_unit, &

                                                             unit_nr

       INTEGER, DIMENSION(:), POINTER                     :: group_partition, i_vals

       TYPE(cp_logger_type), POINTER                      :: logger

       TYPE(mp_para_env_type), POINTER                    :: sub_para_env


       CALL timeset(routinen, handle)

       logger => cp_get_default_logger()

       output_unit = cp_print_key_unit_nr(logger, force_env_section, "EMBED%PRINT%PROGRAM_RUN_INFO", &

                                          extension=".log")


       CALL embed_env_create(embed_env, para_env=para_env)

       ! Setup the new parallel env

       NULLIFY (group_partition)

       CALL section_vals_val_get(force_env_section, "EMBED%GROUP_PARTITION", n_rep_val=n_rep_val)


       ! Split the current communicator

       ALLOCATE (embed_env%group_distribution(0:para_env%num_pe - 1))

       ALLOCATE (sub_para_env)

       IF (n_rep_val > 0) THEN

          CALL section_vals_val_get(force_env_section, "EMBED%GROUP_PARTITION", i_vals=i_vals)

          ALLOCATE (group_partition(0:SIZE(i_vals) - 1))

          group_partition(:) = i_vals

          ngroup_wish = SIZE(i_vals)


          CALL sub_para_env%from_split(para_env, embed_env%ngroups, embed_env%group_distribution, &

                                       n_subgroups=ngroup_wish, &

                                       group_partition=group_partition)

       ELSE

          CALL section_vals_val_get(force_env_section, "EMBED%NGROUPS", n_rep_val=n_rep_val)

          IF (n_rep_val > 0) THEN

             CALL section_vals_val_get(force_env_section, "EMBED%NGROUPS", i_val=ngroup_wish)

             IF (ngroup_wish .NE. 1) cpabort("Embedding runs with NGROUP=1 and no group partitioning")

          ELSE

             ngroup_wish = n_subforce_eval

          END IF

          group_size_wish = max(1, para_env%num_pe/ngroup_wish)


          CALL sub_para_env%from_split(para_env, embed_env%ngroups, embed_env%group_distribution, &

                                       subgroup_min_size=group_size_wish)

       END IF


       IF (output_unit > 0) THEN

          WRITE (output_unit, fmt="(T2,A,T71,I10)") "EMBED_ENV| Number of created MPI groups:", embed_env%ngroups

          WRITE (output_unit, fmt="(T2,A)", advance="NO") "EMBED_ENV| Task to group correspondence:"

          DO i = 0, para_env%num_pe - 1

             IF (modulo(i, 4) == 0) WRITE (output_unit, *)

             WRITE (output_unit, fmt='(A3,I4,A3,I4,A1)', advance="NO") &

                "  (", i, " : ", embed_env%group_distribution(i), ")"

          END DO

          WRITE (output_unit, *)

       END IF

       IF (ASSOCIATED(group_partition)) THEN

          DEALLOCATE (group_partition)

       END IF

       ! Allocate para_env and handle the several loggers

       ALLOCATE (embed_env%sub_para_env(embed_env%ngroups))

       ALLOCATE (embed_env%sub_logger(embed_env%ngroups))

       ALLOCATE (embed_env%energies(n_subforce_eval))

       !

       NULLIFY (logger)

       i = embed_env%group_distribution(para_env%mepos) + 1

       ! Create sub_para_env

       embed_env%sub_para_env(i)%para_env => sub_para_env

       ! Create sub_logger

       IF (embed_env%sub_para_env(i)%para_env%is_source()) THEN

          ! Redirecting output of subforce_eval to file..

          CALL section_vals_val_get(root_section, "GLOBAL%PROJECT_NAME", &

                                    c_val=input_file_path)

          lp = len_trim(input_file_path)

          input_file_path(lp + 1:len(input_file_path)) = "-r-"// &

                                                         adjustl(cp_to_string(i))

          lp = len_trim(input_file_path)

          output_file_path = input_file_path(1:lp)//".out"

          CALL open_file(file_name=output_file_path, file_status="UNKNOWN", &

                         file_action="WRITE", file_position="APPEND", &

                         unit_number=unit_nr)

       ELSE

          unit_nr = -1

       END IF

       CALL cp_logger_create(embed_env%sub_logger(i)%p, &

                             para_env=embed_env%sub_para_env(i)%para_env, &

                             default_global_unit_nr=unit_nr, &

                             close_global_unit_on_dealloc=.false.)

       ! Try to use better names for the local log if it is not too late

       CALL section_vals_val_get(root_section, "GLOBAL%OUTPUT_FILE_NAME", &

                                 c_val=c_val)

       IF (c_val /= "") THEN

          CALL cp_logger_set(embed_env%sub_logger(i)%p, &

                             local_filename=trim(c_val)//"_localLog")

       END IF

       CALL section_vals_val_get(root_section, "GLOBAL%PROJECT", c_val=c_val)

       IF (c_val /= "") THEN

          CALL cp_logger_set(embed_env%sub_logger(i)%p, &

                             local_filename=trim(c_val)//"_localLog")

       END IF

       embed_env%sub_logger(i)%p%iter_info%project_name = c_val

       CALL section_vals_val_get(root_section, "GLOBAL%PRINT_LEVEL", &

                                 i_val=embed_env%sub_logger(i)%p%iter_info%print_level)


       ! *** initializations for the setup of the EMBED environment ***

       CALL embed_init(embed_env, root_section, para_env, force_env_section, &

                       use_motion_section)

       CALL timestop(handle)


    END SUBROUTINE embed_create_force_env


 END MODULE embed_main

modulo
static GRID_HOST_DEVICE int modulo(int a, int m)
Equivalent of Fortran's MODULO, which always return a positive number. https://gcc....
Definition: grid_common.h:117

cp_files
Utility routines to open and close files. Tracking of preconnections.
Definition: cp_files.F:16

cp_files::open_file
subroutine, public open_file(file_name, file_status, file_form, file_action, file_position, file_pad, unit_number, debug, skip_get_unit_number, file_access)
Opens the requested file using a free unit number.
Definition: cp_files.F:308

cp_log_handling
various routines to log and control the output. The idea is that decisions about where to log should ...
Definition: cp_log_handling.F:41

cp_log_handling::cp_logger_set
subroutine, public cp_logger_set(logger, local_filename, global_filename)
sets various attributes of the given logger
Definition: cp_log_handling.F:717

cp_log_handling::cp_logger_create
subroutine, public cp_logger_create(logger, para_env, print_level, default_global_unit_nr, default_local_unit_nr, global_filename, local_filename, close_global_unit_on_dealloc, iter_info, close_local_unit_on_dealloc, suffix, template_logger)
initializes a logger
Definition: cp_log_handling.F:285

cp_log_handling::cp_get_default_logger
type(cp_logger_type) function, pointer, public cp_get_default_logger()
returns the default logger
Definition: cp_log_handling.F:234

cp_output_handling
routines to handle the output, The idea is to remove the decision of wheter to output and what to out...
Definition: cp_output_handling.F:25

cp_output_handling::cp_print_key_unit_nr
integer function, public cp_print_key_unit_nr(logger, basis_section, print_key_path, extension, middle_name, local, log_filename, ignore_should_output, file_form, file_position, file_action, file_status, do_backup, on_file, is_new_file, mpi_io, fout)
...
Definition: cp_output_handling.F:803

embed_environment
initialize embed environment: clone of the mixed environment
Definition: embed_environment.F:12

embed_environment::embed_init
subroutine, public embed_init(embed_env, root_section, para_env, force_env_section, use_motion_section)
reads the input and database file for embedding
Definition: embed_environment.F:59

embed_main
Main force create for embedding.
Definition: embed_main.F:12

embed_main::embed_create_force_env
subroutine, public embed_create_force_env(embed_env, root_section, para_env, force_env_section, n_subforce_eval, use_motion_section)
Controls program flow for embedded calculations.
Definition: embed_main.F:51

embed_types
Definition: embed_types.F:8

embed_types::embed_env_create
subroutine, public embed_env_create(embed_env, para_env)
...
Definition: embed_types.F:312

input_section_types
objects that represent the structure of input sections and the data contained in an input section
Definition: input_section_types.F:15

input_section_types::section_vals_val_get
subroutine, public section_vals_val_get(section_vals, keyword_name, i_rep_section, i_rep_val, n_rep_val, val, l_val, i_val, r_val, c_val, l_vals, i_vals, r_vals, c_vals, explicit)
returns the requested value
Definition: input_section_types.F:1040

kinds
Defines the basic variable types.
Definition: kinds.F:23

kinds::default_path_length
integer, parameter, public default_path_length
Definition: kinds.F:58

message_passing
Interface to the message passing library MPI.
Definition: message_passing.F:23