d2/d4a/optbas__opt__utils_8F_source.html

!--------------------------------------------------------------------------------------------------!

!   CP2K: A general program to perform molecular dynamics simulations                              !

!   Copyright 2000-2025 CP2K developers group <https://cp2k.org>                                   !

!                                                                                                  !

!   SPDX-License-Identifier: GPL-2.0-or-later                                                      !

!--------------------------------------------------------------------------------------------------!

MODULE optbas_opt_utils

   USE atomic_kind_types,               ONLY: atomic_kind_type,&

                                              get_atomic_kind

   USE basis_set_types,                 ONLY: get_gto_basis_set,&

                                              gto_basis_set_type

   USE cell_types,                      ONLY: cell_type

   USE cp_blacs_env,                    ONLY: cp_blacs_env_type

   USE cp_dbcsr_api,                    ONLY: dbcsr_create,&

                                              dbcsr_distribution_type,&

                                              dbcsr_get_info,&

                                              dbcsr_p_type,&

                                              dbcsr_release,&

                                              dbcsr_transposed,&

                                              dbcsr_type,&

                                              dbcsr_type_no_symmetry

   USE cp_dbcsr_operations,             ONLY: copy_dbcsr_to_fm,&

                                              cp_dbcsr_sm_fm_multiply

   USE cp_fm_basic_linalg,              ONLY: cp_fm_invert,&

                                              cp_fm_trace

   USE cp_fm_diag,                      ONLY: cp_fm_power

   USE cp_fm_struct,                    ONLY: cp_fm_struct_create,&

                                              cp_fm_struct_release,&

                                              cp_fm_struct_type

   USE cp_fm_types,                     ONLY: cp_fm_create,&

                                              cp_fm_get_info,&

                                              cp_fm_release,&

                                              cp_fm_type

   USE distribution_1d_types,           ONLY: distribution_1d_type

   USE distribution_2d_types,           ONLY: distribution_2d_type

   USE input_section_types,             ONLY: section_vals_val_get

   USE kinds,                           ONLY: dp

   USE message_passing,                 ONLY: mp_para_env_type

   USE molecule_types,                  ONLY: molecule_type

   USE parallel_gemm_api,               ONLY: parallel_gemm

   USE particle_types,                  ONLY: particle_type

   USE qs_condnum,                      ONLY: overlap_condnum

   USE qs_environment_types,            ONLY: get_qs_env,&

                                              qs_environment_type

   USE qs_kind_types,                   ONLY: get_qs_kind,&

                                              qs_kind_type

   USE qs_ks_types,                     ONLY: qs_ks_env_type

   USE qs_mo_types,                     ONLY: get_mo_set,&

                                              mo_set_type

   USE qs_neighbor_list_types,          ONLY: neighbor_list_set_p_type

   USE qs_neighbor_lists,               ONLY: atom2d_build,&

                                              atom2d_cleanup,&

                                              build_neighbor_lists,&

                                              local_atoms_type,&

                                              pair_radius_setup

#include "./base/base_uses.f90"


   IMPLICIT NONE

   PRIVATE


   PUBLIC :: evaluate_optvals, fit_mo_coeffs, optbas_build_neighborlist


   CHARACTER(len=*), PARAMETER, PRIVATE :: moduleN = 'optbas_opt_utils'


CONTAINS


! **************************************************************************************************

!> \brief ...

!> \param mos ...

!> \param mos_aux_fit ...

!> \param matrix_ks ...

!> \param Q ...

!> \param Snew ...

!> \param S_inv_orb ...

!> \param fval ...

!> \param energy ...

!> \param S_cond_number ...

! **************************************************************************************************


   SUBROUTINE evaluate_optvals(mos, mos_aux_fit, matrix_ks, Q, Snew, S_inv_orb, &

                               fval, energy, S_cond_number)

      TYPE(mo_set_type), DIMENSION(:), INTENT(IN)        :: mos, mos_aux_fit

      TYPE(dbcsr_p_type), DIMENSION(:), POINTER          :: matrix_ks

      TYPE(dbcsr_type), POINTER                          :: q, snew

      TYPE(cp_fm_type), INTENT(IN)                       :: s_inv_orb

      REAL(kind=dp)                                      :: fval, energy, s_cond_number


      CHARACTER(len=*), PARAMETER                        :: routinen = 'evaluate_optvals'


      INTEGER                                            :: handle, ispin, iunit, naux, nmo, norb, &

                                                            nspins

      INTEGER, DIMENSION(:), POINTER                     :: col_blk_sizes, row_blk_sizes

      REAL(kind=dp)                                      :: tmp_energy, trace

      REAL(kind=dp), DIMENSION(2)                        :: condnum

      TYPE(cp_blacs_env_type), POINTER                   :: blacs_env

      TYPE(cp_fm_type)                                   :: tmp1, tmp2

      TYPE(cp_fm_type), POINTER                          :: mo_coeff, mo_coeff_aux_fit

      TYPE(dbcsr_distribution_type)                      :: dbcsr_dist

      TYPE(dbcsr_p_type), DIMENSION(:, :), POINTER       :: smat

      TYPE(dbcsr_type)                                   :: qt


      CALL timeset(routinen, handle)


      nspins = SIZE(mos)


      NULLIFY (col_blk_sizes, row_blk_sizes)

      CALL dbcsr_get_info(q, distribution=dbcsr_dist, &

                          nfullrows_total=naux, nfullcols_total=norb, &

                          row_blk_size=row_blk_sizes, col_blk_size=col_blk_sizes)

      CALL dbcsr_create(matrix=qt, name="Qt", &

                        dist=dbcsr_dist, matrix_type=dbcsr_type_no_symmetry, &

                        row_blk_size=col_blk_sizes, col_blk_size=row_blk_sizes)

      CALL dbcsr_transposed(qt, q)

      !

      fval = 0.0_dp

      energy = 0.0_dp

      DO ispin = 1, nspins

         CALL get_mo_set(mos(ispin), mo_coeff=mo_coeff)

         CALL get_mo_set(mos_aux_fit(ispin), mo_coeff=mo_coeff_aux_fit)

         CALL cp_fm_get_info(mo_coeff, ncol_global=nmo)

         CALL cp_fm_create(tmp1, matrix_struct=mo_coeff%matrix_struct)

         CALL cp_dbcsr_sm_fm_multiply(qt, mo_coeff_aux_fit, tmp1, nmo)

         CALL cp_fm_trace(tmp1, mo_coeff, trace)

         fval = fval - 2.0_dp*trace + 2.0_dp*nmo

         !

         CALL cp_fm_create(tmp2, matrix_struct=mo_coeff%matrix_struct)

         CALL parallel_gemm('N', 'N', norb, nmo, norb, 1.0_dp, s_inv_orb, tmp1, 0.0_dp, tmp2)

         CALL cp_dbcsr_sm_fm_multiply(matrix_ks(ispin)%matrix, tmp2, tmp1, nmo)

         CALL cp_fm_trace(tmp2, tmp1, tmp_energy)

         energy = energy + tmp_energy*(3.0_dp - real(nspins, kind=dp))

         CALL cp_fm_release(tmp1)

         CALL cp_fm_release(tmp2)

      END DO

      CALL dbcsr_release(qt)


      ALLOCATE (smat(1, 1))

      smat(1, 1)%matrix => snew

      iunit = -1

      CALL cp_fm_get_info(s_inv_orb, context=blacs_env)

      CALL overlap_condnum(smat, condnum, iunit, .false., .true., .false., blacs_env)

      s_cond_number = condnum(2)

      DEALLOCATE (smat)


      CALL timestop(handle)


   END SUBROUTINE evaluate_optvals


! **************************************************************************************************

!> \brief ...

!> \param saux ...

!> \param sauxorb ...

!> \param mos ...

!> \param mosaux ...

! **************************************************************************************************


   SUBROUTINE fit_mo_coeffs(saux, sauxorb, mos, mosaux)

      TYPE(dbcsr_p_type), DIMENSION(:), POINTER          :: saux, sauxorb

      TYPE(mo_set_type), DIMENSION(:), INTENT(IN)        :: mos, mosaux


      CHARACTER(len=*), PARAMETER                        :: routinen = 'fit_mo_coeffs'

      REAL(kind=dp), PARAMETER                           :: threshold = 1.e-12_dp


      INTEGER                                            :: handle, ispin, naux, ndep, nmo, norb, &

                                                            nspins

      TYPE(cp_fm_struct_type), POINTER                   :: fm_struct

      TYPE(cp_fm_type)                                   :: fm_s, fm_sinv, tmat, tmp1, tmp2, work

      TYPE(cp_fm_type), POINTER                          :: mo_coeff, mo_coeff_aux


      CALL timeset(routinen, handle)


      CALL dbcsr_get_info(saux(1)%matrix, nfullrows_total=naux)

      CALL dbcsr_get_info(sauxorb(1)%matrix, nfullcols_total=norb)

      CALL get_mo_set(mos(1), mo_coeff=mo_coeff)


      CALL cp_fm_struct_create(fm_struct, nrow_global=naux, ncol_global=naux, &

                               context=mo_coeff%matrix_struct%context, &

                               para_env=mo_coeff%matrix_struct%para_env)

      CALL cp_fm_create(fm_s, fm_struct, name="s_aux")

      CALL cp_fm_create(fm_sinv, fm_struct, name="s_aux_inv")

      CALL copy_dbcsr_to_fm(saux(1)%matrix, fm_s)

      CALL cp_fm_invert(fm_s, fm_sinv)

      CALL cp_fm_release(fm_s)

      CALL cp_fm_struct_release(fm_struct)

      nspins = SIZE(mos)

      DO ispin = 1, nspins

         CALL get_mo_set(mos(ispin), mo_coeff=mo_coeff)

         CALL get_mo_set(mosaux(ispin), mo_coeff=mo_coeff_aux)

         CALL cp_fm_get_info(mo_coeff, ncol_global=nmo)

         CALL cp_fm_create(tmp1, matrix_struct=mo_coeff_aux%matrix_struct)

         CALL cp_fm_create(tmp2, matrix_struct=mo_coeff_aux%matrix_struct)

         CALL cp_fm_struct_create(fm_struct, nrow_global=nmo, ncol_global=nmo, &

                                  context=mo_coeff%matrix_struct%context, &

                                  para_env=mo_coeff%matrix_struct%para_env)

         CALL cp_fm_create(tmat, fm_struct, name="tmat")

         CALL cp_fm_create(work, fm_struct, name="work")

         CALL cp_fm_struct_release(fm_struct)

         !

         CALL cp_dbcsr_sm_fm_multiply(sauxorb(1)%matrix, mo_coeff, tmp1, nmo)

         CALL parallel_gemm('N', 'N', naux, nmo, naux, 1.0_dp, fm_sinv, tmp1, 0.0_dp, tmp2)

         CALL parallel_gemm('T', 'N', nmo, nmo, naux, 1.0_dp, tmp1, tmp2, 0.0_dp, tmat)

         CALL cp_fm_power(tmat, work, -0.5_dp, threshold, ndep)

         CALL parallel_gemm('N', 'N', naux, nmo, nmo, 1.0_dp, tmp2, tmat, 0.0_dp, mo_coeff_aux)

         !

         CALL cp_fm_release(work)

         CALL cp_fm_release(tmat)

         CALL cp_fm_release(tmp1)

         CALL cp_fm_release(tmp2)

      END DO

      CALL cp_fm_release(fm_sinv)


      CALL timestop(handle)


   END SUBROUTINE fit_mo_coeffs


! **************************************************************************************************

!> \brief rebuilds neighborlist for absis sets

!> \param qs_env ...

!> \param sab_aux ...

!> \param sab_aux_orb ...

!> \param basis_type ...

!> \par History

!>       adapted from kg_build_neighborlist

! **************************************************************************************************


   SUBROUTINE optbas_build_neighborlist(qs_env, sab_aux, sab_aux_orb, basis_type)

      TYPE(qs_environment_type), POINTER                 :: qs_env

      TYPE(neighbor_list_set_p_type), DIMENSION(:), &

         POINTER                                         :: sab_aux, sab_aux_orb

      CHARACTER(*)                                       :: basis_type


      CHARACTER(LEN=*), PARAMETER :: routinen = 'optbas_build_neighborlist'


      INTEGER                                            :: handle, ikind, nkind

      LOGICAL                                            :: mic, molecule_only

      LOGICAL, ALLOCATABLE, DIMENSION(:)                 :: aux_fit_present, orb_present

      REAL(dp)                                           :: subcells

      REAL(dp), ALLOCATABLE, DIMENSION(:)                :: aux_fit_radius, orb_radius

      REAL(dp), ALLOCATABLE, DIMENSION(:, :)             :: pair_radius

      TYPE(atomic_kind_type), DIMENSION(:), POINTER      :: atomic_kind_set

      TYPE(cell_type), POINTER                           :: cell

      TYPE(distribution_1d_type), POINTER                :: distribution_1d

      TYPE(distribution_2d_type), POINTER                :: distribution_2d

      TYPE(gto_basis_set_type), POINTER                  :: aux_fit_basis_set, orb_basis_set

      TYPE(local_atoms_type), ALLOCATABLE, DIMENSION(:)  :: atom2d

      TYPE(molecule_type), DIMENSION(:), POINTER         :: molecule_set

      TYPE(mp_para_env_type), POINTER                    :: para_env

      TYPE(particle_type), DIMENSION(:), POINTER         :: particle_set

      TYPE(qs_kind_type), DIMENSION(:), POINTER          :: qs_kind_set

      TYPE(qs_ks_env_type), POINTER                      :: ks_env


      CALL timeset(routinen, handle)

      NULLIFY (para_env)


      ! restrict lists to molecular subgroups

      molecule_only = .false.

      mic = molecule_only


      CALL get_qs_env(qs_env=qs_env, &

                      ks_env=ks_env, &

                      atomic_kind_set=atomic_kind_set, &

                      qs_kind_set=qs_kind_set, &

                      cell=cell, &

                      distribution_2d=distribution_2d, &

                      molecule_set=molecule_set, &

                      local_particles=distribution_1d, &

                      particle_set=particle_set, &

                      para_env=para_env)


      CALL section_vals_val_get(qs_env%input, "DFT%SUBCELLS", r_val=subcells)


      ! Allocate work storage

      nkind = SIZE(atomic_kind_set)

      ALLOCATE (orb_radius(nkind), aux_fit_radius(nkind))

      orb_radius(:) = 0.0_dp

      aux_fit_radius(:) = 0.0_dp

      ALLOCATE (orb_present(nkind), aux_fit_present(nkind))

      ALLOCATE (pair_radius(nkind, nkind))

      ALLOCATE (atom2d(nkind))


      CALL atom2d_build(atom2d, distribution_1d, distribution_2d, atomic_kind_set, &

                        molecule_set, molecule_only, particle_set=particle_set)


      DO ikind = 1, nkind

         CALL get_atomic_kind(atomic_kind_set(ikind), atom_list=atom2d(ikind)%list)

         CALL get_qs_kind(qs_kind_set(ikind), basis_set=orb_basis_set, basis_type="ORB")

         IF (ASSOCIATED(orb_basis_set)) THEN

            orb_present(ikind) = .true.

            CALL get_gto_basis_set(gto_basis_set=orb_basis_set, kind_radius=orb_radius(ikind))

         ELSE

            orb_present(ikind) = .false.

            orb_radius(ikind) = 0.0_dp

         END IF

         CALL get_qs_kind(qs_kind_set(ikind), basis_set=aux_fit_basis_set, basis_type=basis_type)

         IF (ASSOCIATED(aux_fit_basis_set)) THEN

            aux_fit_present(ikind) = .true.

            CALL get_gto_basis_set(gto_basis_set=aux_fit_basis_set, kind_radius=aux_fit_radius(ikind))

         ELSE

            aux_fit_present(ikind) = .false.

            aux_fit_radius(ikind) = 0.0_dp

         END IF

      END DO

      !

      CALL pair_radius_setup(aux_fit_present, aux_fit_present, aux_fit_radius, aux_fit_radius, pair_radius)

      CALL build_neighbor_lists(sab_aux, particle_set, atom2d, cell, pair_radius, &

                                mic=mic, molecular=molecule_only, subcells=subcells, nlname="sab_aux")

      CALL pair_radius_setup(aux_fit_present, orb_present, aux_fit_radius, orb_radius, pair_radius)

      CALL build_neighbor_lists(sab_aux_orb, particle_set, atom2d, cell, pair_radius, &

                                mic=mic, symmetric=.false., molecular=molecule_only, subcells=subcells, &

                                nlname="sab_aux_orb")


      ! Release work storage

      CALL atom2d_cleanup(atom2d)

      DEALLOCATE (atom2d)

      DEALLOCATE (orb_present, aux_fit_present)

      DEALLOCATE (orb_radius, aux_fit_radius)

      DEALLOCATE (pair_radius)


      CALL timestop(handle)


   END SUBROUTINE optbas_build_neighborlist


END MODULE optbas_opt_utils

cp_dbcsr_api::dbcsr_create
Definition cp_dbcsr_api.F:192

cp_fm_basic_linalg::cp_fm_trace
Definition cp_fm_basic_linalg.F:75

cp_fm_types::cp_fm_release
Definition cp_fm_types.F:87

parallel_gemm_api::parallel_gemm
Definition parallel_gemm_api.F:38

atomic_kind_types
Define the atomic kind types and their sub types.
Definition atomic_kind_types.F:23

atomic_kind_types::get_atomic_kind
subroutine, public get_atomic_kind(atomic_kind, fist_potential, element_symbol, name, mass, kind_number, natom, atom_list, rcov, rvdw, z, qeff, apol, cpol, mm_radius, shell, shell_active, damping)
Get attributes of an atomic kind.
Definition atomic_kind_types.F:138

basis_set_types
Definition basis_set_types.F:15

basis_set_types::get_gto_basis_set
subroutine, public get_gto_basis_set(gto_basis_set, name, aliases, norm_type, kind_radius, ncgf, nset, nsgf, cgf_symbol, sgf_symbol, norm_cgf, set_radius, lmax, lmin, lx, ly, lz, m, ncgf_set, npgf, nsgf_set, nshell, cphi, pgf_radius, sphi, scon, zet, first_cgf, first_sgf, l, last_cgf, last_sgf, n, gcc, maxco, maxl, maxpgf, maxsgf_set, maxshell, maxso, nco_sum, npgf_sum, nshell_sum, maxder, short_kind_radius, npgf_seg_sum)
...
Definition basis_set_types.F:624

cell_types
Handles all functions related to the CELL.
Definition cell_types.F:15

cp_blacs_env
methods related to the blacs parallel environment
Definition cp_blacs_env.F:15

cp_dbcsr_api
Definition cp_dbcsr_api.F:8

cp_dbcsr_api::dbcsr_transposed
subroutine, public dbcsr_transposed(transposed, normal, shallow_data_copy, transpose_distribution, use_distribution)
...
Definition cp_dbcsr_api.F:1219

cp_dbcsr_api::dbcsr_get_info
subroutine, public dbcsr_get_info(matrix, nblkrows_total, nblkcols_total, nfullrows_total, nfullcols_total, nblkrows_local, nblkcols_local, nfullrows_local, nfullcols_local, my_prow, my_pcol, local_rows, local_cols, proc_row_dist, proc_col_dist, row_blk_size, col_blk_size, row_blk_offset, col_blk_offset, distribution, name, matrix_type, group)
...
Definition cp_dbcsr_api.F:794

cp_dbcsr_api::dbcsr_release
subroutine, public dbcsr_release(matrix)
...
Definition cp_dbcsr_api.F:1119

cp_dbcsr_operations
DBCSR operations in CP2K.
Definition cp_dbcsr_operations.F:18

cp_dbcsr_operations::cp_dbcsr_sm_fm_multiply
subroutine, public cp_dbcsr_sm_fm_multiply(matrix, fm_in, fm_out, ncol, alpha, beta)
multiply a dbcsr with a fm matrix
Definition cp_dbcsr_operations.F:552

cp_dbcsr_operations::copy_dbcsr_to_fm
subroutine, public copy_dbcsr_to_fm(matrix, fm)
Copy a DBCSR matrix to a BLACS matrix.
Definition cp_dbcsr_operations.F:214

cp_fm_basic_linalg
basic linear algebra operations for full matrices
Definition cp_fm_basic_linalg.F:14

cp_fm_basic_linalg::cp_fm_invert
subroutine, public cp_fm_invert(matrix_a, matrix_inverse, det_a, eps_svd, eigval)
Inverts a cp_fm_type matrix, optionally returning the determinant of the input matrix.
Definition cp_fm_basic_linalg.F:2019

cp_fm_diag
used for collecting some of the diagonalization schemes available for cp_fm_type. cp_fm_power also mo...
Definition cp_fm_diag.F:17

cp_fm_diag::cp_fm_power
subroutine, public cp_fm_power(matrix, work, exponent, threshold, n_dependent, verbose, eigvals)
...
Definition cp_fm_diag.F:1038

cp_fm_struct
represent the structure of a full matrix
Definition cp_fm_struct.F:14

cp_fm_struct::cp_fm_struct_create
subroutine, public cp_fm_struct_create(fmstruct, para_env, context, nrow_global, ncol_global, nrow_block, ncol_block, descriptor, first_p_pos, local_leading_dimension, template_fmstruct, square_blocks, force_block)
allocates and initializes a full matrix structure
Definition cp_fm_struct.F:132

cp_fm_struct::cp_fm_struct_release
subroutine, public cp_fm_struct_release(fmstruct)
releases a full matrix structure
Definition cp_fm_struct.F:351

cp_fm_types
represent a full matrix distributed on many processors
Definition cp_fm_types.F:15

cp_fm_types::cp_fm_get_info
subroutine, public cp_fm_get_info(matrix, name, nrow_global, ncol_global, nrow_block, ncol_block, nrow_local, ncol_local, row_indices, col_indices, local_data, context, nrow_locals, ncol_locals, matrix_struct, para_env)
returns all kind of information about the full matrix
Definition cp_fm_types.F:1009

cp_fm_types::cp_fm_create
subroutine, public cp_fm_create(matrix, matrix_struct, name, use_sp)
creates a new full matrix with the given structure
Definition cp_fm_types.F:164

distribution_1d_types
stores a lists of integer that are local to a processor. The idea is that these integers represent ob...
Definition distribution_1d_types.F:24

distribution_2d_types
stores a mapping of 2D info (e.g. matrix) on a 2D processor distribution (i.e. blacs grid) where cpus...
Definition distribution_2d_types.F:15

input_section_types
objects that represent the structure of input sections and the data contained in an input section
Definition input_section_types.F:15

input_section_types::section_vals_val_get
subroutine, public section_vals_val_get(section_vals, keyword_name, i_rep_section, i_rep_val, n_rep_val, val, l_val, i_val, r_val, c_val, l_vals, i_vals, r_vals, c_vals, explicit)
returns the requested value
Definition input_section_types.F:1047

kinds
Defines the basic variable types.
Definition kinds.F:23

kinds::dp
integer, parameter, public dp
Definition kinds.F:34

message_passing
Interface to the message passing library MPI.
Definition message_passing.F:23

molecule_types
Define the data structure for the molecule information.
Definition molecule_types.F:16

optbas_opt_utils
Definition optbas_opt_utils.F:7

optbas_opt_utils::optbas_build_neighborlist
subroutine, public optbas_build_neighborlist(qs_env, sab_aux, sab_aux_orb, basis_type)
rebuilds neighborlist for absis sets
Definition optbas_opt_utils.F:223

optbas_opt_utils::evaluate_optvals
subroutine, public evaluate_optvals(mos, mos_aux_fit, matrix_ks, q, snew, s_inv_orb, fval, energy, s_cond_number)
...
Definition optbas_opt_utils.F:81

optbas_opt_utils::fit_mo_coeffs
subroutine, public fit_mo_coeffs(saux, sauxorb, mos, mosaux)
...
Definition optbas_opt_utils.F:155

parallel_gemm_api
basic linear algebra operations for full matrixes
Definition parallel_gemm_api.F:14

particle_types
Define the data structure for the particle information.
Definition particle_types.F:19

qs_condnum
Calculation of overlap matrix condition numbers.
Definition qs_condnum.F:13

qs_condnum::overlap_condnum
subroutine, public overlap_condnum(matrixkp_s, condnum, iunit, norml1, norml2, use_arnoldi, blacs_env)
Calculation of the overlap matrix Condition Number.
Definition qs_condnum.F:66

qs_environment_types
Definition qs_environment_types.F:14

qs_environment_types::get_qs_env
subroutine, public get_qs_env(qs_env, atomic_kind_set, qs_kind_set, cell, super_cell, cell_ref, use_ref_cell, kpoints, dft_control, mos, sab_orb, sab_all, qmmm, qmmm_periodic, sac_ae, sac_ppl, sac_lri, sap_ppnl, sab_vdw, sab_scp, sap_oce, sab_lrc, sab_se, sab_xtbe, sab_tbe, sab_core, sab_xb, sab_xtb_pp, sab_xtb_nonbond, sab_almo, sab_kp, sab_kp_nosym, particle_set, energy, force, matrix_h, matrix_h_im, matrix_ks, matrix_ks_im, matrix_vxc, run_rtp, rtp, matrix_h_kp, matrix_h_im_kp, matrix_ks_kp, matrix_ks_im_kp, matrix_vxc_kp, kinetic_kp, matrix_s_kp, matrix_w_kp, matrix_s_ri_aux_kp, matrix_s, matrix_s_ri_aux, matrix_w, matrix_p_mp2, matrix_p_mp2_admm, rho, rho_xc, pw_env, ewald_env, ewald_pw, active_space, mpools, input, para_env, blacs_env, scf_control, rel_control, kinetic, qs_charges, vppl, rho_core, rho_nlcc, rho_nlcc_g, ks_env, ks_qmmm_env, wf_history, scf_env, local_particles, local_molecules, distribution_2d, dbcsr_dist, molecule_kind_set, molecule_set, subsys, cp_subsys, oce, local_rho_set, rho_atom_set, task_list, task_list_soft, rho0_atom_set, rho0_mpole, rhoz_set, ecoul_1c, rho0_s_rs, rho0_s_gs, do_kpoints, has_unit_metric, requires_mo_derivs, mo_derivs, mo_loc_history, nkind, natom, nelectron_total, nelectron_spin, efield, neighbor_list_id, linres_control, xas_env, virial, cp_ddapc_env, cp_ddapc_ewald, outer_scf_history, outer_scf_ihistory, x_data, et_coupling, dftb_potential, results, se_taper, se_store_int_env, se_nddo_mpole, se_nonbond_env, admm_env, lri_env, lri_density, exstate_env, ec_env, harris_env, dispersion_env, gcp_env, vee, rho_external, external_vxc, mask, mp2_env, bs_env, kg_env, wanniercentres, atprop, ls_scf_env, do_transport, transport_env, v_hartree_rspace, s_mstruct_changed, rho_changed, potential_changed, forces_up_to_date, mscfg_env, almo_scf_env, gradient_history, variable_history, embed_pot, spin_embed_pot, polar_env, mos_last_converged, eeq, rhs)
Get the QUICKSTEP environment.
Definition qs_environment_types.F:514

qs_kind_types
Define the quickstep kind type and their sub types.
Definition qs_kind_types.F:23

qs_kind_types::get_qs_kind
subroutine, public get_qs_kind(qs_kind, basis_set, basis_type, ncgf, nsgf, all_potential, tnadd_potential, gth_potential, sgp_potential, upf_potential, se_parameter, dftb_parameter, xtb_parameter, dftb3_param, zatom, zeff, elec_conf, mao, lmax_dftb, alpha_core_charge, ccore_charge, core_charge, core_charge_radius, paw_proj_set, paw_atom, hard_radius, hard0_radius, max_rad_local, covalent_radius, vdw_radius, gpw_type_forced, harmonics, max_iso_not0, max_s_harm, grid_atom, ngrid_ang, ngrid_rad, lmax_rho0, dft_plus_u_atom, l_of_dft_plus_u, n_of_dft_plus_u, u_minus_j, u_of_dft_plus_u, j_of_dft_plus_u, alpha_of_dft_plus_u, beta_of_dft_plus_u, j0_of_dft_plus_u, occupation_of_dft_plus_u, dispersion, bs_occupation, magnetization, no_optimize, addel, laddel, naddel, orbitals, max_scf, eps_scf, smear, u_ramping, u_minus_j_target, eps_u_ramping, init_u_ramping_each_scf, reltmat, ghost, floating, name, element_symbol, pao_basis_size, pao_model_file, pao_potentials, pao_descriptors, nelec)
Get attributes of an atomic kind.
Definition qs_kind_types.F:454

qs_ks_types
Definition qs_ks_types.F:15

qs_mo_types
Definition and initialisation of the mo data type.
Definition qs_mo_types.F:22

qs_mo_types::get_mo_set
subroutine, public get_mo_set(mo_set, maxocc, homo, lfomo, nao, nelectron, n_el_f, nmo, eigenvalues, occupation_numbers, mo_coeff, mo_coeff_b, uniform_occupation, kts, mu, flexible_electron_count)
Get the components of a MO set data structure.
Definition qs_mo_types.F:397

qs_neighbor_list_types
Define the neighbor list data types and the corresponding functionality.
Definition qs_neighbor_list_types.F:17

qs_neighbor_lists
Generate the atomic neighbor lists.
Definition qs_neighbor_lists.F:19

qs_neighbor_lists::atom2d_cleanup
subroutine, public atom2d_cleanup(atom2d)
free the internals of atom2d
Definition qs_neighbor_lists.F:130

qs_neighbor_lists::pair_radius_setup
subroutine, public pair_radius_setup(present_a, present_b, radius_a, radius_b, pair_radius, prmin)
...
Definition qs_neighbor_lists.F:1626

qs_neighbor_lists::build_neighbor_lists
subroutine, public build_neighbor_lists(ab_list, particle_set, atom, cell, pair_radius, subcells, mic, symmetric, molecular, subset_of_mol, current_subset, operator_type, nlname, atomb_to_keep)
Build simple pair neighbor lists.
Definition qs_neighbor_lists.F:1028

qs_neighbor_lists::atom2d_build
subroutine, public atom2d_build(atom2d, distribution_1d, distribution_2d, atomic_kind_set, molecule_set, molecule_only, particle_set)
Build some distribution structure of atoms, refactored from build_qs_neighbor_lists.
Definition qs_neighbor_lists.F:172

atomic_kind_types::atomic_kind_type
Provides all information about an atomic kind.
Definition atomic_kind_types.F:45

basis_set_types::gto_basis_set_type
Definition basis_set_types.F:72

cell_types::cell_type
Type defining parameters related to the simulation cell.
Definition cell_types.F:55

cp_blacs_env::cp_blacs_env_type
represent a blacs multidimensional parallel environment (for the mpi corrispective see cp_paratypes/m...
Definition cp_blacs_env.F:53

cp_dbcsr_api::dbcsr_distribution_type
Definition cp_dbcsr_api.F:180

cp_dbcsr_api::dbcsr_p_type
Definition cp_dbcsr_api.F:170

cp_dbcsr_api::dbcsr_type
Definition cp_dbcsr_api.F:174

cp_fm_struct::cp_fm_struct_type
keeps the information about the structure of a full matrix
Definition cp_fm_struct.F:82

cp_fm_types::cp_fm_type
represent a full matrix
Definition cp_fm_types.F:113

distribution_1d_types::distribution_1d_type
structure to store local (to a processor) ordered lists of integers.
Definition distribution_1d_types.F:62

distribution_2d_types::distribution_2d_type
distributes pairs on a 2d grid of processors
Definition distribution_2d_types.F:62

message_passing::mp_para_env_type
stores all the informations relevant to an mpi environment
Definition message_passing.F:763

molecule_types::molecule_type
Definition molecule_types.F:110

particle_types::particle_type
Definition particle_types.F:35

qs_environment_types::qs_environment_type
Definition qs_environment_types.F:217

qs_kind_types::qs_kind_type
Provides all information about a quickstep kind.
Definition qs_kind_types.F:171

qs_ks_types::qs_ks_env_type
calculation environment to calculate the ks matrix, holds all the needed vars. assumes that the core ...
Definition qs_ks_types.F:136

qs_mo_types::mo_set_type
Definition qs_mo_types.F:46

qs_neighbor_list_types::neighbor_list_set_p_type
Definition qs_neighbor_list_types.F:67

qs_neighbor_lists::local_atoms_type
Definition qs_neighbor_lists.F:103