ace_wrapper.F

Go to the documentation of this file.

!--------------------------------------------------------------------------------------------------!
!   CP2K: A general program to perform molecular dynamics simulations                              !
!   Copyright 2000-2025 CP2K developers group <https://cp2k.org>                                   !
!                                                                                                  !
!   SPDX-License-Identifier: GPL-2.0-or-later                                                      !
!--------------------------------------------------------------------------------------------------!
 
! **************************************************************************************************
!> \brief Interface to ACE C wrapper.
! **************************************************************************************************
 
MODULE ace_wrapper
   USE iso_c_binding,                   ONLY: c_char,&
                                              c_double,&
                                              c_int,&
                                              c_null_char,&
                                              c_null_ptr,&
                                              c_ptr
#include "./base/base_uses.f90"
 
   IMPLICIT NONE
 
   PRIVATE
   PUBLIC :: ace_model_type, ace_model_compute, ace_model_initialize, ace_model_release
 
   TYPE ace_model_type
      TYPE(c_ptr)                                 :: c_ptr = c_null_ptr
      CHARACTER(LEN=2), DIMENSION(:), ALLOCATABLE :: symbolc
   END TYPE ace_model_type
 
   INTERFACE ace_interface
! **************************************************************************************************
!> \brief ...
!> \param natomc ...
!> \param nghostc ...
!> \param neic ...
!> \param neiatc ...
!> \param originc ...
!> \param nlistc ...
!> \param attypec ...
!> \param atposc ...
!> \param forcec ...
!> \param virialc ...
!> \param energyc ...
!> \param acedata_ptr ...
! **************************************************************************************************
      SUBROUTINE acepotcompute(natomc, nghostc, neic, neiatc, originc, nlistc, &
                               attypec, atposc, forcec, virialc, energyc, &
                               acedata_ptr) BIND(C, NAME="AcePotCompute")
 
         IMPORT :: c_ptr, c_int, c_double
         INTEGER(C_INT), VALUE                                           :: natomc
         INTEGER(C_INT), VALUE                                           :: nghostc
         INTEGER(C_INT), VALUE                                           :: neic
         INTEGER(C_INT), DIMENSION(0:natomc)                             :: neiatc
         INTEGER(C_INT), DIMENSION(1:nghostc)                            :: originc
         INTEGER(C_INT), DIMENSION(1:neic)                               :: nlistc
         INTEGER(C_INT), DIMENSION(1:natomc + nghostc)                   :: attypec
         REAL(C_DOUBLE), DIMENSION(1:3*(natomc + nghostc))               :: atposc
         REAL(C_DOUBLE), DIMENSION(1:3*natomc)                           :: forcec
         REAL(C_DOUBLE), DIMENSION(1:6)                                  :: virialc
         REAL(C_DOUBLE), DIMENSION(1:natomc)                             :: energyc
         TYPE(c_ptr)                                                     :: acedata_ptr
      END SUBROUTINE
! **************************************************************************************************
!> \brief ...
!> \param ntypec ...
!> \param symbolc ...
!> \param nlen ...
!> \param cname ...
!> \param rcutc ...
!> \param acedata_ptr ...
! **************************************************************************************************
      SUBROUTINE acepotinitialize(ntypec, symbolc, nlen, cname, rcutc, &
                                  acedata_ptr) BIND(C, NAME="AcePotInitialize")
         USE iso_c_binding, ONLY: c_char, c_int, c_double, c_ptr
      INTEGER(C_INT), VALUE                              :: ntypec
      CHARACTER(KIND=C_CHAR, LEN=1), DIMENSION(*)        :: symbolc
      INTEGER(C_INT), VALUE                              :: nlen
      CHARACTER(KIND=C_CHAR, LEN=1), DIMENSION(*)        :: cname
      REAL(C_DOUBLE), DIMENSION(1:ntypec, 1:ntypec)      :: rcutc
      TYPE(c_ptr)                                        :: acedata_ptr
 
      END SUBROUTINE acepotinitialize
! **************************************************************************************************
!> \brief ...
!> \param acedata_ptr ...
! **************************************************************************************************
      SUBROUTINE acepotfinalize(acedata_ptr) BIND(C, NAME="AcePotFinalize")
         USE iso_c_binding, ONLY: c_ptr
      TYPE(c_ptr)                                        :: acedata_ptr
 
      END SUBROUTINE acepotfinalize
   END INTERFACE ace_interface
 
CONTAINS
 
! **************************************************************************************************
!> \brief ...
!> \param natomc ...
!> \param nghostc ...
!> \param neic ...
!> \param neiatc ...
!> \param originc ...
!> \param nlistc ...
!> \param attypec ...
!> \param atposc ...
!> \param forcec ...
!> \param virialc ...
!> \param energyc ...
!> \param model ...
! **************************************************************************************************
   SUBROUTINE ace_model_compute(natomc, nghostc, neic, neiatc, originc, nlistc, &
                                attypec, atposc, forcec, virialc, energyc, model)
 
      INTEGER                                            :: natomc, nghostc, neic
      INTEGER, DIMENSION(0:natomc), INTENT(IN)           :: neiatc
      INTEGER, DIMENSION(1:nghostc), INTENT(IN)          :: originc
      INTEGER, DIMENSION(1:neic), INTENT(IN)             :: nlistc
      INTEGER, DIMENSION(1:natomc + nghostc), INTENT(IN) :: attypec
      REAL(kind=8), dimension(1:3*(natomc + nghostc)), &
         INTENT(IN)                                      :: atposc
      REAL(kind=8), dimension(1:3*natomc), INTENT(INOUT) :: forcec
      REAL(kind=8), dimension(1:6), INTENT(INOUT)        :: virialc
      REAL(kind=8), dimension(1:natomc), INTENT(INOUT)   :: energyc
      TYPE(ace_model_type), INTENT(IN)                   :: model
 
#if defined(__ACE)
 
      CALL acepotcompute(natomc, nghostc, neic, neiatc, originc, nlistc, attypec, &
                         atposc, forcec, virialc, energyc, model%c_ptr)
#else
      mark_used(natomc)
      mark_used(nghostc)
      mark_used(neic)
      mark_used(neiatc)
      mark_used(originc)
      mark_used(nlistc)
      mark_used(attypec)
      mark_used(atposc)
      mark_used(forcec)
      mark_used(virialc)
      mark_used(energyc)
      mark_used(model)
      cpabort("CP2K was compiled without ACE library.")
#endif
   END SUBROUTINE
 
! **************************************************************************************************
!> \brief ...
!> \param ntypec ...
!> \param symbolc ...
!> \param fname ...
!> \param rcutc ...
!> \param model ...
! **************************************************************************************************
   SUBROUTINE ace_model_initialize(ntypec, symbolc, fname, rcutc, model)
      USE iso_c_binding, ONLY: c_char, c_null_char
      INTEGER, INTENT(IN)                                :: ntypec
      CHARACTER(KIND=C_CHAR, LEN=2), &
         DIMENSION(1:ntypec), INTENT(IN)                 :: symbolc
      CHARACTER(KIND=C_CHAR, LEN=*), INTENT(IN)          :: fname
      REAL(kind=8), dimension(1:ntypec, 1:ntypec), &
         INTENT(OUT)                                     :: rcutc
      TYPE(ace_model_type), INTENT(OUT)                  :: model
 
#if defined(__ACE)
 
      CHARACTER(KIND=C_CHAR), DIMENSION(LEN(fname) + 1)  :: cname
      INTEGER                                            :: i, nlen
 
      nlen = len(fname)
      DO i = 1, nlen
         cname(i) = fname(i:i)
      END DO
      nlen = nlen + 1
      cname(nlen) = c_null_char
      CALL acepotinitialize(ntypec, symbolc, nlen, cname, rcutc, model%c_ptr)
      ALLOCATE (model%symbolc(ntypec))
      DO i = 1, ntypec
         model%symbolc(i) = symbolc(i)
      END DO
#else
      mark_used(ntypec)
      mark_used(symbolc)
      mark_used(fname)
      mark_used(rcutc)
      mark_used(model)
      cpabort("CP2K was compiled without ACE library.")
#endif
   END SUBROUTINE ace_model_initialize
 
!**************************************************************************************************
!> \brief Releases an ACE model and all its ressources.
!> \param model Pointer to the ACE model.
! **************************************************************************************************
   SUBROUTINE ace_model_release(model)
      USE iso_c_binding, ONLY: c_null_ptr
      TYPE(ace_model_type), INTENT(INOUT)                :: model
 
#if defined(__ACE)
 
      CALL acepotfinalize(model%c_ptr)
      model%c_ptr = c_null_ptr
      IF (ALLOCATED(model%symbolc)) DEALLOCATE (model%symbolc)
#else
      mark_used(model)
      cpabort("CP2K was compiled without ACE library.")
#endif
 
   END SUBROUTINE ace_model_release
 
END MODULE ace_wrapper