(git:6344619)
Loading...
Searching...
No Matches
efield_tb_methods.F
Go to the documentation of this file.
1!--------------------------------------------------------------------------------------------------!
2! CP2K: A general program to perform molecular dynamics simulations !
3! Copyright 2000-2026 CP2K developers group <https://cp2k.org> !
4! !
5! SPDX-License-Identifier: GPL-2.0-or-later !
6!--------------------------------------------------------------------------------------------------!
7
8! **************************************************************************************************
9!> \brief Calculation of electric field contributions in TB
10!> \author JGH
11! **************************************************************************************************
12MODULE efield_tb_methods
13 USE atomic_kind_types, ONLY: atomic_kind_type,&
14 get_atomic_kind_set
15 USE cell_types, ONLY: cell_type,&
16 pbc
17 USE cp_control_types, ONLY: dft_control_type
18 USE cp_dbcsr_api, ONLY: dbcsr_get_block_p,&
19 dbcsr_iterator_blocks_left,&
20 dbcsr_iterator_next_block,&
21 dbcsr_iterator_start,&
22 dbcsr_iterator_stop,&
23 dbcsr_iterator_type,&
24 dbcsr_p_type
25 USE kinds, ONLY: dp
26 USE kpoint_types, ONLY: get_kpoint_info,&
27 kpoint_type
28 USE mathconstants, ONLY: pi,&
29 twopi
30 USE message_passing, ONLY: mp_para_env_type
31 USE particle_types, ONLY: particle_type
32 USE qs_energy_types, ONLY: qs_energy_type
33 USE qs_environment_types, ONLY: get_qs_env,&
34 qs_environment_type,&
35 set_qs_env
36 USE qs_force_types, ONLY: qs_force_type
37 USE qs_kind_types, ONLY: qs_kind_type
38 USE qs_neighbor_list_types, ONLY: get_iterator_info,&
39 neighbor_list_iterate,&
40 neighbor_list_iterator_create,&
41 neighbor_list_iterator_p_type,&
42 neighbor_list_iterator_release,&
43 neighbor_list_set_p_type
44 USE qs_period_efield_types, ONLY: efield_berry_type,&
45 init_efield_matrices
46 USE qs_rho_types, ONLY: qs_rho_get,&
47 qs_rho_type
48 USE sap_kind_types, ONLY: release_sap_int,&
49 sap_int_type
50 USE virial_methods, ONLY: virial_pair_force
51 USE virial_types, ONLY: virial_type
52 USE xtb_coulomb, ONLY: xtb_dsint_list
53#include "../base/base_uses.f90"
54
55 IMPLICIT NONE
56
57 PRIVATE
58
59 CHARACTER(len=*), PARAMETER, PRIVATE :: moduleN = 'efield_tb_methods'
60
61 PUBLIC :: efield_tb_matrix
62
63CONTAINS
64
65! **************************************************************************************************
66!> \brief ...
67!> \param qs_env ...
68!> \param ks_matrix ...
69!> \param rho ...
70!> \param mcharge ...
71!> \param energy ...
72!> \param calculate_forces ...
73!> \param just_energy ...
74! **************************************************************************************************
75 SUBROUTINE efield_tb_matrix(qs_env, ks_matrix, rho, mcharge, energy, calculate_forces, just_energy)
76
77 TYPE(qs_environment_type), POINTER :: qs_env
78 TYPE(dbcsr_p_type), DIMENSION(:, :), POINTER :: ks_matrix
79 TYPE(qs_rho_type), POINTER :: rho
80 REAL(dp), DIMENSION(:), INTENT(in) :: mcharge
81 TYPE(qs_energy_type), POINTER :: energy
82 LOGICAL, INTENT(in) :: calculate_forces, just_energy
83
84 CHARACTER(len=*), PARAMETER :: routinen = 'efield_tb_matrix'
85
86 INTEGER :: handle
87 TYPE(dft_control_type), POINTER :: dft_control
88
89 CALL timeset(routinen, handle)
90
91 energy%efield = 0.0_dp
92 CALL get_qs_env(qs_env, dft_control=dft_control)
93 IF (dft_control%qs_control%dftb .OR. dft_control%qs_control%xtb) THEN
94 IF (dft_control%apply_period_efield) THEN
95 ! check if the periodic efield should be applied in the current step
96 IF (dft_control%period_efield%start_frame <= qs_env%sim_step .AND. &
97 (dft_control%period_efield%end_frame == -1 .OR. dft_control%period_efield%end_frame >= qs_env%sim_step)) THEN
98
99 IF (dft_control%period_efield%displacement_field) THEN
100 CALL dfield_tb_berry(qs_env, ks_matrix, rho, mcharge, energy, calculate_forces, just_energy)
101 ELSE
102 CALL efield_tb_berry(qs_env, ks_matrix, rho, mcharge, energy, calculate_forces, just_energy)
103 END IF
104 END IF
105 ELSE IF (dft_control%apply_efield) THEN
106 CALL efield_tb_local(qs_env, ks_matrix, rho, mcharge, energy, calculate_forces, just_energy)
107 ELSE IF (dft_control%apply_efield_field) THEN
108 cpabort("efield_filed")
109 END IF
110 ELSE
111 cpabort("This routine should only be called from TB")
112 END IF
113
114 CALL timestop(handle)
115
116 END SUBROUTINE efield_tb_matrix
117
118! **************************************************************************************************
119!> \brief ...
120!> \param qs_env ...
121!> \param ks_matrix ...
122!> \param rho ...
123!> \param mcharge ...
124!> \param energy ...
125!> \param calculate_forces ...
126!> \param just_energy ...
127! **************************************************************************************************
128 SUBROUTINE efield_tb_local(qs_env, ks_matrix, rho, mcharge, energy, calculate_forces, just_energy)
129 TYPE(qs_environment_type), POINTER :: qs_env
130 TYPE(dbcsr_p_type), DIMENSION(:, :), POINTER :: ks_matrix
131 TYPE(qs_rho_type), POINTER :: rho
132 REAL(dp), DIMENSION(:), INTENT(in) :: mcharge
133 TYPE(qs_energy_type), POINTER :: energy
134 LOGICAL, INTENT(in) :: calculate_forces, just_energy
135
136 CHARACTER(LEN=*), PARAMETER :: routinen = 'efield_tb_local'
137
138 INTEGER :: atom_a, atom_b, handle, ia, icol, idir, &
139 ikind, irow, ispin, jkind, natom, nspin
140 INTEGER, ALLOCATABLE, DIMENSION(:) :: atom_of_kind, kind_of
141 LOGICAL :: do_kpoints, found, use_virial
142 REAL(dp) :: charge, fdir
143 REAL(dp), DIMENSION(3) :: ci, fieldpol, fij, ria, rib
144 REAL(dp), DIMENSION(:, :), POINTER :: ds_block, ks_block, p_block, s_block
145 TYPE(atomic_kind_type), DIMENSION(:), POINTER :: atomic_kind_set
146 TYPE(cell_type), POINTER :: cell
147 TYPE(dbcsr_iterator_type) :: iter
148 TYPE(dbcsr_p_type), DIMENSION(:), POINTER :: matrix_p, matrix_s
149 TYPE(dft_control_type), POINTER :: dft_control
150 TYPE(mp_para_env_type), POINTER :: para_env
151 TYPE(particle_type), DIMENSION(:), POINTER :: particle_set
152 TYPE(qs_force_type), DIMENSION(:), POINTER :: force
153 TYPE(qs_kind_type), DIMENSION(:), POINTER :: qs_kind_set
154 TYPE(virial_type), POINTER :: virial
155
156 CALL timeset(routinen, handle)
157
158 CALL get_qs_env(qs_env, dft_control=dft_control, cell=cell, particle_set=particle_set)
159 CALL get_qs_env(qs_env=qs_env, qs_kind_set=qs_kind_set, energy=energy, para_env=para_env)
160 CALL get_qs_env(qs_env=qs_env, do_kpoints=do_kpoints, virial=virial)
161 IF (do_kpoints) THEN
162 cpabort("Local electric field with kpoints not possible. Use Berry phase periodic version")
163 END IF
164 ! disable stress calculation
165 use_virial = virial%pv_availability .AND. (.NOT. virial%pv_numer)
166 IF (use_virial) THEN
167 cpabort("Stress tensor for non-periodic E-field not possible")
168 END IF
169
170 fieldpol = dft_control%efield_fields(1)%efield%polarisation* &
171 dft_control%efield_fields(1)%efield%strength
172
173 natom = SIZE(particle_set)
174 ci = 0.0_dp
175 DO ia = 1, natom
176 charge = mcharge(ia)
177 ria = particle_set(ia)%r
178 ria = pbc(ria, cell)
179 ci(:) = ci(:) + charge*ria(:)
180 END DO
181 energy%efield = -sum(ci(:)*fieldpol(:))
182
183 IF (.NOT. just_energy) THEN
184
185 IF (calculate_forces) THEN
186 CALL get_qs_env(qs_env=qs_env, atomic_kind_set=atomic_kind_set, force=force)
187 CALL get_atomic_kind_set(atomic_kind_set, atom_of_kind=atom_of_kind, kind_of=kind_of)
188 IF (para_env%mepos == 0) THEN
189 DO ia = 1, natom
190 charge = mcharge(ia)
191 ikind = kind_of(ia)
192 atom_a = atom_of_kind(ia)
193 force(ikind)%efield(1:3, atom_a) = -charge*fieldpol(:)
194 END DO
195 ELSE
196 DO ia = 1, natom
197 ikind = kind_of(ia)
198 atom_a = atom_of_kind(ia)
199 force(ikind)%efield(1:3, atom_a) = 0.0_dp
200 END DO
201 END IF
202 CALL qs_rho_get(rho, rho_ao=matrix_p)
203 END IF
204
205 ! Update KS matrix
206 nspin = SIZE(ks_matrix, 1)
207 NULLIFY (matrix_s)
208 CALL get_qs_env(qs_env=qs_env, matrix_s=matrix_s)
209 CALL dbcsr_iterator_start(iter, matrix_s(1)%matrix)
210 DO WHILE (dbcsr_iterator_blocks_left(iter))
211 NULLIFY (ks_block, s_block, p_block)
212 CALL dbcsr_iterator_next_block(iter, irow, icol, s_block)
213 ria = particle_set(irow)%r
214 ria = pbc(ria, cell)
215 rib = particle_set(icol)%r
216 rib = pbc(rib, cell)
217 fdir = 0.5_dp*sum(fieldpol(1:3)*(ria(1:3) + rib(1:3)))
218 DO ispin = 1, nspin
219 CALL dbcsr_get_block_p(matrix=ks_matrix(ispin, 1)%matrix, &
220 row=irow, col=icol, block=ks_block, found=found)
221 ks_block = ks_block + fdir*s_block
222 cpassert(found)
223 END DO
224 IF (calculate_forces) THEN
225 ikind = kind_of(irow)
226 jkind = kind_of(icol)
227 atom_a = atom_of_kind(irow)
228 atom_b = atom_of_kind(icol)
229 fij = 0.0_dp
230 DO ispin = 1, nspin
231 CALL dbcsr_get_block_p(matrix=matrix_p(ispin)%matrix, &
232 row=irow, col=icol, block=p_block, found=found)
233 cpassert(found)
234 DO idir = 1, 3
235 CALL dbcsr_get_block_p(matrix=matrix_s(idir + 1)%matrix, &
236 row=irow, col=icol, block=ds_block, found=found)
237 cpassert(found)
238 fij(idir) = fij(idir) + sum(p_block*ds_block)
239 END DO
240 END DO
241 fdir = sum(ria(1:3)*fieldpol(1:3))
242 force(ikind)%efield(1:3, atom_a) = force(ikind)%efield(1:3, atom_a) + fdir*fij(1:3)
243 force(jkind)%efield(1:3, atom_b) = force(jkind)%efield(1:3, atom_b) - fdir*fij(1:3)
244 fdir = sum(rib(1:3)*fieldpol(1:3))
245 force(ikind)%efield(1:3, atom_a) = force(ikind)%efield(1:3, atom_a) + fdir*fij(1:3)
246 force(jkind)%efield(1:3, atom_b) = force(jkind)%efield(1:3, atom_b) - fdir*fij(1:3)
247 END IF
248 END DO
249 CALL dbcsr_iterator_stop(iter)
250
251 IF (calculate_forces) THEN
252 DO ikind = 1, SIZE(atomic_kind_set)
253 CALL para_env%sum(force(ikind)%efield)
254 END DO
255 END IF
256
257 END IF
258
259 CALL timestop(handle)
260
261 END SUBROUTINE efield_tb_local
262
263! **************************************************************************************************
264!> \brief ...
265!> \param qs_env ...
266!> \param ks_matrix ...
267!> \param rho ...
268!> \param mcharge ...
269!> \param energy ...
270!> \param calculate_forces ...
271!> \param just_energy ...
272! **************************************************************************************************
273 SUBROUTINE efield_tb_berry(qs_env, ks_matrix, rho, mcharge, energy, calculate_forces, just_energy)
274 TYPE(qs_environment_type), POINTER :: qs_env
275 TYPE(dbcsr_p_type), DIMENSION(:, :), POINTER :: ks_matrix
276 TYPE(qs_rho_type), POINTER :: rho
277 REAL(dp), DIMENSION(:), INTENT(in) :: mcharge
278 TYPE(qs_energy_type), POINTER :: energy
279 LOGICAL, INTENT(in) :: calculate_forces, just_energy
280
281 CHARACTER(LEN=*), PARAMETER :: routinen = 'efield_tb_berry'
282
283 COMPLEX(KIND=dp) :: zdeta
284 COMPLEX(KIND=dp), DIMENSION(3) :: zi
285 INTEGER :: atom_a, atom_b, handle, ia, iac, iatom, &
286 ic, icol, idir, ikind, irow, is, &
287 ispin, jatom, jkind, natom, nimg, &
288 nkind, nspin
289 INTEGER, ALLOCATABLE, DIMENSION(:) :: atom_of_kind, kind_of
290 INTEGER, DIMENSION(3) :: cellind
291 INTEGER, DIMENSION(:, :, :), POINTER :: cell_to_index
292 LOGICAL :: found, use_virial
293 REAL(kind=dp) :: charge, dd, dr, fdir, fi, strength
294 REAL(kind=dp), DIMENSION(3) :: fieldpol, fij, forcea, fpolvec, kvec, &
295 qi, rab, ria, rib, rij
296 REAL(kind=dp), DIMENSION(3, 3) :: hmat
297 REAL(kind=dp), DIMENSION(:, :), POINTER :: ds_block, ks_block, p_block, s_block
298 REAL(kind=dp), DIMENSION(:, :, :), POINTER :: dsint
299 TYPE(atomic_kind_type), DIMENSION(:), POINTER :: atomic_kind_set
300 TYPE(cell_type), POINTER :: cell
301 TYPE(dbcsr_iterator_type) :: iter
302 TYPE(dbcsr_p_type), DIMENSION(:, :), POINTER :: matrix_p, matrix_s
303 TYPE(dft_control_type), POINTER :: dft_control
304 TYPE(kpoint_type), POINTER :: kpoints
305 TYPE(mp_para_env_type), POINTER :: para_env
306 TYPE(neighbor_list_iterator_p_type), &
307 DIMENSION(:), POINTER :: nl_iterator
308 TYPE(neighbor_list_set_p_type), DIMENSION(:), &
309 POINTER :: sab_orb
310 TYPE(particle_type), DIMENSION(:), POINTER :: particle_set
311 TYPE(qs_force_type), DIMENSION(:), POINTER :: force
312 TYPE(qs_kind_type), DIMENSION(:), POINTER :: qs_kind_set
313 TYPE(sap_int_type), DIMENSION(:), POINTER :: sap_int
314 TYPE(virial_type), POINTER :: virial
315
316 CALL timeset(routinen, handle)
317
318 NULLIFY (dft_control, cell, particle_set)
319 CALL get_qs_env(qs_env, dft_control=dft_control, cell=cell, &
320 particle_set=particle_set, virial=virial)
321 NULLIFY (qs_kind_set, para_env, sab_orb)
322 CALL get_qs_env(qs_env=qs_env, qs_kind_set=qs_kind_set, &
323 energy=energy, para_env=para_env, sab_orb=sab_orb)
324
325 ! calculate stress only if forces requested also
326 use_virial = virial%pv_availability .AND. (.NOT. virial%pv_numer)
327 use_virial = use_virial .AND. calculate_forces
328
329 ! if an intensities list is given, select the value for the current step
330 strength = dft_control%period_efield%strength
331 IF (ALLOCATED(dft_control%period_efield%strength_list)) THEN
332 strength = dft_control%period_efield%strength_list(mod(qs_env%sim_step &
333 - dft_control%period_efield%start_frame, SIZE(dft_control%period_efield%strength_list)) + 1)
334 END IF
335
336 fieldpol = dft_control%period_efield%polarisation
337 fieldpol = fieldpol/norm2(fieldpol)
338 fieldpol = -fieldpol*strength
339 hmat = cell%hmat(:, :)/twopi
340 DO idir = 1, 3
341 fpolvec(idir) = fieldpol(1)*hmat(1, idir) + fieldpol(2)*hmat(2, idir) + fieldpol(3)*hmat(3, idir)
342 END DO
343
344 natom = SIZE(particle_set)
345 nspin = SIZE(ks_matrix, 1)
346
347 zi(:) = cmplx(1._dp, 0._dp, dp)
348 DO ia = 1, natom
349 charge = mcharge(ia)
350 ria = particle_set(ia)%r
351 DO idir = 1, 3
352 kvec(:) = twopi*cell%h_inv(idir, :)
353 dd = sum(kvec(:)*ria(:))
354 zdeta = cmplx(cos(dd), sin(dd), kind=dp)**charge
355 zi(idir) = zi(idir)*zdeta
356 END DO
357 END DO
358 qi = aimag(log(zi))
359 energy%efield = sum(fpolvec(:)*qi(:))
360
361 IF (.NOT. just_energy) THEN
362 CALL get_qs_env(qs_env=qs_env, matrix_s_kp=matrix_s)
363 CALL qs_rho_get(rho, rho_ao_kp=matrix_p)
364
365 nimg = dft_control%nimages
366 NULLIFY (cell_to_index)
367 IF (nimg > 1) THEN
368 NULLIFY (kpoints)
369 CALL get_qs_env(qs_env=qs_env, kpoints=kpoints)
370 CALL get_kpoint_info(kpoint=kpoints, cell_to_index=cell_to_index)
371 END IF
372
373 IF (calculate_forces) THEN
374 CALL get_qs_env(qs_env=qs_env, atomic_kind_set=atomic_kind_set, force=force)
375 CALL get_atomic_kind_set(atomic_kind_set, atom_of_kind=atom_of_kind, kind_of=kind_of)
376 IF (para_env%mepos == 0) THEN
377 DO ia = 1, natom
378 charge = mcharge(ia)
379 iatom = atom_of_kind(ia)
380 ikind = kind_of(ia)
381 force(ikind)%efield(:, iatom) = fieldpol(:)*charge
382 IF (use_virial) THEN
383 ria = particle_set(ia)%r
384 ria = pbc(ria, cell)
385 forcea(1:3) = fieldpol(1:3)*charge
386 CALL virial_pair_force(virial%pv_virial, -0.5_dp, forcea, ria)
387 CALL virial_pair_force(virial%pv_virial, -0.5_dp, ria, forcea)
388 END IF
389 END DO
390 ELSE
391 DO ia = 1, natom
392 iatom = atom_of_kind(ia)
393 ikind = kind_of(ia)
394 force(ikind)%efield(:, iatom) = 0.0_dp
395 END DO
396 END IF
397 END IF
398
399 IF (nimg == 1) THEN
400 ! no k-points; all matrices have been transformed to periodic bsf
401 CALL dbcsr_iterator_start(iter, matrix_s(1, 1)%matrix)
402 DO WHILE (dbcsr_iterator_blocks_left(iter))
403 CALL dbcsr_iterator_next_block(iter, irow, icol, s_block)
404
405 fdir = 0.0_dp
406 ria = particle_set(irow)%r
407 rib = particle_set(icol)%r
408 DO idir = 1, 3
409 kvec(:) = twopi*cell%h_inv(idir, :)
410 dd = sum(kvec(:)*ria(:))
411 zdeta = cmplx(cos(dd), sin(dd), kind=dp)
412 fdir = fdir + fpolvec(idir)*aimag(log(zdeta))
413 dd = sum(kvec(:)*rib(:))
414 zdeta = cmplx(cos(dd), sin(dd), kind=dp)
415 fdir = fdir + fpolvec(idir)*aimag(log(zdeta))
416 END DO
417
418 DO is = 1, nspin
419 NULLIFY (ks_block)
420 CALL dbcsr_get_block_p(matrix=ks_matrix(is, 1)%matrix, &
421 row=irow, col=icol, block=ks_block, found=found)
422 cpassert(found)
423 ks_block = ks_block - 0.5_dp*fdir*s_block
424 END DO
425 IF (calculate_forces .AND. irow /= icol) THEN
426 ikind = kind_of(irow)
427 jkind = kind_of(icol)
428 atom_a = atom_of_kind(irow)
429 atom_b = atom_of_kind(icol)
430 fij = 0.0_dp
431 DO ispin = 1, nspin
432 CALL dbcsr_get_block_p(matrix=matrix_p(ispin, 1)%matrix, &
433 row=irow, col=icol, block=p_block, found=found)
434 cpassert(found)
435 DO idir = 1, 3
436 CALL dbcsr_get_block_p(matrix=matrix_s(idir + 1, 1)%matrix, &
437 row=irow, col=icol, block=ds_block, found=found)
438 cpassert(found)
439 fij(idir) = fij(idir) - sum(p_block*ds_block)
440 END DO
441 END DO
442 force(ikind)%efield(1:3, atom_a) = force(ikind)%efield(1:3, atom_a) + fdir*fij(1:3)
443 force(jkind)%efield(1:3, atom_b) = force(jkind)%efield(1:3, atom_b) - fdir*fij(1:3)
444 END IF
445 END DO
446 CALL dbcsr_iterator_stop(iter)
447 !
448 ! stress tensor for Gamma point needs to recalculate overlap integral derivatives
449 !
450 IF (use_virial) THEN
451 ! derivative overlap integral (non collapsed)
452 NULLIFY (sap_int)
453 IF (dft_control%qs_control%dftb) THEN
454 cpabort("DFTB stress tensor for periodic efield not implemented")
455 ELSE IF (dft_control%qs_control%xtb) THEN
456 CALL xtb_dsint_list(qs_env, sap_int)
457 ELSE
458 cpabort("TB method unknown")
459 END IF
460 !
461 CALL get_qs_env(qs_env, nkind=nkind)
462 DO ikind = 1, nkind
463 DO jkind = 1, nkind
464 iac = ikind + nkind*(jkind - 1)
465 IF (.NOT. ASSOCIATED(sap_int(iac)%alist)) cycle
466 DO ia = 1, sap_int(iac)%nalist
467 IF (.NOT. ASSOCIATED(sap_int(iac)%alist(ia)%clist)) cycle
468 iatom = sap_int(iac)%alist(ia)%aatom
469 DO ic = 1, sap_int(iac)%alist(ia)%nclist
470 jatom = sap_int(iac)%alist(ia)%clist(ic)%catom
471 rij = sap_int(iac)%alist(ia)%clist(ic)%rac
472 dr = sqrt(sum(rij(:)**2))
473 IF (dr > 1.e-6_dp) THEN
474 dsint => sap_int(iac)%alist(ia)%clist(ic)%acint
475 icol = max(iatom, jatom)
476 irow = min(iatom, jatom)
477 IF (irow == iatom) rij = -rij
478 fdir = 0.0_dp
479 ria = particle_set(irow)%r
480 rib = particle_set(icol)%r
481 DO idir = 1, 3
482 kvec(:) = twopi*cell%h_inv(idir, :)
483 dd = sum(kvec(:)*ria(:))
484 zdeta = cmplx(cos(dd), sin(dd), kind=dp)
485 fdir = fdir - fpolvec(idir)*aimag(log(zdeta))
486 dd = sum(kvec(:)*rib(:))
487 zdeta = cmplx(cos(dd), sin(dd), kind=dp)
488 fdir = fdir - fpolvec(idir)*aimag(log(zdeta))
489 END DO
490 fi = 1.0_dp
491 IF (iatom == jatom) fi = 0.5_dp
492 DO ispin = 1, nspin
493 NULLIFY (p_block)
494 CALL dbcsr_get_block_p(matrix=matrix_p(ispin, 1)%matrix, &
495 row=irow, col=icol, block=p_block, found=found)
496 cpassert(found)
497 fij = 0.0_dp
498 DO idir = 1, 3
499 IF (irow == iatom) THEN
500 fij(idir) = sum(p_block*dsint(:, :, idir))
501 ELSE
502 fij(idir) = sum(transpose(p_block)*dsint(:, :, idir))
503 END IF
504 END DO
505 IF (irow == iatom) fij = -fij
506 CALL virial_pair_force(virial%pv_virial, fi, fdir*fij(1:3), rij)
507 END DO
508 END IF
509 END DO
510 END DO
511 END DO
512 END DO
513 CALL release_sap_int(sap_int)
514 END IF
515 ELSE
516 CALL neighbor_list_iterator_create(nl_iterator, sab_orb)
517 DO WHILE (neighbor_list_iterate(nl_iterator) == 0)
518 CALL get_iterator_info(nl_iterator, ikind=ikind, jkind=jkind, &
519 iatom=iatom, jatom=jatom, r=rab, cell=cellind)
520
521 icol = max(iatom, jatom)
522 irow = min(iatom, jatom)
523
524 ic = cell_to_index(cellind(1), cellind(2), cellind(3))
525 cpassert(ic > 0)
526
527 fdir = 0.0_dp
528 ria = particle_set(irow)%r
529 rib = particle_set(icol)%r
530 DO idir = 1, 3
531 kvec(:) = twopi*cell%h_inv(idir, :)
532 dd = sum(kvec(:)*ria(:))
533 zdeta = cmplx(cos(dd), sin(dd), kind=dp)
534 fdir = fdir + fpolvec(idir)*aimag(log(zdeta))
535 dd = sum(kvec(:)*rib(:))
536 zdeta = cmplx(cos(dd), sin(dd), kind=dp)
537 fdir = fdir + fpolvec(idir)*aimag(log(zdeta))
538 END DO
539
540 NULLIFY (s_block)
541 CALL dbcsr_get_block_p(matrix=matrix_s(1, ic)%matrix, &
542 row=irow, col=icol, block=s_block, found=found)
543 cpassert(found)
544 DO is = 1, nspin
545 NULLIFY (ks_block)
546 CALL dbcsr_get_block_p(matrix=ks_matrix(is, ic)%matrix, &
547 row=irow, col=icol, block=ks_block, found=found)
548 cpassert(found)
549 ks_block = ks_block - 0.5_dp*fdir*s_block
550 END DO
551 IF (calculate_forces) THEN
552 atom_a = atom_of_kind(iatom)
553 atom_b = atom_of_kind(jatom)
554 fij = 0.0_dp
555 DO ispin = 1, nspin
556 CALL dbcsr_get_block_p(matrix=matrix_p(ispin, ic)%matrix, &
557 row=irow, col=icol, block=p_block, found=found)
558 cpassert(found)
559 DO idir = 1, 3
560 CALL dbcsr_get_block_p(matrix=matrix_s(idir + 1, ic)%matrix, &
561 row=irow, col=icol, block=ds_block, found=found)
562 cpassert(found)
563 fij(idir) = fij(idir) - sum(p_block*ds_block)
564 END DO
565 END DO
566 IF (irow == iatom) fij = -fij
567 force(ikind)%efield(1:3, atom_a) = force(ikind)%efield(1:3, atom_a) - fdir*fij(1:3)
568 force(jkind)%efield(1:3, atom_b) = force(jkind)%efield(1:3, atom_b) + fdir*fij(1:3)
569 IF (use_virial) THEN
570 dr = sqrt(sum(rab(:)**2))
571 IF (dr > 1.e-6_dp) THEN
572 fi = 1.0_dp
573 IF (iatom == jatom) fi = 0.5_dp
574 CALL virial_pair_force(virial%pv_virial, fi, -fdir*fij(1:3), rab)
575 END IF
576 END IF
577 END IF
578 END DO
579 CALL neighbor_list_iterator_release(nl_iterator)
580 END IF
581
582 IF (calculate_forces) THEN
583 DO ikind = 1, SIZE(atomic_kind_set)
584 CALL para_env%sum(force(ikind)%efield)
585 END DO
586 END IF
587
588 END IF
589
590 CALL timestop(handle)
591
592 END SUBROUTINE efield_tb_berry
593
594! **************************************************************************************************
595!> \brief ...
596!> \param qs_env ...
597!> \param ks_matrix ...
598!> \param rho ...
599!> \param mcharge ...
600!> \param energy ...
601!> \param calculate_forces ...
602!> \param just_energy ...
603! **************************************************************************************************
604 SUBROUTINE dfield_tb_berry(qs_env, ks_matrix, rho, mcharge, energy, calculate_forces, just_energy)
605 TYPE(qs_environment_type), POINTER :: qs_env
606 TYPE(dbcsr_p_type), DIMENSION(:, :), POINTER :: ks_matrix
607 TYPE(qs_rho_type), POINTER :: rho
608 REAL(dp), DIMENSION(:), INTENT(in) :: mcharge
609 TYPE(qs_energy_type), POINTER :: energy
610 LOGICAL, INTENT(in) :: calculate_forces, just_energy
611
612 CHARACTER(LEN=*), PARAMETER :: routinen = 'dfield_tb_berry', smoothness_warning = &
613 "Large change of e-field energy detected. Correct for non-smooth energy surface"
614
615 COMPLEX(KIND=dp) :: zdeta
616 COMPLEX(KIND=dp), DIMENSION(3) :: zi
617 INTEGER :: atom_a, atom_b, handle, i, ia, iatom, &
618 ic, icol, idir, ikind, irow, is, &
619 ispin, jatom, jkind, natom, nimg, nspin
620 INTEGER, ALLOCATABLE, DIMENSION(:) :: atom_of_kind, kind_of
621 INTEGER, DIMENSION(3) :: cellind
622 INTEGER, DIMENSION(:, :, :), POINTER :: cell_to_index
623 LOGICAL :: found, use_virial
624 REAL(kind=dp) :: charge, dd, ener_field, fdir, omega, &
625 strength
626 REAL(kind=dp), DIMENSION(3) :: ci, cqi, dfilter, di, fieldpol, fij, &
627 hdi, kvec, qi, rab, ria, rib
628 REAL(kind=dp), DIMENSION(3, 3) :: hmat
629 REAL(kind=dp), DIMENSION(:, :), POINTER :: ds_block, ks_block, p_block, s_block
630 TYPE(atomic_kind_type), DIMENSION(:), POINTER :: atomic_kind_set
631 TYPE(cell_type), POINTER :: cell
632 TYPE(dbcsr_iterator_type) :: iter
633 TYPE(dbcsr_p_type), DIMENSION(:, :), POINTER :: matrix_p, matrix_s
634 TYPE(dft_control_type), POINTER :: dft_control
635 TYPE(efield_berry_type), POINTER :: efield
636 TYPE(kpoint_type), POINTER :: kpoints
637 TYPE(mp_para_env_type), POINTER :: para_env
638 TYPE(neighbor_list_iterator_p_type), &
639 DIMENSION(:), POINTER :: nl_iterator
640 TYPE(neighbor_list_set_p_type), DIMENSION(:), &
641 POINTER :: sab_orb
642 TYPE(particle_type), DIMENSION(:), POINTER :: particle_set
643 TYPE(qs_force_type), DIMENSION(:), POINTER :: force
644 TYPE(qs_kind_type), DIMENSION(:), POINTER :: qs_kind_set
645 TYPE(virial_type), POINTER :: virial
646
647 CALL timeset(routinen, handle)
648
649 NULLIFY (dft_control, cell, particle_set)
650 CALL get_qs_env(qs_env, dft_control=dft_control, cell=cell, &
651 particle_set=particle_set, virial=virial)
652 NULLIFY (qs_kind_set, para_env, sab_orb)
653 CALL get_qs_env(qs_env=qs_env, qs_kind_set=qs_kind_set, &
654 efield=efield, energy=energy, para_env=para_env, sab_orb=sab_orb)
655
656 ! efield history
657 CALL init_efield_matrices(efield)
658 CALL set_qs_env(qs_env, efield=efield)
659
660 ! calculate stress only if forces requested also
661 use_virial = virial%pv_availability .AND. (.NOT. virial%pv_numer)
662 use_virial = use_virial .AND. calculate_forces
663 ! disable stress calculation
664 IF (use_virial) THEN
665 cpabort("Stress tensor for periodic D-field not implemented")
666 END IF
667
668 dfilter(1:3) = dft_control%period_efield%d_filter(1:3)
669
670 ! if an intensities list is given, select the value for the current step
671 strength = dft_control%period_efield%strength
672 IF (ALLOCATED(dft_control%period_efield%strength_list)) THEN
673 strength = dft_control%period_efield%strength_list(mod(qs_env%sim_step &
674 - dft_control%period_efield%start_frame, SIZE(dft_control%period_efield%strength_list)) + 1)
675 END IF
676
677 fieldpol = dft_control%period_efield%polarisation
678 fieldpol = fieldpol/norm2(fieldpol)
679 fieldpol = fieldpol*strength
680
681 omega = cell%deth
682 hmat = cell%hmat(:, :)/twopi
683
684 natom = SIZE(particle_set)
685 nspin = SIZE(ks_matrix, 1)
686
687 zi(:) = cmplx(1._dp, 0._dp, dp)
688 DO ia = 1, natom
689 charge = mcharge(ia)
690 ria = particle_set(ia)%r
691 DO idir = 1, 3
692 kvec(:) = twopi*cell%h_inv(idir, :)
693 dd = sum(kvec(:)*ria(:))
694 zdeta = cmplx(cos(dd), sin(dd), kind=dp)**charge
695 zi(idir) = zi(idir)*zdeta
696 END DO
697 END DO
698 qi = aimag(log(zi))
699
700 ! make sure the total normalized polarization is within [-1:1]
701 DO idir = 1, 3
702 cqi(idir) = qi(idir)/omega
703 IF (cqi(idir) > pi) cqi(idir) = cqi(idir) - twopi
704 IF (cqi(idir) < -pi) cqi(idir) = cqi(idir) + twopi
705 ! now check for log branch
706 IF (calculate_forces) THEN
707 IF (abs(efield%polarisation(idir) - cqi(idir)) > pi) THEN
708 di(idir) = (efield%polarisation(idir) - cqi(idir))/pi
709 DO i = 1, 10
710 cqi(idir) = cqi(idir) + sign(1.0_dp, di(idir))*twopi
711 IF (abs(efield%polarisation(idir) - cqi(idir)) < pi) EXIT
712 END DO
713 END IF
714 END IF
715 cqi(idir) = cqi(idir)*omega
716 END DO
717 DO idir = 1, 3
718 ci(idir) = 0.0_dp
719 DO i = 1, 3
720 ci(idir) = ci(idir) + hmat(idir, i)*cqi(i)
721 END DO
722 END DO
723 ! update the references
724 IF (calculate_forces) THEN
725 ener_field = sum(ci)
726 ! check for smoothness of energy surface
727 IF (abs(efield%field_energy - ener_field) > pi*abs(sum(hmat))) THEN
728 cpwarn(smoothness_warning)
729 END IF
730 efield%field_energy = ener_field
731 efield%polarisation(:) = cqi(:)/omega
732 END IF
733
734 ! Energy
735 ener_field = 0.0_dp
736 DO idir = 1, 3
737 ener_field = ener_field + dfilter(idir)*(fieldpol(idir) - 2._dp*twopi/omega*ci(idir))**2
738 END DO
739 energy%efield = 0.25_dp/twopi*ener_field
740
741 IF (.NOT. just_energy) THEN
742 di(:) = -(fieldpol(:) - 2._dp*twopi/omega*ci(:))*dfilter(:)/omega
743
744 CALL get_qs_env(qs_env=qs_env, matrix_s_kp=matrix_s)
745 CALL qs_rho_get(rho, rho_ao_kp=matrix_p)
746
747 nimg = dft_control%nimages
748 NULLIFY (cell_to_index)
749 IF (nimg > 1) THEN
750 NULLIFY (kpoints)
751 CALL get_qs_env(qs_env=qs_env, kpoints=kpoints)
752 CALL get_kpoint_info(kpoint=kpoints, cell_to_index=cell_to_index)
753 END IF
754
755 IF (calculate_forces) THEN
756 CALL get_qs_env(qs_env=qs_env, atomic_kind_set=atomic_kind_set, force=force)
757 CALL get_atomic_kind_set(atomic_kind_set, atom_of_kind=atom_of_kind, kind_of=kind_of)
758 IF (para_env%mepos == 0) THEN
759 DO ia = 1, natom
760 charge = mcharge(ia)
761 iatom = atom_of_kind(ia)
762 ikind = kind_of(ia)
763 force(ikind)%efield(:, iatom) = force(ikind)%efield(:, iatom) + di(:)*charge
764 END DO
765 END IF
766 END IF
767
768 IF (nimg == 1) THEN
769 ! no k-points; all matrices have been transformed to periodic bsf
770 CALL dbcsr_iterator_start(iter, matrix_s(1, 1)%matrix)
771 DO WHILE (dbcsr_iterator_blocks_left(iter))
772 CALL dbcsr_iterator_next_block(iter, irow, icol, s_block)
773
774 DO idir = 1, 3
775 hdi(idir) = -sum(di(1:3)*hmat(1:3, idir))
776 END DO
777 fdir = 0.0_dp
778 ria = particle_set(irow)%r
779 rib = particle_set(icol)%r
780 DO idir = 1, 3
781 kvec(:) = twopi*cell%h_inv(idir, :)
782 dd = sum(kvec(:)*ria(:))
783 zdeta = cmplx(cos(dd), sin(dd), kind=dp)
784 fdir = fdir + hdi(idir)*aimag(log(zdeta))
785 dd = sum(kvec(:)*rib(:))
786 zdeta = cmplx(cos(dd), sin(dd), kind=dp)
787 fdir = fdir + hdi(idir)*aimag(log(zdeta))
788 END DO
789
790 DO is = 1, nspin
791 NULLIFY (ks_block)
792 CALL dbcsr_get_block_p(matrix=ks_matrix(is, 1)%matrix, &
793 row=irow, col=icol, block=ks_block, found=found)
794 cpassert(found)
795 ks_block = ks_block + 0.5_dp*fdir*s_block
796 END DO
797 IF (calculate_forces) THEN
798 ikind = kind_of(irow)
799 jkind = kind_of(icol)
800 atom_a = atom_of_kind(irow)
801 atom_b = atom_of_kind(icol)
802 fij = 0.0_dp
803 DO ispin = 1, nspin
804 CALL dbcsr_get_block_p(matrix=matrix_p(ispin, 1)%matrix, &
805 row=irow, col=icol, block=p_block, found=found)
806 cpassert(found)
807 DO idir = 1, 3
808 CALL dbcsr_get_block_p(matrix=matrix_s(idir + 1, 1)%matrix, &
809 row=irow, col=icol, block=ds_block, found=found)
810 cpassert(found)
811 fij(idir) = fij(idir) + sum(p_block*ds_block)
812 END DO
813 END DO
814 force(ikind)%efield(1:3, atom_a) = force(ikind)%efield(1:3, atom_a) + fdir*fij(1:3)
815 force(jkind)%efield(1:3, atom_b) = force(jkind)%efield(1:3, atom_b) - fdir*fij(1:3)
816 END IF
817
818 END DO
819 CALL dbcsr_iterator_stop(iter)
820 ELSE
821 CALL neighbor_list_iterator_create(nl_iterator, sab_orb)
822 DO WHILE (neighbor_list_iterate(nl_iterator) == 0)
823 CALL get_iterator_info(nl_iterator, ikind=ikind, jkind=jkind, &
824 iatom=iatom, jatom=jatom, r=rab, cell=cellind)
825
826 icol = max(iatom, jatom)
827 irow = min(iatom, jatom)
828
829 ic = cell_to_index(cellind(1), cellind(2), cellind(3))
830 cpassert(ic > 0)
831
832 DO idir = 1, 3
833 hdi(idir) = -sum(di(1:3)*hmat(1:3, idir))
834 END DO
835 fdir = 0.0_dp
836 ria = particle_set(irow)%r
837 rib = particle_set(icol)%r
838 DO idir = 1, 3
839 kvec(:) = twopi*cell%h_inv(idir, :)
840 dd = sum(kvec(:)*ria(:))
841 zdeta = cmplx(cos(dd), sin(dd), kind=dp)
842 fdir = fdir + hdi(idir)*aimag(log(zdeta))
843 dd = sum(kvec(:)*rib(:))
844 zdeta = cmplx(cos(dd), sin(dd), kind=dp)
845 fdir = fdir + hdi(idir)*aimag(log(zdeta))
846 END DO
847
848 NULLIFY (s_block)
849 CALL dbcsr_get_block_p(matrix=matrix_s(1, ic)%matrix, &
850 row=irow, col=icol, block=s_block, found=found)
851 cpassert(found)
852 DO is = 1, nspin
853 NULLIFY (ks_block)
854 CALL dbcsr_get_block_p(matrix=ks_matrix(is, ic)%matrix, &
855 row=irow, col=icol, block=ks_block, found=found)
856 cpassert(found)
857 ks_block = ks_block + 0.5_dp*fdir*s_block
858 END DO
859 IF (calculate_forces) THEN
860 atom_a = atom_of_kind(iatom)
861 atom_b = atom_of_kind(jatom)
862 fij = 0.0_dp
863 DO ispin = 1, nspin
864 CALL dbcsr_get_block_p(matrix=matrix_p(ispin, ic)%matrix, &
865 row=irow, col=icol, block=p_block, found=found)
866 cpassert(found)
867 DO idir = 1, 3
868 CALL dbcsr_get_block_p(matrix=matrix_s(idir + 1, ic)%matrix, &
869 row=irow, col=icol, block=ds_block, found=found)
870 cpassert(found)
871 fij(idir) = fij(idir) + sum(p_block*ds_block)
872 END DO
873 END DO
874 IF (irow == iatom) fij = -fij
875 force(ikind)%efield(1:3, atom_a) = force(ikind)%efield(1:3, atom_a) - fdir*fij(1:3)
876 force(jkind)%efield(1:3, atom_b) = force(jkind)%efield(1:3, atom_b) + fdir*fij(1:3)
877 END IF
878
879 END DO
880 CALL neighbor_list_iterator_release(nl_iterator)
881 END IF
882
883 END IF
884
885 CALL timestop(handle)
886
887 END SUBROUTINE dfield_tb_berry
888
889END MODULE efield_tb_methods
cell_types::pbc
Definition cell_types.F:105
sap_kind_types::release_sap_int
Definition sap_kind_types.F:110
atomic_kind_types
Define the atomic kind types and their sub types.
Definition atomic_kind_types.F:23
atomic_kind_types::get_atomic_kind_set
subroutine, public get_atomic_kind_set(atomic_kind_set, atom_of_kind, kind_of, natom_of_kind, maxatom, natom, nshell, fist_potential_present, shell_present, shell_adiabatic, shell_check_distance, damping_present)
Get attributes of an atomic kind set.
Definition atomic_kind_types.F:223
cell_types
Handles all functions related to the CELL.
Definition cell_types.F:15
cp_control_types
Defines control structures, which contain the parameters and the settings for the DFT-based calculati...
Definition cp_control_types.F:12
cp_dbcsr_api
Definition cp_dbcsr_api.F:8
cp_dbcsr_api::dbcsr_iterator_blocks_left
logical function, public dbcsr_iterator_blocks_left(iterator)
...
Definition cp_dbcsr_api.F:944
cp_dbcsr_api::dbcsr_iterator_stop
subroutine, public dbcsr_iterator_stop(iterator)
...
Definition cp_dbcsr_api.F:1050
cp_dbcsr_api::dbcsr_get_block_p
subroutine, public dbcsr_get_block_p(matrix, row, col, block, found, row_size, col_size)
...
Definition cp_dbcsr_api.F:693
cp_dbcsr_api::dbcsr_iterator_next_block
subroutine, public dbcsr_iterator_next_block(iterator, row, column, block, block_number_argument_has_been_removed, row_size, col_size, row_offset, col_offset, transposed)
...
Definition cp_dbcsr_api.F:971
cp_dbcsr_api::dbcsr_iterator_start
subroutine, public dbcsr_iterator_start(iterator, matrix, shared, dynamic, dynamic_byrows)
...
Definition cp_dbcsr_api.F:1012
efield_tb_methods
Calculation of electric field contributions in TB.
Definition efield_tb_methods.F:12
efield_tb_methods::efield_tb_matrix
subroutine, public efield_tb_matrix(qs_env, ks_matrix, rho, mcharge, energy, calculate_forces, just_energy)
...
Definition efield_tb_methods.F:76
kinds
Defines the basic variable types.
Definition kinds.F:23
kinds::dp
integer, parameter, public dp
Definition kinds.F:34
kpoint_types
Types and basic routines needed for a kpoint calculation.
Definition kpoint_types.F:15
kpoint_types::get_kpoint_info
subroutine, public get_kpoint_info(kpoint, kp_scheme, nkp_grid, kp_shift, symmetry, verbose, full_grid, use_real_wfn, eps_geo, parallel_group_size, kp_range, nkp, xkp, wkp, para_env, blacs_env_all, para_env_kp, para_env_inter_kp, blacs_env, kp_env, kp_aux_env, mpools, iogrp, nkp_groups, kp_dist, cell_to_index, index_to_cell, sab_nl, sab_nl_nosym, inversion_symmetry_only, symmetry_backend, symmetry_reduction_method, gamma_centered, lattice_fft)
Retrieve information from a kpoint environment.
Definition kpoint_types.F:585
mathconstants
Definition of mathematical constants and functions.
Definition mathconstants.F:16
mathconstants::pi
real(kind=dp), parameter, public pi
Definition mathconstants.F:110
mathconstants::twopi
real(kind=dp), parameter, public twopi
Definition mathconstants.F:112
message_passing
Interface to the message passing library MPI.
Definition message_passing.F:27
particle_types
Define the data structure for the particle information.
Definition particle_types.F:19
qs_energy_types
Definition qs_energy_types.F:14
qs_environment_types
Definition qs_environment_types.F:14
qs_environment_types::get_qs_env
subroutine, public get_qs_env(qs_env, atomic_kind_set, qs_kind_set, cell, super_cell, cell_ref, use_ref_cell, kpoints, dft_control, mos, sab_orb, sab_all, qmmm, qmmm_periodic, mimic, sac_ae, sac_ppl, sac_lri, sap_ppnl, sab_vdw, sab_scp, sap_oce, sab_lrc, sab_se, sab_xtbe, sab_tbe, sab_core, sab_xb, sab_xtb_pp, sab_xtb_nonbond, sab_almo, sab_kp, sab_kp_nosym, sab_cneo, particle_set, energy, force, matrix_h, matrix_h_im, matrix_ks, matrix_ks_im, matrix_vxc, run_rtp, rtp, matrix_h_kp, matrix_h_im_kp, matrix_ks_kp, matrix_ks_im_kp, matrix_vxc_kp, kinetic_kp, matrix_s_kp, matrix_w_kp, matrix_s_ri_aux_kp, matrix_s, matrix_s_ri_aux, matrix_w, matrix_p_mp2, matrix_p_mp2_admm, matrix_vhxc, rho, rho_xc, pw_env, ewald_env, ewald_pw, active_space, mpools, input, para_env, blacs_env, scf_control, rel_control, kinetic, qs_charges, vppl, xcint_weights, rho_core, rho_nlcc, rho_nlcc_g, ks_env, ks_qmmm_env, wf_history, scf_env, local_particles, local_molecules, distribution_2d, dbcsr_dist, molecule_kind_set, molecule_set, subsys, cp_subsys, oce, local_rho_set, rho_atom_set, task_list, task_list_soft, rho0_atom_set, rho0_mpole, rhoz_set, rhoz_cneo_set, ecoul_1c, rho0_s_rs, rho0_s_gs, rhoz_cneo_s_rs, rhoz_cneo_s_gs, do_kpoints, has_unit_metric, requires_mo_derivs, mo_derivs, mo_loc_history, nkind, natom, nelectron_total, nelectron_spin, efield, neighbor_list_id, linres_control, xas_env, virial, cp_ddapc_env, cp_ddapc_ewald, outer_scf_history, outer_scf_ihistory, x_data, et_coupling, dftb_potential, results, se_taper, se_store_int_env, se_nddo_mpole, se_nonbond_env, admm_env, lri_env, lri_density, exstate_env, ec_env, harris_env, dispersion_env, gcp_env, vee, rho_external, external_vxc, mask, mp2_env, bs_env, kg_env, wanniercentres, atprop, ls_scf_env, do_transport, transport_env, v_hartree_rspace, s_mstruct_changed, rho_changed, potential_changed, forces_up_to_date, mscfg_env, almo_scf_env, gradient_history, variable_history, embed_pot, spin_embed_pot, polar_env, mos_last_converged, eeq, rhs, do_rixs, tb_tblite)
Get the QUICKSTEP environment.
Definition qs_environment_types.F:544
qs_environment_types::set_qs_env
subroutine, public set_qs_env(qs_env, super_cell, mos, qmmm, qmmm_periodic, mimic, ewald_env, ewald_pw, mpools, rho_external, external_vxc, mask, scf_control, rel_control, qs_charges, ks_env, ks_qmmm_env, wf_history, scf_env, active_space, input, oce, rho_atom_set, rho0_atom_set, rho0_mpole, run_rtp, rtp, rhoz_set, rhoz_tot, ecoul_1c, has_unit_metric, requires_mo_derivs, mo_derivs, mo_loc_history, efield, rhoz_cneo_set, linres_control, xas_env, cp_ddapc_env, cp_ddapc_ewald, outer_scf_history, outer_scf_ihistory, x_data, et_coupling, dftb_potential, se_taper, se_store_int_env, se_nddo_mpole, se_nonbond_env, admm_env, ls_scf_env, do_transport, transport_env, lri_env, lri_density, exstate_env, ec_env, dispersion_env, harris_env, gcp_env, mp2_env, bs_env, kg_env, force, kpoints, wanniercentres, almo_scf_env, gradient_history, variable_history, embed_pot, spin_embed_pot, polar_env, mos_last_converged, eeq, rhs, do_rixs, tb_tblite)
Set the QUICKSTEP environment.
Definition qs_environment_types.F:1134
qs_force_types
Definition qs_force_types.F:13
qs_kind_types
Define the quickstep kind type and their sub types.
Definition qs_kind_types.F:23
qs_neighbor_list_types
Define the neighbor list data types and the corresponding functionality.
Definition qs_neighbor_list_types.F:17
qs_neighbor_list_types::neighbor_list_iterator_create
subroutine, public neighbor_list_iterator_create(iterator_set, nl, search, nthread)
Neighbor list iterator functions.
Definition qs_neighbor_list_types.F:165
qs_neighbor_list_types::neighbor_list_iterator_release
subroutine, public neighbor_list_iterator_release(iterator_set)
...
Definition qs_neighbor_list_types.F:251
qs_neighbor_list_types::neighbor_list_iterate
integer function, public neighbor_list_iterate(iterator_set, mepos)
...
Definition qs_neighbor_list_types.F:351
qs_neighbor_list_types::get_iterator_info
subroutine, public get_iterator_info(iterator_set, mepos, ikind, jkind, nkind, ilist, nlist, inode, nnode, iatom, jatom, r, cell)
...
Definition qs_neighbor_list_types.F:550
qs_period_efield_types
type for berry phase efield matrices. At the moment only used for cosmat and sinmat
Definition qs_period_efield_types.F:16
qs_period_efield_types::init_efield_matrices
subroutine, public init_efield_matrices(efield)
...
Definition qs_period_efield_types.F:47
qs_rho_types
superstucture that hold various representations of the density and keeps track of which ones are vali...
Definition qs_rho_types.F:18
qs_rho_types::qs_rho_get
subroutine, public qs_rho_get(rho_struct, rho_ao, rho_ao_im, rho_ao_kp, rho_ao_im_kp, rho_r, drho_r, rho_g, drho_g, tau_r, tau_g, rho_r_valid, drho_r_valid, rho_g_valid, drho_g_valid, tau_r_valid, tau_g_valid, tot_rho_r, tot_rho_g, rho_r_sccs, soft_valid, complex_rho_ao)
returns info about the density described by this object. If some representation is not available an e...
Definition qs_rho_types.F:229
sap_kind_types
General overlap type integrals containers.
Definition sap_kind_types.F:12
virial_methods
Definition virial_methods.F:12
virial_methods::virial_pair_force
pure subroutine, public virial_pair_force(pv_virial, f0, force, rab)
Computes the contribution to the stress tensor from two-body pair-wise forces.
Definition virial_methods.F:142
virial_types
Definition virial_types.F:13
xtb_coulomb
Calculation of Coulomb contributions in xTB.
Definition xtb_coulomb.F:12
xtb_coulomb::xtb_dsint_list
subroutine, public xtb_dsint_list(qs_env, sap_int)
...
Definition xtb_coulomb.F:817
atomic_kind_types::atomic_kind_type
Provides all information about an atomic kind.
Definition atomic_kind_types.F:45
cell_types::cell_type
Type defining parameters related to the simulation cell.
Definition cell_types.F:60
cp_control_types::dft_control_type
Definition cp_control_types.F:786
cp_dbcsr_api::dbcsr_iterator_type
Definition cp_dbcsr_api.F:188
cp_dbcsr_api::dbcsr_p_type
Definition cp_dbcsr_api.F:172
kpoint_types::kpoint_type
Contains information about kpoints.
Definition kpoint_types.F:196
message_passing::mp_para_env_type
stores all the informations relevant to an mpi environment
Definition message_passing.F:768
particle_types::particle_type
Definition particle_types.F:35
qs_energy_types::qs_energy_type
Definition qs_energy_types.F:25
qs_environment_types::qs_environment_type
Definition qs_environment_types.F:223
qs_force_types::qs_force_type
Definition qs_force_types.F:28
qs_kind_types::qs_kind_type
Provides all information about a quickstep kind.
Definition qs_kind_types.F:190
qs_neighbor_list_types::neighbor_list_iterator_p_type
Definition qs_neighbor_list_types.F:117
qs_neighbor_list_types::neighbor_list_set_p_type
Definition qs_neighbor_list_types.F:67
qs_period_efield_types::efield_berry_type
Definition qs_period_efield_types.F:32
qs_rho_types::qs_rho_type
keeps the density in various representations, keeping track of which ones are valid.
Definition qs_rho_types.F:62
sap_kind_types::sap_int_type
Definition sap_kind_types.F:67
virial_types::virial_type
Definition virial_types.F:26