(git:374b731)
Loading...
Searching...
No Matches
qs_core_energies.F
Go to the documentation of this file.
1!--------------------------------------------------------------------------------------------------!
2! CP2K: A general program to perform molecular dynamics simulations !
3! Copyright 2000-2024 CP2K developers group <https://cp2k.org> !
4! !
5! SPDX-License-Identifier: GPL-2.0-or-later !
6!--------------------------------------------------------------------------------------------------!
7
8! **************************************************************************************************
9!> \brief Calculation of the energies concerning the core charge distribution
10!> \par History
11!> - Full refactoring of calculate_ecore and calculate_ecore_overlap (jhu)
12!> \author Matthias Krack (27.04.2001)
13! **************************************************************************************************
14MODULE qs_core_energies
15 USE atomic_kind_types, ONLY: atomic_kind_type,&
16 get_atomic_kind,&
17 get_atomic_kind_set
18 USE atprop_types, ONLY: atprop_array_init,&
19 atprop_type
20 USE cell_types, ONLY: cell_type,&
21 pbc
22 USE dbcsr_api, ONLY: dbcsr_dot,&
23 dbcsr_p_type,&
24 dbcsr_type
25 USE distribution_1d_types, ONLY: distribution_1d_type
26 USE kinds, ONLY: dp
27 USE mathconstants, ONLY: oorootpi,&
28 twopi
29 USE message_passing, ONLY: mp_comm_type,&
30 mp_para_env_type
31 USE particle_types, ONLY: particle_type
32 USE qs_energy_types, ONLY: qs_energy_type
33 USE qs_environment_types, ONLY: get_qs_env,&
34 qs_environment_type
35 USE qs_force_types, ONLY: qs_force_type
36 USE qs_kind_types, ONLY: get_qs_kind,&
37 qs_kind_type
38 USE qs_neighbor_list_types, ONLY: get_iterator_info,&
39 neighbor_list_iterate,&
40 neighbor_list_iterator_create,&
41 neighbor_list_iterator_p_type,&
42 neighbor_list_iterator_release,&
43 neighbor_list_set_p_type
44 USE virial_methods, ONLY: virial_pair_force
45 USE virial_types, ONLY: virial_type
46#include "./base/base_uses.f90"
47
48 IMPLICIT NONE
49
50 PRIVATE
51
52! *** Global parameters ***
53
54 CHARACTER(len=*), PARAMETER, PRIVATE :: moduleN = 'qs_core_energies'
55
56 PUBLIC :: calculate_ptrace, &
57 calculate_ecore_overlap, &
58 calculate_ecore_self, calculate_ecore_alpha
59
60 INTERFACE calculate_ptrace
61 MODULE PROCEDURE calculate_ptrace_1, calculate_ptrace_gamma, calculate_ptrace_kp
62 END INTERFACE
63
64! **************************************************************************************************
65
66CONTAINS
67
68! **************************************************************************************************
69!> \brief Calculate the trace of a operator matrix with the density matrix.
70!> Sum over all spin components (in P, no spin in H)
71!> \param hmat ...
72!> \param pmat ...
73!> \param ecore ...
74!> \param nspin ...
75!> \date 29.07.2014
76!> \par History
77!> - none
78!> \author JGH
79!> \version 1.0
80! **************************************************************************************************
81 SUBROUTINE calculate_ptrace_gamma(hmat, pmat, ecore, nspin)
82
83 TYPE(dbcsr_p_type), DIMENSION(:), POINTER :: hmat, pmat
84 REAL(KIND=dp), INTENT(OUT) :: ecore
85 INTEGER, INTENT(IN) :: nspin
86
87 CHARACTER(len=*), PARAMETER :: routineN = 'calculate_ptrace_gamma'
88
89 INTEGER :: handle, ispin
90 REAL(KIND=dp) :: etr
91
92 CALL timeset(routinen, handle)
93
94 ecore = 0.0_dp
95 DO ispin = 1, nspin
96 etr = 0.0_dp
97 CALL dbcsr_dot(hmat(1)%matrix, pmat(ispin)%matrix, etr)
98 ecore = ecore + etr
99 END DO
100
101 CALL timestop(handle)
102
103 END SUBROUTINE calculate_ptrace_gamma
104
105! **************************************************************************************************
106!> \brief Calculate the trace of a operator matrix with the density matrix.
107!> Sum over all spin components (in P, no spin in H) and the real space
108!> coordinates
109!> \param hmat H matrix
110!> \param pmat P matrices
111!> \param ecore Tr(HP) output
112!> \param nspin Number of P matrices
113!> \date 29.07.2014
114!> \author JGH
115!> \version 1.0
116! **************************************************************************************************
117 SUBROUTINE calculate_ptrace_kp(hmat, pmat, ecore, nspin)
118
119 TYPE(dbcsr_p_type), DIMENSION(:, :), POINTER :: hmat, pmat
120 REAL(kind=dp), INTENT(OUT) :: ecore
121 INTEGER, INTENT(IN) :: nspin
122
123 CHARACTER(len=*), PARAMETER :: routinen = 'calculate_ptrace_kp'
124
125 INTEGER :: handle, ic, ispin, nc
126 REAL(kind=dp) :: etr
127
128 CALL timeset(routinen, handle)
129
130 nc = SIZE(pmat, 2)
131
132 ecore = 0.0_dp
133 DO ispin = 1, nspin
134 DO ic = 1, nc
135 etr = 0.0_dp
136 CALL dbcsr_dot(hmat(1, ic)%matrix, pmat(ispin, ic)%matrix, etr)
137 ecore = ecore + etr
138 END DO
139 END DO
140
141 CALL timestop(handle)
142
143 END SUBROUTINE calculate_ptrace_kp
144
145! **************************************************************************************************
146!> \brief Calculate the core Hamiltonian energy which includes the kinetic
147!> and the potential energy of the electrons. It is assumed, that
148!> the core Hamiltonian matrix h and the density matrix p have the
149!> same sparse matrix structure (same atomic blocks and block
150!> ordering)
151!> \param h ...
152!> \param p ...
153!> \param ecore ...
154!> \date 03.05.2001
155!> \par History
156!> - simplified taking advantage of new non-redundant matrix
157!> structure (27.06.2003,MK)
158!> - simplified using DBCSR trace function (21.07.2010, jhu)
159!> \author MK
160!> \version 1.0
161! **************************************************************************************************
162 SUBROUTINE calculate_ptrace_1(h, p, ecore)
163
164 TYPE(dbcsr_type), POINTER :: h, p
165 REAL(kind=dp), INTENT(OUT) :: ecore
166
167 CHARACTER(len=*), PARAMETER :: routinen = 'calculate_ptrace_1'
168
169 INTEGER :: handle
170
171 CALL timeset(routinen, handle)
172
173 ecore = 0.0_dp
174 CALL dbcsr_dot(h, p, ecore)
175
176 CALL timestop(handle)
177
178 END SUBROUTINE calculate_ptrace_1
179
180! **************************************************************************************************
181!> \brief Calculate the overlap energy of the core charge distribution.
182!> \param qs_env ...
183!> \param para_env ...
184!> \param calculate_forces ...
185!> \param molecular ...
186!> \param E_overlap_core ...
187!> \param atecc ...
188!> \date 30.04.2001
189!> \par History
190!> - Force calculation added (03.06.2002,MK)
191!> - Parallelized using a list of local atoms for rows and
192!> columns (19.07.2003,MK)
193!> - Use precomputed neighborlists (sab_core) and nl iterator (28.07.2010,jhu)
194!> \author MK
195!> \version 1.0
196! **************************************************************************************************
197 SUBROUTINE calculate_ecore_overlap(qs_env, para_env, calculate_forces, molecular, &
198 E_overlap_core, atecc)
199 TYPE(qs_environment_type), POINTER :: qs_env
200 TYPE(mp_para_env_type), POINTER :: para_env
201 LOGICAL, INTENT(IN) :: calculate_forces
202 LOGICAL, INTENT(IN), OPTIONAL :: molecular
203 REAL(kind=dp), INTENT(OUT), OPTIONAL :: e_overlap_core
204 REAL(kind=dp), DIMENSION(:), OPTIONAL :: atecc
205
206 CHARACTER(len=*), PARAMETER :: routinen = 'calculate_ecore_overlap'
207
208 INTEGER :: atom_a, atom_b, handle, iatom, ikind, &
209 jatom, jkind, natom, nkind
210 INTEGER, ALLOCATABLE, DIMENSION(:) :: atom_of_kind
211 LOGICAL :: atenergy, only_molecule, use_virial
212 REAL(kind=dp) :: aab, dab, eab, ecore_overlap, f, fab, &
213 rab2, rootaab, zab
214 REAL(kind=dp), ALLOCATABLE, DIMENSION(:) :: alpha, radius, zeff
215 REAL(kind=dp), DIMENSION(3) :: deab, rab
216 REAL(kind=dp), DIMENSION(3, 3) :: pv_loc
217 TYPE(atomic_kind_type), DIMENSION(:), POINTER :: atomic_kind_set
218 TYPE(atprop_type), POINTER :: atprop
219 TYPE(mp_comm_type) :: group
220 TYPE(neighbor_list_iterator_p_type), &
221 DIMENSION(:), POINTER :: nl_iterator
222 TYPE(neighbor_list_set_p_type), DIMENSION(:), &
223 POINTER :: sab_core
224 TYPE(particle_type), DIMENSION(:), POINTER :: particle_set
225 TYPE(qs_energy_type), POINTER :: energy
226 TYPE(qs_force_type), DIMENSION(:), POINTER :: force
227 TYPE(qs_kind_type), DIMENSION(:), POINTER :: qs_kind_set
228 TYPE(virial_type), POINTER :: virial
229
230 CALL timeset(routinen, handle)
231
232 NULLIFY (atomic_kind_set)
233 NULLIFY (qs_kind_set)
234 NULLIFY (energy)
235 NULLIFY (atprop)
236 NULLIFY (force)
237 NULLIFY (particle_set)
238
239 group = para_env
240
241 only_molecule = .false.
242 IF (PRESENT(molecular)) only_molecule = molecular
243
244 CALL get_qs_env(qs_env=qs_env, &
245 atomic_kind_set=atomic_kind_set, &
246 qs_kind_set=qs_kind_set, &
247 particle_set=particle_set, &
248 energy=energy, &
249 force=force, &
250 sab_core=sab_core, &
251 atprop=atprop, &
252 virial=virial)
253
254 ! Allocate work storage
255 nkind = SIZE(atomic_kind_set)
256 natom = SIZE(particle_set)
257
258 use_virial = virial%pv_availability .AND. (.NOT. virial%pv_numer)
259
260 ALLOCATE (alpha(nkind), radius(nkind), zeff(nkind))
261 alpha(:) = 0.0_dp
262 radius(:) = 0.0_dp
263 zeff(:) = 0.0_dp
264
265 IF (calculate_forces) THEN
266 CALL get_atomic_kind_set(atomic_kind_set, atom_of_kind=atom_of_kind)
267 END IF
268
269 atenergy = .false.
270 IF (ASSOCIATED(atprop)) THEN
271 IF (atprop%energy) THEN
272 atenergy = .true.
273 CALL atprop_array_init(atprop%atecc, natom)
274 END IF
275 END IF
276
277 DO ikind = 1, nkind
278 CALL get_qs_kind(qs_kind_set(ikind), &
279 alpha_core_charge=alpha(ikind), &
280 core_charge_radius=radius(ikind), &
281 zeff=zeff(ikind))
282 END DO
283
284 ecore_overlap = 0.0_dp
285 pv_loc = 0.0_dp
286
287 CALL neighbor_list_iterator_create(nl_iterator, sab_core)
288 DO WHILE (neighbor_list_iterate(nl_iterator) == 0)
289 CALL get_iterator_info(nl_iterator, ikind=ikind, jkind=jkind, iatom=iatom, jatom=jatom, r=rab)
290 zab = zeff(ikind)*zeff(jkind)
291 aab = alpha(ikind)*alpha(jkind)/(alpha(ikind) + alpha(jkind))
292 rootaab = sqrt(aab)
293 fab = 2.0_dp*oorootpi*zab*rootaab
294 rab2 = rab(1)*rab(1) + rab(2)*rab(2) + rab(3)*rab(3)
295 IF (rab2 > 1.e-8_dp) THEN
296 IF (ikind == jkind .AND. iatom == jatom) THEN
297 f = 0.5_dp
298 ELSE
299 f = 1.0_dp
300 END IF
301 dab = sqrt(rab2)
302 eab = zab*erfc(rootaab*dab)/dab
303 ecore_overlap = ecore_overlap + f*eab
304 IF (atenergy) THEN
305 atprop%atecc(iatom) = atprop%atecc(iatom) + 0.5_dp*f*eab
306 atprop%atecc(jatom) = atprop%atecc(jatom) + 0.5_dp*f*eab
307 END IF
308 IF (PRESENT(atecc)) THEN
309 atecc(iatom) = atecc(iatom) + 0.5_dp*f*eab
310 atecc(jatom) = atecc(jatom) + 0.5_dp*f*eab
311 END IF
312 IF (calculate_forces) THEN
313 deab(:) = rab(:)*f*(eab + fab*exp(-aab*rab2))/rab2
314 atom_a = atom_of_kind(iatom)
315 atom_b = atom_of_kind(jatom)
316 force(ikind)%core_overlap(:, atom_a) = force(ikind)%core_overlap(:, atom_a) + deab(:)
317 force(jkind)%core_overlap(:, atom_b) = force(jkind)%core_overlap(:, atom_b) - deab(:)
318 IF (use_virial) THEN
319 CALL virial_pair_force(pv_loc, 1._dp, deab, rab)
320 END IF
321 END IF
322 END IF
323 END DO
324 CALL neighbor_list_iterator_release(nl_iterator)
325
326 DEALLOCATE (alpha, radius, zeff)
327 IF (calculate_forces) THEN
328 DEALLOCATE (atom_of_kind)
329 END IF
330 IF (calculate_forces .AND. use_virial) THEN
331 virial%pv_ecore_overlap = virial%pv_ecore_overlap + pv_loc
332 virial%pv_virial = virial%pv_virial + pv_loc
333 END IF
334
335 CALL group%sum(ecore_overlap)
336
337 energy%core_overlap = ecore_overlap
338
339 IF (PRESENT(e_overlap_core)) THEN
340 e_overlap_core = energy%core_overlap
341 END IF
342
343 CALL timestop(handle)
344
345 END SUBROUTINE calculate_ecore_overlap
346
347! **************************************************************************************************
348!> \brief Calculate the self energy of the core charge distribution.
349!> \param qs_env ...
350!> \param E_self_core ...
351!> \param atecc ...
352!> \date 27.04.2001
353!> \author MK
354!> \version 1.0
355! **************************************************************************************************
356 SUBROUTINE calculate_ecore_self(qs_env, E_self_core, atecc)
357 TYPE(qs_environment_type), POINTER :: qs_env
358 REAL(kind=dp), INTENT(OUT), OPTIONAL :: e_self_core
359 REAL(kind=dp), DIMENSION(:), OPTIONAL :: atecc
360
361 CHARACTER(len=*), PARAMETER :: routinen = 'calculate_ecore_self'
362
363 INTEGER :: handle, iatom, ikind, iparticle_local, &
364 natom, nparticle_local
365 REAL(kind=dp) :: alpha_core_charge, ecore_self, es, zeff
366 TYPE(atomic_kind_type), DIMENSION(:), POINTER :: atomic_kind_set
367 TYPE(atprop_type), POINTER :: atprop
368 TYPE(distribution_1d_type), POINTER :: local_particles
369 TYPE(particle_type), DIMENSION(:), POINTER :: particle_set
370 TYPE(qs_energy_type), POINTER :: energy
371 TYPE(qs_kind_type), DIMENSION(:), POINTER :: qs_kind_set
372
373! -------------------------------------------------------------------------
374
375 NULLIFY (atprop)
376 CALL timeset(routinen, handle)
377
378 CALL get_qs_env(qs_env=qs_env, atomic_kind_set=atomic_kind_set, &
379 qs_kind_set=qs_kind_set, energy=energy, atprop=atprop)
380
381 ecore_self = 0.0_dp
382
383 DO ikind = 1, SIZE(atomic_kind_set)
384 CALL get_atomic_kind(atomic_kind_set(ikind), natom=natom)
385 CALL get_qs_kind(qs_kind_set(ikind), zeff=zeff, alpha_core_charge=alpha_core_charge)
386 ecore_self = ecore_self - real(natom, dp)*zeff**2*sqrt(alpha_core_charge)
387 END DO
388
389 energy%core_self = ecore_self/sqrt(twopi)
390 IF (PRESENT(e_self_core)) THEN
391 e_self_core = energy%core_self
392 END IF
393
394 IF (ASSOCIATED(atprop)) THEN
395 IF (atprop%energy) THEN
396 ! atomic energy
397 CALL get_qs_env(qs_env=qs_env, particle_set=particle_set, &
398 local_particles=local_particles)
399 natom = SIZE(particle_set)
400 CALL atprop_array_init(atprop%ateself, natom)
401
402 DO ikind = 1, SIZE(atomic_kind_set)
403 nparticle_local = local_particles%n_el(ikind)
404 CALL get_qs_kind(qs_kind_set(ikind), zeff=zeff, alpha_core_charge=alpha_core_charge)
405 es = zeff**2*sqrt(alpha_core_charge)/sqrt(twopi)
406 DO iparticle_local = 1, nparticle_local
407 iatom = local_particles%list(ikind)%array(iparticle_local)
408 atprop%ateself(iatom) = atprop%ateself(iatom) - es
409 END DO
410 END DO
411 END IF
412 END IF
413 IF (PRESENT(atecc)) THEN
414 ! atomic energy
415 CALL get_qs_env(qs_env=qs_env, particle_set=particle_set, &
416 local_particles=local_particles)
417 natom = SIZE(particle_set)
418 DO ikind = 1, SIZE(atomic_kind_set)
419 nparticle_local = local_particles%n_el(ikind)
420 CALL get_qs_kind(qs_kind_set(ikind), zeff=zeff, alpha_core_charge=alpha_core_charge)
421 es = zeff**2*sqrt(alpha_core_charge)/sqrt(twopi)
422 DO iparticle_local = 1, nparticle_local
423 iatom = local_particles%list(ikind)%array(iparticle_local)
424 atecc(iatom) = atecc(iatom) - es
425 END DO
426 END DO
427 END IF
428
429 CALL timestop(handle)
430
431 END SUBROUTINE calculate_ecore_self
432
433! **************************************************************************************************
434!> \brief Calculate the overlap and self energy of the core charge distribution for a given alpha
435!> Use a minimum image convention and double loop over all atoms
436!> \param qs_env ...
437!> \param alpha ...
438!> \param atecc ...
439!> \author JGH
440!> \version 1.0
441! **************************************************************************************************
442 SUBROUTINE calculate_ecore_alpha(qs_env, alpha, atecc)
443 TYPE(qs_environment_type), POINTER :: qs_env
444 REAL(kind=dp), INTENT(IN) :: alpha
445 REAL(kind=dp), DIMENSION(:) :: atecc
446
447 CHARACTER(len=*), PARAMETER :: routinen = 'calculate_ecore_alpha'
448
449 INTEGER :: handle, iatom, ikind, jatom, jkind, &
450 natom, nkind
451 INTEGER, ALLOCATABLE, DIMENSION(:) :: kind_of
452 REAL(kind=dp) :: dab, eab, fab, rootaab, zab
453 REAL(kind=dp), ALLOCATABLE, DIMENSION(:) :: zeff
454 REAL(kind=dp), DIMENSION(3) :: rab
455 TYPE(atomic_kind_type), DIMENSION(:), POINTER :: atomic_kind_set
456 TYPE(cell_type), POINTER :: cell
457 TYPE(particle_type), DIMENSION(:), POINTER :: particle_set
458 TYPE(qs_kind_type), DIMENSION(:), POINTER :: qs_kind_set
459
460 CALL timeset(routinen, handle)
461
462 CALL get_qs_env(qs_env=qs_env, &
463 cell=cell, &
464 atomic_kind_set=atomic_kind_set, &
465 qs_kind_set=qs_kind_set, &
466 particle_set=particle_set)
467 CALL get_atomic_kind_set(atomic_kind_set=atomic_kind_set, kind_of=kind_of)
468 !
469 nkind = SIZE(atomic_kind_set)
470 natom = SIZE(particle_set)
471 ALLOCATE (zeff(nkind))
472 zeff(:) = 0.0_dp
473 DO ikind = 1, nkind
474 CALL get_qs_kind(qs_kind_set(ikind), zeff=zeff(ikind))
475 END DO
476
477 rootaab = sqrt(0.5_dp*alpha)
478 DO iatom = 1, natom
479 ikind = kind_of(iatom)
480 atecc(iatom) = atecc(iatom) - zeff(ikind)**2*sqrt(alpha/twopi)
481 DO jatom = iatom + 1, natom
482 jkind = kind_of(jatom)
483 zab = zeff(ikind)*zeff(jkind)
484 fab = 2.0_dp*oorootpi*zab*rootaab
485 rab = particle_set(iatom)%r - particle_set(jatom)%r
486 rab = pbc(rab, cell)
487 dab = sqrt(sum(rab(:)**2))
488 eab = zab*erfc(rootaab*dab)/dab
489 atecc(iatom) = atecc(iatom) + 0.5_dp*eab
490 atecc(jatom) = atecc(jatom) + 0.5_dp*eab
491 END DO
492 END DO
493
494 DEALLOCATE (zeff)
495
496 CALL timestop(handle)
497
498 END SUBROUTINE calculate_ecore_alpha
499
500END MODULE qs_core_energies
cell_types::pbc
Definition cell_types.F:92
qs_core_energies::calculate_ptrace
Definition qs_core_energies.F:60
atomic_kind_types
Define the atomic kind types and their sub types.
Definition atomic_kind_types.F:23
atomic_kind_types::get_atomic_kind_set
subroutine, public get_atomic_kind_set(atomic_kind_set, atom_of_kind, kind_of, natom_of_kind, maxatom, natom, nshell, fist_potential_present, shell_present, shell_adiabatic, shell_check_distance, damping_present)
Get attributes of an atomic kind set.
Definition atomic_kind_types.F:223
atomic_kind_types::get_atomic_kind
subroutine, public get_atomic_kind(atomic_kind, fist_potential, element_symbol, name, mass, kind_number, natom, atom_list, rcov, rvdw, z, qeff, apol, cpol, mm_radius, shell, shell_active, damping)
Get attributes of an atomic kind.
Definition atomic_kind_types.F:138
atprop_types
Holds information on atomic properties.
Definition atprop_types.F:14
atprop_types::atprop_array_init
subroutine, public atprop_array_init(atarray, natom)
...
Definition atprop_types.F:98
cell_types
Handles all functions related to the CELL.
Definition cell_types.F:15
distribution_1d_types
stores a lists of integer that are local to a processor. The idea is that these integers represent ob...
Definition distribution_1d_types.F:24
kinds
Defines the basic variable types.
Definition kinds.F:23
kinds::dp
integer, parameter, public dp
Definition kinds.F:34
mathconstants
Definition of mathematical constants and functions.
Definition mathconstants.F:16
mathconstants::oorootpi
real(kind=dp), parameter, public oorootpi
Definition mathconstants.F:115
mathconstants::twopi
real(kind=dp), parameter, public twopi
Definition mathconstants.F:112
message_passing
Interface to the message passing library MPI.
Definition message_passing.F:23
particle_types
Define the data structure for the particle information.
Definition particle_types.F:19
qs_core_energies
Calculation of the energies concerning the core charge distribution.
Definition qs_core_energies.F:14
qs_core_energies::calculate_ecore_overlap
subroutine, public calculate_ecore_overlap(qs_env, para_env, calculate_forces, molecular, e_overlap_core, atecc)
Calculate the overlap energy of the core charge distribution.
Definition qs_core_energies.F:199
qs_core_energies::calculate_ecore_self
subroutine, public calculate_ecore_self(qs_env, e_self_core, atecc)
Calculate the self energy of the core charge distribution.
Definition qs_core_energies.F:357
qs_core_energies::calculate_ecore_alpha
subroutine, public calculate_ecore_alpha(qs_env, alpha, atecc)
Calculate the overlap and self energy of the core charge distribution for a given alpha Use a minimum...
Definition qs_core_energies.F:443
qs_energy_types
Definition qs_energy_types.F:14
qs_environment_types
Definition qs_environment_types.F:14
qs_environment_types::get_qs_env
subroutine, public get_qs_env(qs_env, atomic_kind_set, qs_kind_set, cell, super_cell, cell_ref, use_ref_cell, kpoints, dft_control, mos, sab_orb, sab_all, qmmm, qmmm_periodic, sac_ae, sac_ppl, sac_lri, sap_ppnl, sab_vdw, sab_scp, sap_oce, sab_lrc, sab_se, sab_xtbe, sab_tbe, sab_core, sab_xb, sab_xtb_nonbond, sab_almo, sab_kp, sab_kp_nosym, particle_set, energy, force, matrix_h, matrix_h_im, matrix_ks, matrix_ks_im, matrix_vxc, run_rtp, rtp, matrix_h_kp, matrix_h_im_kp, matrix_ks_kp, matrix_ks_im_kp, matrix_vxc_kp, kinetic_kp, matrix_s_kp, matrix_w_kp, matrix_s_ri_aux_kp, matrix_s, matrix_s_ri_aux, matrix_w, matrix_p_mp2, matrix_p_mp2_admm, rho, rho_xc, pw_env, ewald_env, ewald_pw, active_space, mpools, input, para_env, blacs_env, scf_control, rel_control, kinetic, qs_charges, vppl, rho_core, rho_nlcc, rho_nlcc_g, ks_env, ks_qmmm_env, wf_history, scf_env, local_particles, local_molecules, distribution_2d, dbcsr_dist, molecule_kind_set, molecule_set, subsys, cp_subsys, oce, local_rho_set, rho_atom_set, task_list, task_list_soft, rho0_atom_set, rho0_mpole, rhoz_set, ecoul_1c, rho0_s_rs, rho0_s_gs, do_kpoints, has_unit_metric, requires_mo_derivs, mo_derivs, mo_loc_history, nkind, natom, nelectron_total, nelectron_spin, efield, neighbor_list_id, linres_control, xas_env, virial, cp_ddapc_env, cp_ddapc_ewald, outer_scf_history, outer_scf_ihistory, x_data, et_coupling, dftb_potential, results, se_taper, se_store_int_env, se_nddo_mpole, se_nonbond_env, admm_env, lri_env, lri_density, exstate_env, ec_env, dispersion_env, gcp_env, vee, rho_external, external_vxc, mask, mp2_env, bs_env, kg_env, wanniercentres, atprop, ls_scf_env, do_transport, transport_env, v_hartree_rspace, s_mstruct_changed, rho_changed, potential_changed, forces_up_to_date, mscfg_env, almo_scf_env, gradient_history, variable_history, embed_pot, spin_embed_pot, polar_env, mos_last_converged, rhs)
Get the QUICKSTEP environment.
Definition qs_environment_types.F:502
qs_force_types
Definition qs_force_types.F:13
qs_kind_types
Define the quickstep kind type and their sub types.
Definition qs_kind_types.F:23
qs_kind_types::get_qs_kind
subroutine, public get_qs_kind(qs_kind, basis_set, basis_type, ncgf, nsgf, all_potential, tnadd_potential, gth_potential, sgp_potential, upf_potential, se_parameter, dftb_parameter, xtb_parameter, dftb3_param, zeff, elec_conf, mao, lmax_dftb, alpha_core_charge, ccore_charge, core_charge, core_charge_radius, paw_proj_set, paw_atom, hard_radius, hard0_radius, max_rad_local, covalent_radius, vdw_radius, gpw_r3d_rs_type_forced, harmonics, max_iso_not0, max_s_harm, grid_atom, ngrid_ang, ngrid_rad, lmax_rho0, dft_plus_u_atom, l_of_dft_plus_u, n_of_dft_plus_u, u_minus_j, u_of_dft_plus_u, j_of_dft_plus_u, alpha_of_dft_plus_u, beta_of_dft_plus_u, j0_of_dft_plus_u, occupation_of_dft_plus_u, dispersion, bs_occupation, magnetization, no_optimize, addel, laddel, naddel, orbitals, max_scf, eps_scf, smear, u_ramping, u_minus_j_target, eps_u_ramping, init_u_ramping_each_scf, reltmat, ghost, floating, name, element_symbol, pao_basis_size, pao_potentials, pao_descriptors, nelec)
Get attributes of an atomic kind.
Definition qs_kind_types.F:451
qs_neighbor_list_types
Define the neighbor list data types and the corresponding functionality.
Definition qs_neighbor_list_types.F:17
qs_neighbor_list_types::neighbor_list_iterator_create
subroutine, public neighbor_list_iterator_create(iterator_set, nl, search, nthread)
Neighbor list iterator functions.
Definition qs_neighbor_list_types.F:165
qs_neighbor_list_types::neighbor_list_iterator_release
subroutine, public neighbor_list_iterator_release(iterator_set)
...
Definition qs_neighbor_list_types.F:251
qs_neighbor_list_types::neighbor_list_iterate
integer function, public neighbor_list_iterate(iterator_set, mepos)
...
Definition qs_neighbor_list_types.F:351
qs_neighbor_list_types::get_iterator_info
subroutine, public get_iterator_info(iterator_set, mepos, ikind, jkind, nkind, ilist, nlist, inode, nnode, iatom, jatom, r, cell)
...
Definition qs_neighbor_list_types.F:549
virial_methods
Definition virial_methods.F:12
virial_methods::virial_pair_force
pure subroutine, public virial_pair_force(pv_virial, f0, force, rab)
Computes the contribution to the stress tensor from two-body pair-wise forces.
Definition virial_methods.F:139
virial_types
Definition virial_types.F:13
atomic_kind_types::atomic_kind_type
Provides all information about an atomic kind.
Definition atomic_kind_types.F:45
atprop_types::atprop_type
type for the atomic properties
Definition atprop_types.F:31
cell_types::cell_type
Type defining parameters related to the simulation cell.
Definition cell_types.F:55
distribution_1d_types::distribution_1d_type
structure to store local (to a processor) ordered lists of integers.
Definition distribution_1d_types.F:62
message_passing::mp_comm_type
Definition message_passing.F:189
message_passing::mp_para_env_type
stores all the informations relevant to an mpi environment
Definition message_passing.F:763
particle_types::particle_type
Definition particle_types.F:35
qs_energy_types::qs_energy_type
Definition qs_energy_types.F:25
qs_environment_types::qs_environment_type
Definition qs_environment_types.F:215
qs_force_types::qs_force_type
Definition qs_force_types.F:28
qs_kind_types::qs_kind_type
Provides all information about a quickstep kind.
Definition qs_kind_types.F:171
qs_neighbor_list_types::neighbor_list_iterator_p_type
Definition qs_neighbor_list_types.F:117
qs_neighbor_list_types::neighbor_list_set_p_type
Definition qs_neighbor_list_types.F:67
virial_types::virial_type
Definition virial_types.F:26