d9/dad/min__basis__set_8F_source.html

!--------------------------------------------------------------------------------------------------!

!   CP2K: A general program to perform molecular dynamics simulations                              !

!   Copyright 2000-2024 CP2K developers group <https://cp2k.org>                                   !

!                                                                                                  !

!   SPDX-License-Identifier: GPL-2.0-or-later                                                      !

!--------------------------------------------------------------------------------------------------!


! **************************************************************************************************

!> \brief generate or use from input minimal basis set

!> \par History

!>      03.2023 created [JGH]

!> \author JGH

! **************************************************************************************************

MODULE min_basis_set

   USE basis_set_container_types,       ONLY: add_basis_set_to_container

   USE basis_set_types,                 ONLY: &

        allocate_sto_basis_set, create_gto_from_sto_basis, create_primitive_basis_set, &

        deallocate_gto_basis_set, deallocate_sto_basis_set, get_gto_basis_set, gto_basis_set_type, &

        init_orb_basis_set, set_sto_basis_set, srules, sto_basis_set_type

   USE cp_control_types,                ONLY: dft_control_type

   USE kinds,                           ONLY: default_string_length,&

                                              dp

   USE periodic_table,                  ONLY: get_ptable_info,&

                                              ptable

   USE qs_environment_types,            ONLY: get_qs_env,&

                                              qs_environment_type

   USE qs_interactions,                 ONLY: init_interaction_radii_orb_basis

   USE qs_kind_types,                   ONLY: get_qs_kind,&

                                              qs_kind_type

#include "./base/base_uses.f90"


   IMPLICIT NONE

   PRIVATE


   CHARACTER(len=*), PARAMETER, PRIVATE :: moduleN = 'min_basis_set'


   PUBLIC ::  create_minbas_set


! **************************************************************************************************


CONTAINS


! **************************************************************************************************

!> \brief ...

!> \param qs_env ...

!> \param unit_nr ...

!> \param basis_type ...

!> \param primitive ...

! **************************************************************************************************


   SUBROUTINE create_minbas_set(qs_env, unit_nr, basis_type, primitive)

      TYPE(qs_environment_type), POINTER                 :: qs_env

      INTEGER, INTENT(IN)                                :: unit_nr

      CHARACTER(LEN=*), INTENT(IN), OPTIONAL             :: basis_type

      INTEGER, INTENT(IN), OPTIONAL                      :: primitive


      CHARACTER(LEN=2)                                   :: element_symbol

      CHARACTER(LEN=default_string_length)               :: bname, btype

      INTEGER                                            :: ikind, lb, mao, ne, ngau, nkind, nprim, &

                                                            nsgf, ub, z

      INTEGER, DIMENSION(0:3)                            :: elcon

      INTEGER, DIMENSION(:), POINTER                     :: econf

      REAL(kind=dp)                                      :: zval

      TYPE(dft_control_type), POINTER                    :: dft_control

      TYPE(gto_basis_set_type), POINTER                  :: pbasis, refbasis

      TYPE(qs_kind_type), DIMENSION(:), POINTER          :: qs_kind_set

      TYPE(qs_kind_type), POINTER                        :: qs_kind


      IF (PRESENT(basis_type)) THEN

         btype = trim(basis_type)

      ELSE

         btype = "MIN"

      END IF

      IF (PRESENT(primitive)) THEN

         nprim = primitive

      ELSE

         nprim = -1

      END IF


      ! check for or generate reference basis

      CALL get_qs_env(qs_env=qs_env, qs_kind_set=qs_kind_set)

      CALL get_qs_env(qs_env, dft_control=dft_control)

      nkind = SIZE(qs_kind_set)

      DO ikind = 1, nkind

         qs_kind => qs_kind_set(ikind)

         CALL get_qs_kind(qs_kind, zeff=zval, elec_conf=econf, element_symbol=element_symbol)

         CALL get_ptable_info(element_symbol, ielement=z)

         NULLIFY (refbasis, pbasis)

         CALL get_qs_kind(qs_kind=qs_kind, basis_set=refbasis, basis_type=btype)

         IF (.NOT. ASSOCIATED(refbasis)) THEN

            CALL get_qs_kind(qs_kind=qs_kind, mao=mao)

            ! generate a minimal basis set

            elcon = 0

            lb = lbound(econf, 1)

            ub = ubound(econf, 1)

            ne = ub - lb

            elcon(0:ne) = econf(lb:ub)

            IF (nprim > 0) THEN

               ngau = nprim

               CALL create_min_basis(refbasis, z, elcon, mao, ngau)

               CALL create_primitive_basis_set(refbasis, pbasis)

               CALL init_interaction_radii_orb_basis(pbasis, dft_control%qs_control%eps_pgf_orb)

               CALL add_basis_set_to_container(qs_kind%basis_sets, pbasis, btype)

               CALL deallocate_gto_basis_set(refbasis)

            ELSE

               ! STO-3G

               ngau = 3

               CALL create_min_basis(refbasis, z, elcon, mao, ngau)

               CALL init_interaction_radii_orb_basis(refbasis, dft_control%qs_control%eps_pgf_orb)

               CALL add_basis_set_to_container(qs_kind%basis_sets, refbasis, btype)

            END IF

            CALL get_qs_kind(qs_kind=qs_kind, basis_set=refbasis, basis_type=btype)

         END IF

         IF (unit_nr > 0) THEN

            CALL get_gto_basis_set(refbasis, name=bname, nsgf=nsgf)

            WRITE (unit_nr, '(T2,A,A,T14,A,I4,T40,A,A24)') "Kind: ", element_symbol, "NBasFun: ", nsgf, &

               "Reference Basis: ", adjustl(trim(bname))

         END IF

      END DO


   END SUBROUTINE create_minbas_set


! **************************************************************************************************

!> \brief Creates a minimal basis set based on Slater rules

!> \param min_basis_set ...

!> \param zval ...

!> \param econf ...

!> \param mao ...

!> \param ngau ...

!> \par History

!>      03.2023 created [JGH]

! **************************************************************************************************

   SUBROUTINE create_min_basis(min_basis_set, zval, econf, mao, ngau)

      TYPE(gto_basis_set_type), POINTER                  :: min_basis_set

      INTEGER, INTENT(IN)                                :: zval

      INTEGER, DIMENSION(0:3)                            :: econf

      INTEGER, INTENT(IN)                                :: mao, ngau


      CHARACTER(len=1), DIMENSION(0:3), PARAMETER        :: lnam = (/"S", "P", "D", "F"/)


      CHARACTER(len=6)                                   :: str

      CHARACTER(len=6), DIMENSION(:), POINTER            :: sym

      CHARACTER(LEN=default_string_length)               :: bname

      INTEGER                                            :: i, iss, l, lm, n, nmao, nn, nss

      INTEGER, DIMENSION(0:3)                            :: nae, nco, npe

      INTEGER, DIMENSION(4, 7)                           :: ne

      INTEGER, DIMENSION(:), POINTER                     :: lq, nq

      REAL(kind=dp), DIMENSION(:), POINTER               :: zet

      TYPE(sto_basis_set_type), POINTER                  :: sto_basis_set


      cpassert(.NOT. ASSOCIATED(min_basis_set))

      NULLIFY (sto_basis_set)


      ! electronic configuration

      ne = 0

      DO l = 1, 4

         nn = 2*(l - 1) + 1

         DO i = l, 7

            ne(l, i) = ptable(zval)%e_conv(l - 1) - 2*nn*(i - l)

            ne(l, i) = max(ne(l, i), 0)

            ne(l, i) = min(ne(l, i), 2*nn)

         END DO

      END DO

      ! STO definition

      nae = 0

      npe = 0

      DO l = 0, 3

         nn = 2*(2*l + 1)

         nae(l) = ptable(zval)%e_conv(l)/nn

         IF (mod(ptable(zval)%e_conv(l), nn) /= 0) nae(l) = nae(l) + 1

         npe(l) = econf(l)/nn

         IF (mod(econf(l), nn) /= 0) npe(l) = npe(l) + 1

      END DO

      cpassert(all(nae - npe >= 0))

      nco = nae - npe

      ! MAO count

      nmao = 0

      DO l = 0, 3

         nmao = nmao + npe(l)*(2*l + 1)

      END DO


      IF (mao > nmao) THEN

         nmao = mao - nmao

         SELECT CASE (nmao)

         CASE (1)

            npe(0) = npe(0) + 1

         CASE (2)

            npe(0) = npe(0) + 2

         CASE (3)

            npe(1) = npe(1) + 1

         CASE (4)

            npe(0) = npe(0) + 1

            npe(1) = npe(1) + 1

         CASE (5)

            IF (npe(2) == 0) THEN

               npe(2) = npe(2) + 1

            ELSE

               npe(0) = npe(0) + 2

               npe(1) = npe(1) + 1

            END IF

         CASE (6)

            npe(0) = npe(0) + 1

            npe(2) = npe(2) + 1

         CASE (7)

            npe(0) = npe(0) + 2

            npe(2) = npe(2) + 1

         CASE (8)

            npe(0) = npe(0) + 3

            npe(2) = npe(2) + 1

         CASE (9)

            npe(0) = npe(0) + 1

            npe(1) = npe(1) + 1

            npe(2) = npe(2) + 1

         CASE DEFAULT

            cpabort("Default setting of minimal basis failed")

         END SELECT

         CALL cp_warn(__location__, "Reference basis has been adjusted according to MAO value.")

      END IF


      ! All shells should have at least 1 function

      lm = 0

      DO l = 0, 3

         IF (npe(l) > 0) lm = l

      END DO

      DO l = 0, lm

         IF (npe(l) == 0) npe(l) = 1

      END DO


      nss = sum(npe)

      ALLOCATE (sym(nss), lq(nss), nq(nss), zet(nss))

      iss = 0

      DO l = 0, 3

         DO i = 1, npe(l)

            iss = iss + 1

            lq(iss) = l

            n = nco(l) + l

            nq(iss) = n + i

            str = "      "

            WRITE (str(5:5), fmt='(I1)') nq(iss)

            str(6:6) = lnam(l)

            sym(iss) = str

            zet(iss) = srules(zval, ne, nq(iss), lq(iss))

         END DO

      END DO


      bname = adjustr(ptable(zval)%symbol)//"_MBas"

      CALL allocate_sto_basis_set(sto_basis_set)

      CALL set_sto_basis_set(sto_basis_set, name=bname, nshell=nss, nq=nq, &

                             lq=lq, zet=zet, symbol=sym)

      CALL create_gto_from_sto_basis(sto_basis_set, min_basis_set, ngau)

      min_basis_set%norm_type = 2

      CALL init_orb_basis_set(min_basis_set)

      CALL deallocate_sto_basis_set(sto_basis_set)


      DEALLOCATE (sym, lq, nq, zet)


   END SUBROUTINE create_min_basis


! **************************************************************************************************


END MODULE min_basis_set

basis_set_container_types
Definition basis_set_container_types.F:13

basis_set_container_types::add_basis_set_to_container
subroutine, public add_basis_set_to_container(container, basis_set, basis_set_type)
...
Definition basis_set_container_types.F:149

basis_set_types
Definition basis_set_types.F:15

basis_set_types::create_primitive_basis_set
subroutine, public create_primitive_basis_set(basis_set, pbasis)
...
Definition basis_set_types.F:283

basis_set_types::deallocate_gto_basis_set
subroutine, public deallocate_gto_basis_set(gto_basis_set)
...
Definition basis_set_types.F:168

basis_set_types::srules
pure real(dp) function, public srules(z, ne, n, l)
...
Definition basis_set_types.F:2509

basis_set_types::deallocate_sto_basis_set
subroutine, public deallocate_sto_basis_set(sto_basis_set)
...
Definition basis_set_types.F:1964

basis_set_types::allocate_sto_basis_set
subroutine, public allocate_sto_basis_set(sto_basis_set)
...
Definition basis_set_types.F:1950

basis_set_types::create_gto_from_sto_basis
subroutine, public create_gto_from_sto_basis(sto_basis_set, gto_basis_set, ngauss, ortho)
...
Definition basis_set_types.F:2254

basis_set_types::set_sto_basis_set
subroutine, public set_sto_basis_set(sto_basis_set, name, nshell, symbol, nq, lq, zet)
...
Definition basis_set_types.F:2041

basis_set_types::init_orb_basis_set
subroutine, public init_orb_basis_set(gto_basis_set)
Initialise a Gaussian-type orbital (GTO) basis set data set.
Definition basis_set_types.F:1057

basis_set_types::get_gto_basis_set
subroutine, public get_gto_basis_set(gto_basis_set, name, aliases, norm_type, kind_radius, ncgf, nset, nsgf, cgf_symbol, sgf_symbol, norm_cgf, set_radius, lmax, lmin, lx, ly, lz, m, ncgf_set, npgf, nsgf_set, nshell, cphi, pgf_radius, sphi, scon, zet, first_cgf, first_sgf, l, last_cgf, last_sgf, n, gcc, maxco, maxl, maxpgf, maxsgf_set, maxshell, maxso, nco_sum, npgf_sum, nshell_sum, maxder, short_kind_radius)
...
Definition basis_set_types.F:615

cp_control_types
Defines control structures, which contain the parameters and the settings for the DFT-based calculati...
Definition cp_control_types.F:12

kinds
Defines the basic variable types.
Definition kinds.F:23

kinds::dp
integer, parameter, public dp
Definition kinds.F:34

kinds::default_string_length
integer, parameter, public default_string_length
Definition kinds.F:57

min_basis_set
generate or use from input minimal basis set
Definition min_basis_set.F:14

min_basis_set::create_minbas_set
subroutine, public create_minbas_set(qs_env, unit_nr, basis_type, primitive)
...
Definition min_basis_set.F:51

periodic_table
Periodic Table related data definitions.
Definition periodic_table.F:28

periodic_table::ptable
type(atom), dimension(0:nelem), public ptable
Definition periodic_table.F:65

periodic_table::get_ptable_info
subroutine, public get_ptable_info(symbol, number, amass, ielement, covalent_radius, metallic_radius, vdw_radius, found)
Pass information about the kind given the element symbol.
Definition periodic_table.F:85

qs_environment_types
Definition qs_environment_types.F:14

qs_environment_types::get_qs_env
subroutine, public get_qs_env(qs_env, atomic_kind_set, qs_kind_set, cell, super_cell, cell_ref, use_ref_cell, kpoints, dft_control, mos, sab_orb, sab_all, qmmm, qmmm_periodic, sac_ae, sac_ppl, sac_lri, sap_ppnl, sab_vdw, sab_scp, sap_oce, sab_lrc, sab_se, sab_xtbe, sab_tbe, sab_core, sab_xb, sab_xtb_nonbond, sab_almo, sab_kp, sab_kp_nosym, particle_set, energy, force, matrix_h, matrix_h_im, matrix_ks, matrix_ks_im, matrix_vxc, run_rtp, rtp, matrix_h_kp, matrix_h_im_kp, matrix_ks_kp, matrix_ks_im_kp, matrix_vxc_kp, kinetic_kp, matrix_s_kp, matrix_w_kp, matrix_s_ri_aux_kp, matrix_s, matrix_s_ri_aux, matrix_w, matrix_p_mp2, matrix_p_mp2_admm, rho, rho_xc, pw_env, ewald_env, ewald_pw, active_space, mpools, input, para_env, blacs_env, scf_control, rel_control, kinetic, qs_charges, vppl, rho_core, rho_nlcc, rho_nlcc_g, ks_env, ks_qmmm_env, wf_history, scf_env, local_particles, local_molecules, distribution_2d, dbcsr_dist, molecule_kind_set, molecule_set, subsys, cp_subsys, oce, local_rho_set, rho_atom_set, task_list, task_list_soft, rho0_atom_set, rho0_mpole, rhoz_set, ecoul_1c, rho0_s_rs, rho0_s_gs, do_kpoints, has_unit_metric, requires_mo_derivs, mo_derivs, mo_loc_history, nkind, natom, nelectron_total, nelectron_spin, efield, neighbor_list_id, linres_control, xas_env, virial, cp_ddapc_env, cp_ddapc_ewald, outer_scf_history, outer_scf_ihistory, x_data, et_coupling, dftb_potential, results, se_taper, se_store_int_env, se_nddo_mpole, se_nonbond_env, admm_env, lri_env, lri_density, exstate_env, ec_env, dispersion_env, gcp_env, vee, rho_external, external_vxc, mask, mp2_env, bs_env, kg_env, wanniercentres, atprop, ls_scf_env, do_transport, transport_env, v_hartree_rspace, s_mstruct_changed, rho_changed, potential_changed, forces_up_to_date, mscfg_env, almo_scf_env, gradient_history, variable_history, embed_pot, spin_embed_pot, polar_env, mos_last_converged, rhs)
Get the QUICKSTEP environment.
Definition qs_environment_types.F:502

qs_interactions
Calculate the interaction radii for the operator matrix calculation.
Definition qs_interactions.F:17

qs_interactions::init_interaction_radii_orb_basis
subroutine, public init_interaction_radii_orb_basis(orb_basis_set, eps_pgf_orb, eps_pgf_short)
...
Definition qs_interactions.F:420

qs_kind_types
Define the quickstep kind type and their sub types.
Definition qs_kind_types.F:23

qs_kind_types::get_qs_kind
subroutine, public get_qs_kind(qs_kind, basis_set, basis_type, ncgf, nsgf, all_potential, tnadd_potential, gth_potential, sgp_potential, upf_potential, se_parameter, dftb_parameter, xtb_parameter, dftb3_param, zeff, elec_conf, mao, lmax_dftb, alpha_core_charge, ccore_charge, core_charge, core_charge_radius, paw_proj_set, paw_atom, hard_radius, hard0_radius, max_rad_local, covalent_radius, vdw_radius, gpw_r3d_rs_type_forced, harmonics, max_iso_not0, max_s_harm, grid_atom, ngrid_ang, ngrid_rad, lmax_rho0, dft_plus_u_atom, l_of_dft_plus_u, n_of_dft_plus_u, u_minus_j, u_of_dft_plus_u, j_of_dft_plus_u, alpha_of_dft_plus_u, beta_of_dft_plus_u, j0_of_dft_plus_u, occupation_of_dft_plus_u, dispersion, bs_occupation, magnetization, no_optimize, addel, laddel, naddel, orbitals, max_scf, eps_scf, smear, u_ramping, u_minus_j_target, eps_u_ramping, init_u_ramping_each_scf, reltmat, ghost, floating, name, element_symbol, pao_basis_size, pao_potentials, pao_descriptors, nelec)
Get attributes of an atomic kind.
Definition qs_kind_types.F:451

basis_set_types::gto_basis_set_type
Definition basis_set_types.F:71

basis_set_types::sto_basis_set_type
Definition basis_set_types.F:100

cp_control_types::dft_control_type
Definition cp_control_types.F:559

qs_environment_types::qs_environment_type
Definition qs_environment_types.F:215

qs_kind_types::qs_kind_type
Provides all information about a quickstep kind.
Definition qs_kind_types.F:171