d2/d60/moments__utils_8F_source.html

!--------------------------------------------------------------------------------------------------!

!   CP2K: A general program to perform molecular dynamics simulations                              !

!   Copyright 2000-2025 CP2K developers group <https://cp2k.org>                                   !

!                                                                                                  !

!   SPDX-License-Identifier: GPL-2.0-or-later                                                      !

!--------------------------------------------------------------------------------------------------!


! **************************************************************************************************

!> \brief Calculates the moment integrals <a|r^m|b>

!> \par History

!>      12.2007 [tlaino] - Splitting common routines to QS and FIST

!>      06.2009 [tlaino] - Extending to molecular dipoles (interval of atoms)

!> \author JGH (20.07.2006)

! **************************************************************************************************

MODULE moments_utils

   USE atomic_kind_types,               ONLY: atomic_kind_type,&

                                              get_atomic_kind

   USE cell_types,                      ONLY: cell_type,&

                                              pbc

   USE distribution_1d_types,           ONLY: distribution_1d_type

   USE fist_environment_types,          ONLY: fist_env_get,&

                                              fist_environment_type

   USE input_constants,                 ONLY: use_mom_ref_coac,&

                                              use_mom_ref_com,&

                                              use_mom_ref_user,&

                                              use_mom_ref_zero

   USE kinds,                           ONLY: dp

   USE message_passing,                 ONLY: mp_para_env_type

   USE particle_types,                  ONLY: particle_type

   USE qs_environment_types,            ONLY: get_qs_env,&

                                              qs_environment_type

   USE qs_kind_types,                   ONLY: get_qs_kind,&

                                              qs_kind_type

#include "./base/base_uses.f90"


   IMPLICIT NONE


   PRIVATE


   CHARACTER(len=*), PARAMETER, PRIVATE :: moduleN = 'moments_utils'


! *** Public subroutines ***


   PUBLIC :: get_reference_point


CONTAINS


! **************************************************************************************************

!> \brief ...

!> \param rpoint ...

!> \param drpoint ...

!> \param qs_env ...

!> \param fist_env ...

!> \param reference ...

!> \param ref_point ...

!> \param ifirst ...

!> \param ilast ...

! **************************************************************************************************


   SUBROUTINE get_reference_point(rpoint, drpoint, qs_env, fist_env, reference, ref_point, &

                                  ifirst, ilast)

      REAL(dp), DIMENSION(3), INTENT(OUT)                :: rpoint

      REAL(dp), DIMENSION(3), INTENT(OUT), OPTIONAL      :: drpoint

      TYPE(qs_environment_type), OPTIONAL, POINTER       :: qs_env

      TYPE(fist_environment_type), OPTIONAL, POINTER     :: fist_env

      INTEGER, INTENT(IN)                                :: reference

      REAL(kind=dp), DIMENSION(:), POINTER               :: ref_point

      INTEGER, INTENT(IN), OPTIONAL                      :: ifirst, ilast


      INTEGER                                            :: akind, ia, iatom, ikind

      LOGICAL                                            :: do_molecule

      REAL(dp)                                           :: charge, mass, mass_low, mtot, ztot

      REAL(dp), DIMENSION(3)                             :: center, ria

      TYPE(atomic_kind_type), POINTER                    :: atomic_kind

      TYPE(cell_type), POINTER                           :: cell

      TYPE(distribution_1d_type), POINTER                :: local_particles

      TYPE(mp_para_env_type), POINTER                    :: para_env

      TYPE(particle_type), DIMENSION(:), POINTER         :: particle_set

      TYPE(qs_kind_type), DIMENSION(:), POINTER          :: qs_kind_set


      cpassert(PRESENT(ifirst) .EQV. PRESENT(ilast))

      NULLIFY (cell, particle_set, qs_kind_set, local_particles, para_env)

      IF (PRESENT(qs_env)) THEN

         CALL get_qs_env(qs_env, cell=cell, particle_set=particle_set, &

                         qs_kind_set=qs_kind_set, &

                         local_particles=local_particles, para_env=para_env)

      END IF

      IF (PRESENT(fist_env)) THEN

         CALL fist_env_get(fist_env, cell=cell, particle_set=particle_set, &

                           local_particles=local_particles, para_env=para_env)

      END IF

      do_molecule = .false.

      IF (PRESENT(ifirst) .AND. PRESENT(ilast)) do_molecule = .true.

      IF (PRESENT(drpoint)) drpoint = 0.0_dp

      SELECT CASE (reference)

      CASE DEFAULT

         cpabort("Type of reference point not implemented")

      CASE (use_mom_ref_com)

         rpoint = 0._dp

         mtot = 0._dp

         center(:) = 0._dp

         IF (do_molecule) THEN

            mass_low = -huge(mass_low)

            ! fold the molecule around the heaviest atom in the molecule

            DO iatom = ifirst, ilast

               atomic_kind => particle_set(iatom)%atomic_kind

               CALL get_atomic_kind(atomic_kind=atomic_kind, mass=mass)

               IF (mass > mass_low) THEN

                  mass_low = mass

                  center = particle_set(iatom)%r

               END IF

            END DO

            DO iatom = ifirst, ilast

               ria = particle_set(iatom)%r

               ria = pbc(ria - center, cell) + center

               atomic_kind => particle_set(iatom)%atomic_kind

               CALL get_atomic_kind(atomic_kind=atomic_kind, mass=mass)

               rpoint(:) = rpoint(:) + mass*ria(:)

               IF (PRESENT(drpoint)) drpoint = drpoint + mass*particle_set(iatom)%v

               mtot = mtot + mass

            END DO

         ELSE

            DO ikind = 1, SIZE(local_particles%n_el)

               DO ia = 1, local_particles%n_el(ikind)

                  iatom = local_particles%list(ikind)%array(ia)

                  ria = particle_set(iatom)%r

                  ria = pbc(ria, cell)

                  atomic_kind => particle_set(iatom)%atomic_kind

                  CALL get_atomic_kind(atomic_kind=atomic_kind, mass=mass)

                  rpoint(:) = rpoint(:) + mass*ria(:)

                  IF (PRESENT(drpoint)) drpoint = drpoint + mass*particle_set(iatom)%v

                  mtot = mtot + mass

               END DO

            END DO

            CALL para_env%sum(rpoint)

            CALL para_env%sum(mtot)

         END IF

         IF (abs(mtot) > 0._dp) THEN

            rpoint(:) = rpoint(:)/mtot

            IF (PRESENT(drpoint)) drpoint = drpoint/mtot

         END IF

      CASE (use_mom_ref_coac)

         rpoint = 0._dp

         ztot = 0._dp

         center(:) = 0._dp

         IF (do_molecule) THEN

            mass_low = -huge(mass_low)

            ! fold the molecule around the heaviest atom in the molecule

            DO iatom = ifirst, ilast

               atomic_kind => particle_set(iatom)%atomic_kind

               CALL get_atomic_kind(atomic_kind=atomic_kind, mass=mass)

               IF (mass > mass_low) THEN

                  mass_low = mass

                  center = particle_set(iatom)%r

               END IF

            END DO

            DO iatom = ifirst, ilast

               ria = particle_set(iatom)%r

               ria = pbc(ria - center, cell) + center

               atomic_kind => particle_set(iatom)%atomic_kind

               CALL get_atomic_kind(atomic_kind, kind_number=akind)

               CALL get_qs_kind(qs_kind_set(akind), core_charge=charge)

               rpoint(:) = rpoint(:) + charge*ria(:)

               IF (PRESENT(drpoint)) drpoint = drpoint + charge*particle_set(iatom)%v

               ztot = ztot + charge

            END DO

         ELSE

            DO ikind = 1, SIZE(local_particles%n_el)

               DO ia = 1, local_particles%n_el(ikind)

                  iatom = local_particles%list(ikind)%array(ia)

                  ria = particle_set(iatom)%r

                  ria = pbc(ria, cell)

                  atomic_kind => particle_set(iatom)%atomic_kind

                  CALL get_atomic_kind(atomic_kind, kind_number=akind)

                  CALL get_qs_kind(qs_kind_set(akind), core_charge=charge)

                  rpoint(:) = rpoint(:) + charge*ria(:)

                  IF (PRESENT(drpoint)) drpoint = drpoint + charge*particle_set(iatom)%v

                  ztot = ztot + charge

               END DO

            END DO

            CALL para_env%sum(rpoint)

            CALL para_env%sum(ztot)

         END IF

         IF (abs(ztot) > 0._dp) THEN

            rpoint(:) = rpoint(:)/ztot

            IF (PRESENT(drpoint)) drpoint = drpoint/ztot

         END IF

      CASE (use_mom_ref_user)

         rpoint = ref_point

      CASE (use_mom_ref_zero)

         rpoint = 0._dp

      END SELECT


   END SUBROUTINE get_reference_point


END MODULE moments_utils


cell_types::pbc
Definition cell_types.F:92

atomic_kind_types
Define the atomic kind types and their sub types.
Definition atomic_kind_types.F:23

atomic_kind_types::get_atomic_kind
subroutine, public get_atomic_kind(atomic_kind, fist_potential, element_symbol, name, mass, kind_number, natom, atom_list, rcov, rvdw, z, qeff, apol, cpol, mm_radius, shell, shell_active, damping)
Get attributes of an atomic kind.
Definition atomic_kind_types.F:138

cell_types
Handles all functions related to the CELL.
Definition cell_types.F:15

distribution_1d_types
stores a lists of integer that are local to a processor. The idea is that these integers represent ob...
Definition distribution_1d_types.F:24

fist_environment_types
Definition fist_environment_types.F:15

fist_environment_types::fist_env_get
subroutine, public fist_env_get(fist_env, atomic_kind_set, particle_set, ewald_pw, local_particles, local_molecules, molecule_kind_set, molecule_set, cell, cell_ref, ewald_env, fist_nonbond_env, thermo, para_env, subsys, qmmm, qmmm_env, input, shell_model, shell_model_ad, shell_particle_set, core_particle_set, multipoles, results, exclusions, efield)
Purpose: Get the FIST environment.
Definition fist_environment_types.F:140

input_constants
collects all constants needed in input so that they can be used without circular dependencies
Definition input_constants.F:17

input_constants::use_mom_ref_coac
integer, parameter, public use_mom_ref_coac
Definition input_constants.F:497

input_constants::use_mom_ref_user
integer, parameter, public use_mom_ref_user
Definition input_constants.F:497

input_constants::use_mom_ref_com
integer, parameter, public use_mom_ref_com
Definition input_constants.F:497

input_constants::use_mom_ref_zero
integer, parameter, public use_mom_ref_zero
Definition input_constants.F:497

kinds
Defines the basic variable types.
Definition kinds.F:23

kinds::dp
integer, parameter, public dp
Definition kinds.F:34

message_passing
Interface to the message passing library MPI.
Definition message_passing.F:23

moments_utils
Calculates the moment integrals <a|r^m|b>
Definition moments_utils.F:15

moments_utils::get_reference_point
subroutine, public get_reference_point(rpoint, drpoint, qs_env, fist_env, reference, ref_point, ifirst, ilast)
...
Definition moments_utils.F:61

particle_types
Define the data structure for the particle information.
Definition particle_types.F:19

qs_environment_types
Definition qs_environment_types.F:14

qs_environment_types::get_qs_env
subroutine, public get_qs_env(qs_env, atomic_kind_set, qs_kind_set, cell, super_cell, cell_ref, use_ref_cell, kpoints, dft_control, mos, sab_orb, sab_all, qmmm, qmmm_periodic, sac_ae, sac_ppl, sac_lri, sap_ppnl, sab_vdw, sab_scp, sap_oce, sab_lrc, sab_se, sab_xtbe, sab_tbe, sab_core, sab_xb, sab_xtb_pp, sab_xtb_nonbond, sab_almo, sab_kp, sab_kp_nosym, particle_set, energy, force, matrix_h, matrix_h_im, matrix_ks, matrix_ks_im, matrix_vxc, run_rtp, rtp, matrix_h_kp, matrix_h_im_kp, matrix_ks_kp, matrix_ks_im_kp, matrix_vxc_kp, kinetic_kp, matrix_s_kp, matrix_w_kp, matrix_s_ri_aux_kp, matrix_s, matrix_s_ri_aux, matrix_w, matrix_p_mp2, matrix_p_mp2_admm, rho, rho_xc, pw_env, ewald_env, ewald_pw, active_space, mpools, input, para_env, blacs_env, scf_control, rel_control, kinetic, qs_charges, vppl, rho_core, rho_nlcc, rho_nlcc_g, ks_env, ks_qmmm_env, wf_history, scf_env, local_particles, local_molecules, distribution_2d, dbcsr_dist, molecule_kind_set, molecule_set, subsys, cp_subsys, oce, local_rho_set, rho_atom_set, task_list, task_list_soft, rho0_atom_set, rho0_mpole, rhoz_set, ecoul_1c, rho0_s_rs, rho0_s_gs, do_kpoints, has_unit_metric, requires_mo_derivs, mo_derivs, mo_loc_history, nkind, natom, nelectron_total, nelectron_spin, efield, neighbor_list_id, linres_control, xas_env, virial, cp_ddapc_env, cp_ddapc_ewald, outer_scf_history, outer_scf_ihistory, x_data, et_coupling, dftb_potential, results, se_taper, se_store_int_env, se_nddo_mpole, se_nonbond_env, admm_env, lri_env, lri_density, exstate_env, ec_env, harris_env, dispersion_env, gcp_env, vee, rho_external, external_vxc, mask, mp2_env, bs_env, kg_env, wanniercentres, atprop, ls_scf_env, do_transport, transport_env, v_hartree_rspace, s_mstruct_changed, rho_changed, potential_changed, forces_up_to_date, mscfg_env, almo_scf_env, gradient_history, variable_history, embed_pot, spin_embed_pot, polar_env, mos_last_converged, eeq, rhs)
Get the QUICKSTEP environment.
Definition qs_environment_types.F:514

qs_kind_types
Define the quickstep kind type and their sub types.
Definition qs_kind_types.F:23

qs_kind_types::get_qs_kind
subroutine, public get_qs_kind(qs_kind, basis_set, basis_type, ncgf, nsgf, all_potential, tnadd_potential, gth_potential, sgp_potential, upf_potential, se_parameter, dftb_parameter, xtb_parameter, dftb3_param, zatom, zeff, elec_conf, mao, lmax_dftb, alpha_core_charge, ccore_charge, core_charge, core_charge_radius, paw_proj_set, paw_atom, hard_radius, hard0_radius, max_rad_local, covalent_radius, vdw_radius, gpw_type_forced, harmonics, max_iso_not0, max_s_harm, grid_atom, ngrid_ang, ngrid_rad, lmax_rho0, dft_plus_u_atom, l_of_dft_plus_u, n_of_dft_plus_u, u_minus_j, u_of_dft_plus_u, j_of_dft_plus_u, alpha_of_dft_plus_u, beta_of_dft_plus_u, j0_of_dft_plus_u, occupation_of_dft_plus_u, dispersion, bs_occupation, magnetization, no_optimize, addel, laddel, naddel, orbitals, max_scf, eps_scf, smear, u_ramping, u_minus_j_target, eps_u_ramping, init_u_ramping_each_scf, reltmat, ghost, floating, name, element_symbol, pao_basis_size, pao_model_file, pao_potentials, pao_descriptors, nelec)
Get attributes of an atomic kind.
Definition qs_kind_types.F:454

atomic_kind_types::atomic_kind_type
Provides all information about an atomic kind.
Definition atomic_kind_types.F:45

cell_types::cell_type
Type defining parameters related to the simulation cell.
Definition cell_types.F:55

distribution_1d_types::distribution_1d_type
structure to store local (to a processor) ordered lists of integers.
Definition distribution_1d_types.F:62

fist_environment_types::fist_environment_type
Definition fist_environment_types.F:71

message_passing::mp_para_env_type
stores all the informations relevant to an mpi environment
Definition message_passing.F:763

particle_types::particle_type
Definition particle_types.F:35

qs_environment_types::qs_environment_type
Definition qs_environment_types.F:217

qs_kind_types::qs_kind_type
Provides all information about a quickstep kind.
Definition qs_kind_types.F:171