deepmd_wrapper.F

Go to the documentation of this file.

!--------------------------------------------------------------------------------------------------!
!   CP2K: A general program to perform molecular dynamics simulations                              !
!   Copyright 2000-2025 CP2K developers group <https://cp2k.org>                                   !
!                                                                                                  !
!   SPDX-License-Identifier: GPL-2.0-or-later                                                      !
!--------------------------------------------------------------------------------------------------!
 
! **************************************************************************************************
!> \brief Interface to the DeePMD-kit or a c++ wrapper.
!> \par History
!>      07.2019 created [Yongbin Zhuang]
!>      06.2021 refactored [Yunpei Liu]
!>      10.2023 adapt to DeePMD-kit C Interface [Yunpei Liu]
!> \author Yongbin Zhuang
! **************************************************************************************************
 
MODULE deepmd_wrapper
   USE iso_c_binding,                   ONLY: c_associated,&
                                              c_char,&
                                              c_double,&
                                              c_f_pointer,&
                                              c_int,&
                                              c_null_char,&
                                              c_null_ptr,&
                                              c_ptr
   USE kinds,                           ONLY: default_string_length,&
                                              dp
#include "./base/base_uses.f90"
 
   IMPLICIT NONE
   PRIVATE
   PUBLIC :: deepmd_model_type, deepmd_model_load, deepmd_model_compute, deepmd_model_release
 
   TYPE deepmd_model_type
      PRIVATE
      TYPE(C_PTR)                          :: c_ptr = c_null_ptr
   END TYPE deepmd_model_type
 
CONTAINS
 
! **************************************************************************************************
!> \brief Load DP from a model file.
!> \param filename Path to the model file.
!> \return Pointer to the DP model.
! **************************************************************************************************
   FUNCTION deepmd_model_load(filename) RESULT(model)
      CHARACTER(len=*), INTENT(IN)                       :: filename
      TYPE(deepmd_model_type)                            :: model
 
      CHARACTER(LEN=*), PARAMETER                        :: routinen = 'deepmd_model_load'
 
      CHARACTER(LEN=1, KIND=C_CHAR), DIMENSION(:), &
         POINTER                                         :: error_f_ptr
      CHARACTER(LEN=default_string_length)               :: error_str
      INTEGER                                            :: handle, i
      TYPE(c_ptr)                                        :: error_c_ptr
      INTERFACE
         FUNCTION newdeeppot(filename) BIND(C, name="DP_NewDeepPot")
            IMPORT :: c_ptr, c_char
            CHARACTER(kind=C_CHAR), DIMENSION(*)               :: filename
            TYPE(c_ptr)                                        :: newdeeppot
         END FUNCTION
      END INTERFACE
      INTERFACE
         FUNCTION deeppotcheckok(model) BIND(C, name="DP_DeepPotCheckOK")
            IMPORT :: c_ptr
            TYPE(c_ptr), VALUE                        :: model
            TYPE(c_ptr)                               :: deeppotcheckok
         END FUNCTION deeppotcheckok
      END INTERFACE
      INTERFACE
         SUBROUTINE deletechar(ptr) BIND(C, name="DP_DeleteChar")
            IMPORT :: c_ptr
            TYPE(c_ptr), VALUE                        :: ptr
         END SUBROUTINE deletechar
      END INTERFACE
 
      CALL timeset(routinen, handle)
 
#if defined(__DEEPMD)
      cpassert(.NOT. c_associated(model%c_ptr))
      model%c_ptr = newdeeppot(filename=trim(filename)//c_null_char)
      cpassert(c_associated(model%c_ptr))
 
      ! Check for errors.
      error_c_ptr = deeppotcheckok(model%c_ptr)
      cpassert(c_associated(error_c_ptr))
      CALL c_f_pointer(error_c_ptr, error_f_ptr, shape=(/default_string_length/))
      error_str = ""
      DO i = 1, default_string_length
         IF (error_f_ptr(i) == c_null_char) EXIT
         error_str(i:i) = error_f_ptr(i)
      END DO
      CALL deletechar(error_c_ptr)
      IF (len_trim(error_str) > 0) cpabort(trim(error_str))
#else
      cpabort("CP2K was compiled without libdeepmd_c library.")
      mark_used(filename)
      mark_used(model)
      mark_used(i)
      mark_used(error_str)
      mark_used(error_c_ptr)
      mark_used(error_f_ptr)
#endif
 
      CALL timestop(handle)
   END FUNCTION deepmd_model_load
 
! **************************************************************************************************
!> \brief Compute energy, force and virial from DP.
!> \param model Pointer to the DP model.
!> \param natom Number of atoms.
!> \param coord Coordinates of the atoms.
!> \param atype Atom types.
!> \param cell Cell vectors.
!> \param energy Potential energy.
!> \param force Forces.
!> \param virial Virial tensor.
!> \param atomic_energy Atomic energies.
!> \param atomic_virial Atomic virial tensors.
! **************************************************************************************************
   SUBROUTINE deepmd_model_compute(model, natom, coord, atype, cell, energy, force, virial, &
                                   atomic_energy, atomic_virial)
      TYPE(deepmd_model_type)                            :: model
      INTEGER                                            :: natom
      REAL(kind=dp), DIMENSION(natom, 3), INTENT(IN)     :: coord
      INTEGER, DIMENSION(natom), INTENT(IN)              :: atype
      REAL(kind=dp), DIMENSION(9), INTENT(IN)            :: cell
      REAL(kind=dp), INTENT(OUT)                         :: energy
      REAL(kind=dp), DIMENSION(natom, 3), INTENT(OUT)    :: force
      REAL(kind=dp), DIMENSION(9), INTENT(OUT)           :: virial
      REAL(kind=dp), DIMENSION(natom), INTENT(OUT)       :: atomic_energy
      REAL(kind=dp), DIMENSION(natom, 9), INTENT(OUT)    :: atomic_virial
 
      CHARACTER(LEN=*), PARAMETER :: routinen = 'deepmd_model_compute'
 
      INTEGER                                            :: handle
      INTERFACE
         SUBROUTINE deeppotcompute(model, natom, coord, atype, cell, energy, force, virial, &
                                   atomic_energy, atomic_virial) BIND(C, name="DP_DeepPotCompute")
            IMPORT :: c_ptr, c_int, c_double
            TYPE(c_ptr), VALUE                                 :: model
            INTEGER(C_INT), VALUE                              :: natom
            REAL(c_double), DIMENSION(natom, 3)                :: coord
            INTEGER(C_INT), DIMENSION(natom)                   :: atype
            REAL(c_double), DIMENSION(9)                       :: cell
            REAL(c_double)                                     :: energy
            REAL(c_double), DIMENSION(natom, 3)                :: force
            REAL(c_double), DIMENSION(9)                       :: virial
            REAL(c_double), DIMENSION(natom)                   :: atomic_energy
            REAL(c_double), DIMENSION(natom, 9)                :: atomic_virial
         END SUBROUTINE
      END INTERFACE
 
      CALL timeset(routinen, handle)
 
#if defined(__DEEPMD)
      cpassert(c_associated(model%c_ptr))
      CALL deeppotcompute(model=model%c_ptr, &
                          natom=natom, &
                          coord=coord, &
                          atype=atype, &
                          cell=cell, &
                          energy=energy, &
                          force=force, &
                          virial=virial, &
                          atomic_energy=atomic_energy, &
                          atomic_virial=atomic_virial)
#else
      cpabort("CP2K was compiled without libdeepmd_c library.")
      mark_used(model)
      mark_used(natom)
      mark_used(coord)
      mark_used(atype)
      mark_used(cell)
      energy = 0.0_dp
      force = 0.0_dp
      virial = 0.0_dp
      atomic_energy = 0.0_dp
      atomic_virial = 0.0_dp
#endif
 
      CALL timestop(handle)
   END SUBROUTINE
 
! **************************************************************************************************
!> \brief Releases a deepmd model and all its ressources.
!> \param model Pointer to the DP model.
! **************************************************************************************************
   SUBROUTINE deepmd_model_release(model)
      TYPE(deepmd_model_type)                            :: model
 
      CHARACTER(LEN=*), PARAMETER :: routinen = 'deepmd_model_release'
 
      INTEGER                                            :: handle
      INTERFACE
         SUBROUTINE deletedeeppot(model) BIND(C, name="DP_DeleteDeepPot")
            IMPORT :: c_ptr
            TYPE(c_ptr), VALUE                                 :: model
         END SUBROUTINE deletedeeppot
      END INTERFACE
 
      CALL timeset(routinen, handle)
 
#if defined(__DEEPMD)
      cpassert(c_associated(model%c_ptr))
      CALL deletedeeppot(model%c_ptr)
      model%c_ptr = c_null_ptr
#else
      cpabort("CP2K was compiled without libdeepmd_c library.")
      mark_used(model)
#endif
 
      CALL timestop(handle)
   END SUBROUTINE deepmd_model_release
 
END MODULE deepmd_wrapper