cp_dlaf_utils_api.F

Go to the documentation of this file.

!--------------------------------------------------------------------------------------------------!
!   CP2K: A general program to perform molecular dynamics simulations                              !
!   Copyright 2000-2024 CP2K developers group <https://cp2k.org>                                   !
!                                                                                                  !
!   SPDX-License-Identifier: GPL-2.0-or-later                                                      !
!--------------------------------------------------------------------------------------------------!
 
MODULE cp_dlaf_utils_api
   USE iso_c_binding,                   ONLY: c_char,&
                                              c_int,&
                                              c_loc,&
                                              c_null_char,&
                                              c_ptr
#include "../base/base_uses.f90"
 
   IMPLICIT NONE
 
   PRIVATE
 
   CHARACTER(len=*), PARAMETER, PRIVATE :: moduleN = 'cp_dlaf_utils_api'
 
   PUBLIC :: cp_dlaf_initialize, cp_dlaf_finalize
   PUBLIC :: cp_dlaf_create_grid, cp_dlaf_free_grid
 
CONTAINS
 
! **************************************************************************************************
!> \brief Initialize DLA-Future and pika runtime
!> \author Rocco Meli
!> \author Mikael Simberg
!> \author Mathieu Taillefumier
! **************************************************************************************************
   SUBROUTINE cp_dlaf_initialize()
      CHARACTER(len=*), PARAMETER :: routinen = 'cp_dlaf_initialize'
      INTEGER, PARAMETER                                 :: dlaf_argc = 1, pika_argc = 1
 
      CHARACTER(len=5, kind=C_CHAR), ALLOCATABLE, TARGET :: dlaf_argv(:), pika_argv(:)
      INTEGER                                            :: handle
      TYPE(c_ptr), ALLOCATABLE, DIMENSION(:)             :: dlaf_argv_ptr, pika_argv_ptr
      INTERFACE
         SUBROUTINE dlaf_init(pika_argc, pika_argv, dlaf_argc, dlaf_argv) bind(C, name='dlaf_initialize')
            IMPORT :: c_ptr, c_int
            TYPE(c_ptr), DIMENSION(*) :: pika_argv
            TYPE(c_ptr), DIMENSION(*) :: dlaf_argv
            INTEGER(kind=c_int), value :: pika_argc
            INTEGER(kind=c_int), value :: dlaf_argc
         END SUBROUTINE dlaf_init
      END INTERFACE
 
      CALL timeset(routinen, handle)
 
#if defined(__DLAF)
      ALLOCATE (pika_argv(pika_argc))
      pika_argv(1) = "dlaf"//c_null_char
      ALLOCATE (dlaf_argv(dlaf_argc))
      dlaf_argv(1) = "dlaf"//c_null_char
 
      ALLOCATE (pika_argv_ptr(pika_argc))
      pika_argv_ptr(1) = c_loc(pika_argv(1))
      ALLOCATE (dlaf_argv_ptr(dlaf_argc))
      dlaf_argv_ptr(1) = c_loc(dlaf_argv(1))
 
      CALL dlaf_init(pika_argc, pika_argv_ptr, dlaf_argc, dlaf_argv_ptr)
#else
      mark_used(pika_argv)
      mark_used(pika_argv_ptr)
      mark_used(pika_argc)
      mark_used(dlaf_argv)
      mark_used(dlaf_argv_ptr)
      mark_used(dlaf_argc)
#endif
 
      CALL timestop(handle)
   END SUBROUTINE cp_dlaf_initialize
 
! **************************************************************************************************
!> \brief Finalize DLA-Future and pika runtime
!> \author Rocco Meli
!> \author Mikael Simberg
!> \author Mathieu Taillefumier
! **************************************************************************************************
   SUBROUTINE cp_dlaf_finalize()
      CHARACTER(len=*), PARAMETER                        :: routinen = 'cp_dlaf_finalize'
 
      INTEGER                                            :: handle
      INTERFACE
         SUBROUTINE dlaf_finalize_aux() &
            bind(c, name='dlaf_finalize')
         END SUBROUTINE dlaf_finalize_aux
      END INTERFACE
 
      CALL timeset(routinen, handle)
 
#if defined(__DLAF)
      CALL dlaf_finalize_aux()
#endif
 
      CALL timestop(handle)
   END SUBROUTINE cp_dlaf_finalize
 
! **************************************************************************************************
!> \brief Create DLA-Future grid from BLACS context
!> \param blacs_context ...
!> \author Rocco Meli
!> \author Mikael Simberg
!> \author Mathieu Taillefumier
! **************************************************************************************************
   SUBROUTINE cp_dlaf_create_grid(blacs_context)
      INTEGER, INTENT(IN)                                :: blacs_context
 
      CHARACTER(len=*), PARAMETER :: routinen = 'cp_dlaf_create_grid'
 
      INTEGER                                            :: handle
      INTERFACE
         SUBROUTINE dlaf_create_grid(blacs_contxt) &
            bind(c, name='dlaf_create_grid_from_blacs')
            IMPORT :: c_int
            INTEGER(KIND=C_INT), VALUE :: blacs_contxt
         END SUBROUTINE
      END INTERFACE
 
      CALL timeset(routinen, handle)
 
#if defined(__DLAF)
      CALL dlaf_create_grid(blacs_context)
#else
      mark_used(blacs_context)
      cpabort("CP2K compiled without the DLA-Future library.")
#endif
 
      CALL timestop(handle)
   END SUBROUTINE cp_dlaf_create_grid
 
! **************************************************************************************************
!> \brief Free DLA-Future grid corresponding to BLACS context
!> \param blacs_context ...
!> \author Rocco Meli
!> \author Mikael Simberg
!> \author Mathieu Taillefumier
! **************************************************************************************************
   SUBROUTINE cp_dlaf_free_grid(blacs_context)
      INTEGER, INTENT(IN)                                :: blacs_context
 
      CHARACTER(len=*), PARAMETER                        :: routinen = 'cp_dlaf_free_grid'
 
      INTEGER                                            :: handle
      INTERFACE
         SUBROUTINE dlaf_free_grid(blacs_contxt) &
            bind(c, name='dlaf_free_grid')
            IMPORT :: c_int
            INTEGER(KIND=C_INT), VALUE :: blacs_contxt
         END SUBROUTINE
      END INTERFACE
 
      CALL timeset(routinen, handle)
 
#if defined(__DLAF)
      CALL dlaf_free_grid(blacs_context)
#else
      mark_used(blacs_context)
      cpabort("CP2K compiled without the DLA-Future library.")
#endif
 
      CALL timestop(handle)
   END SUBROUTINE cp_dlaf_free_grid
 
END MODULE cp_dlaf_utils_api