mimic_loop.F

Go to the documentation of this file.

!--------------------------------------------------------------------------------------------------!
!   CP2K: A general program to perform molecular dynamics simulations                              !
!   Copyright 2000-2025 CP2K developers group <https://cp2k.org>                                   !
!                                                                                                  !
!   SPDX-License-Identifier: GPL-2.0-or-later                                                      !
!--------------------------------------------------------------------------------------------------!
 
! **************************************************************************************************
!> \brief Module containing the main loop for simulations with the MiMiC framework
!> \par History
!>      05.2025 Created [AA]
!> \author Andrej Antalik
! **************************************************************************************************
 
MODULE mimic_loop
 
   USE force_env_methods,               ONLY: force_env_calc_energy_force
   USE force_env_types,                 ONLY: force_env_type
   USE mcl_requests,                    ONLY: &
        mcl_compute_forces, mcl_exit, mcl_recv_particle_positions, &
        mcl_recv_potential_on_gridpoints, mcl_send_box_gridpoint_coords, &
        mcl_send_box_num_gridpoints, mcl_send_box_origin, mcl_send_box_vectors, &
        mcl_send_client_apiver, mcl_send_client_id, mcl_send_client_name, mcl_send_client_runtype, &
        mcl_send_density, mcl_send_energy, mcl_send_nuclear_charges, mcl_send_num_constr_angles, &
        mcl_send_num_constr_bonds, mcl_send_num_fragments, mcl_send_num_particles, &
        mcl_send_num_particles_in_fragments, mcl_send_num_particle_species, &
        mcl_send_particle_forces, mcl_send_particle_ids_in_fragments, mcl_send_particle_positions, &
        mcl_send_particle_species_ids, mcl_send_reference_charges, mcl_send_species_elements, &
        mcl_send_species_labels, mcl_send_species_masses
   USE mimic_communicator,              ONLY: mimic_communicator_type
#include "../base/base_uses.f90"
 
   IMPLICIT NONE
 
   PRIVATE
 
   PUBLIC :: do_mimic_loop
 
CONTAINS
 
! **************************************************************************************************
!> \brief The main loop for a MiMiC run
!> \param force_env ...
!> \par History
!>      5.2025 created [AA]
! **************************************************************************************************
   SUBROUTINE do_mimic_loop(force_env)
      TYPE(force_env_type), POINTER                      :: force_env
 
      CHARACTER(LEN=*), PARAMETER                        :: routinen = 'do_mimic_loop'
 
      CHARACTER(LEN=32)                                  :: request_str
      INTEGER                                            :: handle, request
      LOGICAL                                            :: is_last_step
      TYPE(mimic_communicator_type)                      :: mimic_comm
 
      CALL timeset(routinen, handle)
 
      cpassert(ASSOCIATED(force_env))
 
      CALL mimic_comm%initialize(force_env)
 
      is_last_step = .false.
      DO WHILE (.NOT. is_last_step)
         request = mimic_comm%receive_request()
 
         SELECT CASE (request)
         CASE (mcl_send_client_id)
            CALL mimic_comm%send_client_info("id")
         CASE (mcl_send_client_name)
            CALL mimic_comm%send_client_info("name")
         CASE (mcl_send_client_runtype)
            CALL mimic_comm%send_client_info("run_type")
         CASE (mcl_send_client_apiver)
            CALL mimic_comm%send_client_info("api_version")
         CASE (mcl_send_num_particles)
            CALL mimic_comm%send_value("num_atoms")
         CASE (mcl_send_num_particle_species)
            CALL mimic_comm%send_value("num_kinds")
         CASE (mcl_send_particle_species_ids)
            CALL mimic_comm%send_atom_info("kinds")
         CASE (mcl_send_num_fragments)
            CALL mimic_comm%send_value("num_fragments")
         CASE (mcl_send_num_particles_in_fragments)
            CALL mimic_comm%send_value("num_atoms_in_fragments")
         CASE (mcl_send_num_constr_bonds)
            CALL mimic_comm%send_value("num_bonds")
         CASE (mcl_send_num_constr_angles)
            CALL mimic_comm%send_value("num_angles")
         CASE (mcl_send_species_masses)
            CALL mimic_comm%send_kind_info("masses")
         CASE (mcl_send_particle_ids_in_fragments)
            CALL mimic_comm%send_atom_info("ids")
         CASE (mcl_send_species_elements)
            CALL mimic_comm%send_kind_info("elements")
         CASE (mcl_send_species_labels)
            CALL mimic_comm%send_kind_info("labels")
         CASE (mcl_send_particle_positions)
            CALL mimic_comm%send_positions()
         CASE (mcl_recv_particle_positions)
            CALL mimic_comm%receive_positions()
         CASE (mcl_send_particle_forces)
            CALL mimic_comm%send_forces()
         CASE (mcl_send_energy)
            CALL mimic_comm%send_value("energy")
         CASE (mcl_send_nuclear_charges)
            CALL mimic_comm%send_kind_info("nuclear_charges")
         CASE (mcl_send_box_num_gridpoints)
            CALL mimic_comm%send_box_info("num_gridpoints")
         CASE (mcl_send_box_origin)
            CALL mimic_comm%send_box_info("origin")
         CASE (mcl_send_box_vectors)
            CALL mimic_comm%send_box_info("box_vectors")
         CASE (mcl_send_box_gridpoint_coords)
            CALL mimic_comm%send_grid_coordinates()
         CASE (mcl_send_density)
            CALL mimic_comm%send_density()
         CASE (mcl_recv_potential_on_gridpoints)
            CALL mimic_comm%receive_potential()
         CASE (mcl_send_reference_charges)
            CALL mimic_comm%send_result("hirshfeld_charges")
         CASE (mcl_compute_forces)
            CALL force_env_calc_energy_force(force_env, calc_force=.true.)
         CASE (mcl_exit)
            is_last_step = .true.
         CASE DEFAULT
            WRITE (request_str, "(I0)") request
            cpabort("Unrecognized MiMiC request: "//trim(request_str))
         END SELECT
      END DO
 
      CALL mimic_comm%finalize()
 
      CALL timestop(handle)
 
   END SUBROUTINE do_mimic_loop
 
END MODULE mimic_loop