d5/dca/mixed__main_8F_source.html

!--------------------------------------------------------------------------------------------------!

!   CP2K: A general program to perform molecular dynamics simulations                              !

!   Copyright 2000-2025 CP2K developers group <https://cp2k.org>                                   !

!                                                                                                  !

!   SPDX-License-Identifier: GPL-2.0-or-later                                                      !

!--------------------------------------------------------------------------------------------------!


! **************************************************************************************************

!> \brief perform biased molecular dynamics (H= k H1 + (1-k) H2 [linear or general mixing)

!> \author fschiff 11.06

! **************************************************************************************************

MODULE mixed_main

   USE cp_files,                        ONLY: open_file

   USE cp_log_handling,                 ONLY: cp_get_default_logger,&

                                              cp_logger_create,&

                                              cp_logger_set,&

                                              cp_logger_type,&

                                              cp_to_string

   USE cp_output_handling,              ONLY: cp_print_key_unit_nr

   USE input_section_types,             ONLY: section_vals_type,&

                                              section_vals_val_get

   USE kinds,                           ONLY: default_path_length,&

                                              default_string_length

   USE message_passing,                 ONLY: mp_para_env_type

   USE mixed_environment,               ONLY: mixed_init

   USE mixed_environment_types,         ONLY: mixed_env_create,&

                                              mixed_environment_type

#include "./base/base_uses.f90"


   IMPLICIT NONE


   PRIVATE


   ! Global parameters

   CHARACTER(len=*), PARAMETER, PRIVATE :: moduleN = 'mixed_main'


   PUBLIC :: mixed_create_force_env


CONTAINS

! **************************************************************************************************

!> \brief Controls program flow for mixed calculations

!> \param mixed_env ...

!> \param root_section ...

!> \param para_env ...

!> \param force_env_section ...

!> \param n_subforce_eval ...

!> \param use_motion_section ...

!> \author fschiff

! **************************************************************************************************


   SUBROUTINE mixed_create_force_env(mixed_env, root_section, para_env, &

                                     force_env_section, n_subforce_eval, use_motion_section)


      TYPE(mixed_environment_type), INTENT(OUT)          :: mixed_env

      TYPE(section_vals_type), POINTER                   :: root_section

      TYPE(mp_para_env_type), POINTER                    :: para_env

      TYPE(section_vals_type), POINTER                   :: force_env_section

      INTEGER, INTENT(IN)                                :: n_subforce_eval

      LOGICAL, INTENT(IN)                                :: use_motion_section


      CHARACTER(LEN=*), PARAMETER :: routinen = 'mixed_create_force_env'


      CHARACTER(len=default_path_length)                 :: c_val, input_file_path, output_file_path

      INTEGER                                            :: group_size_wish, handle, i, lp, &

                                                            n_rep_val, ngroup_wish, output_unit, &

                                                            unit_nr

      INTEGER, DIMENSION(:), POINTER                     :: group_partition, i_vals

      TYPE(cp_logger_type), POINTER                      :: logger

      TYPE(mp_para_env_type), POINTER                    :: sub_para_env


      CALL timeset(routinen, handle)

      logger => cp_get_default_logger()

      output_unit = cp_print_key_unit_nr(logger, force_env_section, "MIXED%PRINT%PROGRAM_RUN_INFO", &

                                         extension=".log")


      CALL mixed_env_create(mixed_env, para_env=para_env)

      ! Setup the new parallel env

      NULLIFY (group_partition)

      CALL section_vals_val_get(force_env_section, "MIXED%GROUP_PARTITION", n_rep_val=n_rep_val)


      ! Split the current communicator

      ALLOCATE (mixed_env%group_distribution(0:para_env%num_pe - 1))

      ALLOCATE (sub_para_env)

      IF (n_rep_val > 0) THEN

         CALL section_vals_val_get(force_env_section, "MIXED%GROUP_PARTITION", i_vals=i_vals)

         ALLOCATE (group_partition(0:SIZE(i_vals) - 1))

         group_partition(:) = i_vals

         ngroup_wish = SIZE(i_vals)


         CALL sub_para_env%from_split(para_env, mixed_env%ngroups, mixed_env%group_distribution, &

                                      n_subgroups=ngroup_wish, &

                                      group_partition=group_partition)

      ELSE

         CALL section_vals_val_get(force_env_section, "MIXED%NGROUPS", n_rep_val=n_rep_val)

         IF (n_rep_val > 0) THEN

            CALL section_vals_val_get(force_env_section, "MIXED%NGROUPS", i_val=ngroup_wish)

         ELSE

            ngroup_wish = n_subforce_eval

         END IF

         group_size_wish = max(1, para_env%num_pe/ngroup_wish)


         CALL sub_para_env%from_split(para_env, mixed_env%ngroups, mixed_env%group_distribution, &

                                      subgroup_min_size=group_size_wish)

      END IF


      IF (output_unit > 0) THEN

         WRITE (output_unit, fmt="(T2,A,T71,I10)") "MIXED_ENV| Number of created MPI groups:", mixed_env%ngroups

         WRITE (output_unit, fmt="(T2,A)", advance="NO") "MIXED_ENV| Task to group correspondence:"

         DO i = 0, para_env%num_pe - 1

            IF (modulo(i, 4) == 0) WRITE (output_unit, *)

            WRITE (output_unit, fmt='(A3,I4,A3,I4,A1)', advance="NO") &

               "  (", i, " : ", mixed_env%group_distribution(i), ")"

         END DO

         WRITE (output_unit, *)

      END IF

      IF (ASSOCIATED(group_partition)) THEN

         DEALLOCATE (group_partition)

      END IF

      ! Allocate para_env and handle the several loggers

      ALLOCATE (mixed_env%sub_para_env(mixed_env%ngroups))

      ALLOCATE (mixed_env%sub_logger(mixed_env%ngroups))

      ALLOCATE (mixed_env%energies(n_subforce_eval))

      !

      NULLIFY (logger)

      i = mixed_env%group_distribution(para_env%mepos) + 1

      ! Create sub_para_env

      mixed_env%sub_para_env(i)%para_env => sub_para_env

      ! Create sub_logger

      IF (mixed_env%sub_para_env(i)%para_env%is_source()) THEN

         ! Redirecting output of subforce_eval to file..

         CALL section_vals_val_get(root_section, "GLOBAL%PROJECT_NAME", &

                                   c_val=input_file_path)

         lp = len_trim(input_file_path)

         input_file_path(lp + 1:len(input_file_path)) = "-r-"// &

                                                        adjustl(cp_to_string(i))

         lp = len_trim(input_file_path)

         output_file_path = input_file_path(1:lp)//".out"

         CALL open_file(file_name=output_file_path, file_status="UNKNOWN", &

                        file_action="WRITE", file_position="APPEND", &

                        unit_number=unit_nr)

      ELSE

         unit_nr = -1

      END IF

      CALL cp_logger_create(mixed_env%sub_logger(i)%p, &

                            para_env=mixed_env%sub_para_env(i)%para_env, &

                            default_global_unit_nr=unit_nr, &

                            close_global_unit_on_dealloc=.false.)

      ! Try to use better names for the local log if it is not too late

      CALL section_vals_val_get(root_section, "GLOBAL%OUTPUT_FILE_NAME", &

                                c_val=c_val)

      IF (c_val /= "") THEN

         CALL cp_logger_set(mixed_env%sub_logger(i)%p, &

                            local_filename=trim(c_val)//"_localLog")

      END IF

      CALL section_vals_val_get(root_section, "GLOBAL%PROJECT", c_val=c_val)

      IF (c_val /= "") THEN

         CALL cp_logger_set(mixed_env%sub_logger(i)%p, &

                            local_filename=trim(c_val)//"_localLog")

      END IF

      IF (len_trim(c_val) > default_string_length) THEN

         cpwarn("The project name will be truncated.")

      END IF

      mixed_env%sub_logger(i)%p%iter_info%project_name = trim(c_val)

      CALL section_vals_val_get(root_section, "GLOBAL%PRINT_LEVEL", &

                                i_val=mixed_env%sub_logger(i)%p%iter_info%print_level)


      ! Initializations for the setup of the MIXED environment

      CALL mixed_init(mixed_env, root_section, para_env, force_env_section, &

                      use_motion_section)

      CALL timestop(handle)


   END SUBROUTINE mixed_create_force_env


END MODULE mixed_main

modulo
static GRID_HOST_DEVICE int modulo(int a, int m)
Equivalent of Fortran's MODULO, which always return a positive number. https://gcc....
Definition grid_common.h:120

cp_log_handling::cp_to_string
Definition cp_log_handling.F:90

cp_files
Utility routines to open and close files. Tracking of preconnections.
Definition cp_files.F:16

cp_files::open_file
subroutine, public open_file(file_name, file_status, file_form, file_action, file_position, file_pad, unit_number, debug, skip_get_unit_number, file_access)
Opens the requested file using a free unit number.
Definition cp_files.F:308

cp_log_handling
various routines to log and control the output. The idea is that decisions about where to log should ...
Definition cp_log_handling.F:41

cp_log_handling::cp_logger_set
subroutine, public cp_logger_set(logger, local_filename, global_filename)
sets various attributes of the given logger
Definition cp_log_handling.F:717

cp_log_handling::cp_logger_create
subroutine, public cp_logger_create(logger, para_env, print_level, default_global_unit_nr, default_local_unit_nr, global_filename, local_filename, close_global_unit_on_dealloc, iter_info, close_local_unit_on_dealloc, suffix, template_logger)
initializes a logger
Definition cp_log_handling.F:285

cp_log_handling::cp_get_default_logger
type(cp_logger_type) function, pointer, public cp_get_default_logger()
returns the default logger
Definition cp_log_handling.F:234

cp_output_handling
routines to handle the output, The idea is to remove the decision of wheter to output and what to out...
Definition cp_output_handling.F:25

cp_output_handling::cp_print_key_unit_nr
integer function, public cp_print_key_unit_nr(logger, basis_section, print_key_path, extension, middle_name, local, log_filename, ignore_should_output, file_form, file_position, file_action, file_status, do_backup, on_file, is_new_file, mpi_io, fout)
...
Definition cp_output_handling.F:853

input_section_types
objects that represent the structure of input sections and the data contained in an input section
Definition input_section_types.F:15

input_section_types::section_vals_val_get
subroutine, public section_vals_val_get(section_vals, keyword_name, i_rep_section, i_rep_val, n_rep_val, val, l_val, i_val, r_val, c_val, l_vals, i_vals, r_vals, c_vals, explicit)
returns the requested value
Definition input_section_types.F:1047

kinds
Defines the basic variable types.
Definition kinds.F:23

kinds::default_string_length
integer, parameter, public default_string_length
Definition kinds.F:57

kinds::default_path_length
integer, parameter, public default_path_length
Definition kinds.F:58

message_passing
Interface to the message passing library MPI.
Definition message_passing.F:23

mixed_environment_types
Definition mixed_environment_types.F:11

mixed_environment_types::mixed_env_create
subroutine, public mixed_env_create(mixed_env, para_env)
allocates and intitializes a mixed_env
Definition mixed_environment_types.F:283

mixed_environment
initialize mixed environment
Definition mixed_environment.F:12

mixed_environment::mixed_init
subroutine, public mixed_init(mixed_env, root_section, para_env, force_env_section, use_motion_section)
reads the input and database file for mixed
Definition mixed_environment.F:61

mixed_main
perform biased molecular dynamics (H= k H1 + (1-k) H2 [linear or general mixing)
Definition mixed_main.F:12

mixed_main::mixed_create_force_env
subroutine, public mixed_create_force_env(mixed_env, root_section, para_env, force_env_section, n_subforce_eval, use_motion_section)
Controls program flow for mixed calculations.
Definition mixed_main.F:52

cp_log_handling::cp_logger_type
type of a logger, at the moment it contains just a print level starting at which level it should be l...
Definition cp_log_handling.F:140

input_section_types::section_vals_type
stores the values of a section
Definition input_section_types.F:127

message_passing::mp_para_env_type
stores all the informations relevant to an mpi environment
Definition message_passing.F:763

mixed_environment_types::mixed_environment_type
Definition mixed_environment_types.F:64